Fonction SI dans VBA excel [Résolu]

[kaboche]

Bonjour,

Je cherche une formule afin de completer ma formule IF...Then dans VBA excel.
J'ai un tableau de X lignes de données je vourdais afficher certaines données dans un formulaire (dejà fais) quand la recherche est égale à un code.
C'est fa fonction "si" autrement dit, (dans excel c'est facile, on a juste à faire glisser la fonction jusu'en bas du tableau).

Mais avec du VBA, on fais comment? Au jour d'aujourd'hui, je n'arrive qu'a le faire que pour une seule ligne!! Comment le faire pour tout le tableau ?

Voici les lignes que j'ai utilisé pour mon unique ligne :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Private Sub CommandButton1_Click()
'pour aller chercher les résultats
 
If accueil.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then Fiche.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value
If accueil.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then Fiche.TextBox2.Value = Worksheets("MESUP_FC").Cells(2, 2).Value
If accueil.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then Fiche.TextBox3.Value = Worksheets("MESUP_FC").Cells(2, 5).Value
If accueil.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then Fiche.TextBox4.Value = Worksheets("MESUP_FC").Cells(2, 6).Value
If accueil.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then Fiche.TextBox5.Value = Worksheets("MESUP_FC").Cells(2, 7).Value
If accueil.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then Fiche.TextBox6.Value = Worksheets("MESUP_FC").Cells(2, 8).Value
If accueil.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then Fiche.TextBox7.Value = Worksheets("MESUP_FC").Cells(2, 9).Value
If accueil.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then Fiche.TextBox8.Value = Worksheets("MESUP_FC").Cells(2, 10).Value
If accueil.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then Fiche.TextBox9.Value = Worksheets("MESUP_FC").Cells(2, 11).Value
If accueil.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then Fiche.TextBox10.Value = Worksheets("MESUP_FC").Cells(2, 12).Value
If accueil.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then Fiche.TextBox11.Value = Worksheets("MESUP_FC").Cells(2, 13).Value
If accueil.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then Fiche.TextBox12.Value = Worksheets("MESUP_FC").Cells(2, 14).Value
If accueil.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then Fiche.TextBox13.Value = Worksheets("MESUP_FC").Cells(2, 15).Value
If accueil.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then Fiche.TextBox14.Value = Worksheets("MESUP_FC").Cells(2, 16).Value
If accueil.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then Fiche.TextBox15.Value = Worksheets("MESUP_FC").Cells(2, 17).Value
If accueil.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then Fiche.TextBox16.Value = Worksheets("MESUP_FC").Cells(2, 18).Value
If accueil.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then Fiche.TextBox17.Value = Worksheets("MESUP_FC").Cells(2, 19).Value
If accueil.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then Fiche.TextBox18.Value = Worksheets("MESUP_FC").Cells(2, 20).Value
If accueil.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then Fiche.TextBox19.Value = Worksheets("MESUP_FC").Cells(2, 21).Value
If accueil.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then Fiche.TextBox20.Value = Worksheets("MESUP_FC").Cells(2, 22).Value
If accueil.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then Fiche.TextBox21.Value = Worksheets("MESUP_FC").Cells(2, 23).Value
If accueil.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then Fiche.TextBox22.Value = Worksheets("MESUP_FC").Cells(2, 24).Value
'pour montrer la fiche
Fiche.Show
End Sub

Comment faire pour élargir ceci à tout le tableau ?
Merci de votre aide

fabien

[Theze]

Bonjour,

Si j'ai bien compris, tu veux remplacer ton code par une boucle afin qu'il ne soit pas répétitif ?

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 
Private Sub CommandButton1_Click()
 
    Dim I As Integer
    Dim J As Integer
 
    If TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value Then
 
        'traîte le cas du premier TextBox
        Fiche.TextBox1.Value = Worksheets("MESUP_FC").Cells(2, 7).Value
 
        For I = 2 To 24
 
            'évite les colonnes 3 et 4 (C et D)
            If I <> 3 And I <> 4 Then
 
                J = J + 1
 
                Fiche.Controls("TextBox" & J + 1).Text = Worksheets("MESUP_FC").Cells(2, I).Value
 
            End If
 
        Next I
 
    End If
 
'pour montrer la fiche
Fiche.Show
 
End Sub

Hervé.

[kaboche]

Merci beaucoup hervé,
je pensais également à une boucle, mais je suis novice.
Cependant ton VBA ne marche que pour ma première ligne de mon tableau.
Le code (ma recherche) que que l'on cherche est bien en cells (2,7)! par contre il y a un nouveau code à chaque ligne. C'est à dire de la cellule (2, 7) à (355, 7) !

Comment je fais pour que chaque code rechercher mes textbox prennent la valeur de ce meme code correspodant à cette meme ligne ?

fabien

[mercatog]

Une proposition avec la méthode Find

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Private Sub CommandButton1_Click()
Dim c As Range
Dim Code As String
 
Code = accueil.TextBox1.Value
If Code <> "" Then
    Set c = Worksheets("MESUP_FC").Range("G:G").Find(Code, LookIn:=xlValues, lookat:=xlWhole)
    If Not c Is Nothing Then
        Call Remp(c.Row)
        Set c = Nothing
    End If
End If
End Sub
 
Private Sub Remp(ByVal Lig As Long)
Dim i As Byte
 
With Worksheets("MESUP_FC")
    fiche.TextBox1.Value = .Cells(Lig, 7).Value
    fiche.TextBox2.Value = .Cells(Lig, 2).Value
    For i = 3 To 22
        fiche.Controls("TextBox" & i).Value = .Cells(Lig, i + 2)
    Next i
End With
End Sub

[kaboche]

Merci Mercatog mais j'ai un message d'erreur :
Bloc If sans end If !

[mercatog]

Oups, une ligne a sauté

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Private Sub CommandButton1_Click()
Dim c As Range
Dim Code As String
 
Code = accueil.TextBox1.Value
If Code <> "" Then
    Set c = Worksheets("MESUP_FC").Range("G:G").Find(Code, LookIn:=xlValues, lookat:=xlWhole)
    If Not c Is Nothing Then
        Call Remp(c.Row)
        Set c = Nothing
    End If
End If
End Sub
 
Private Sub Remp(ByVal Lig As Long)
Dim i As Byte
 
With Worksheets("MESUP_FC")
    fiche.TextBox1.Value = .Cells(Lig, 7).Value
    fiche.TextBox2.Value = .Cells(Lig, 2).Value
    For i = 3 To 22
        fiche.Controls("TextBox" & i).Value = .Cells(Lig, i + 2)
    Next i
End With
End Sub

[kaboche]

Merveilleux
merci beaucoup mercatog!!!!
par contre c'est comme si javais tricher pour un devoir car je ne comprend pas une ligne du code!!!
vais tenter de comprendre, mais en tt cas merci beaucoup!

[mercatog]

Surtout ne triche pas!!!
Ci-joint code commenté pour expliquer (n'oublie pas le F1: l'aide) c'est très utile et c'est gratuit

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Private Sub CommandButton1_Click()
Dim c As Range
Dim Code As String
 
'Code: le contenu de TextBox1 qu'on va chercher sur la colonne G
Code = Accueil.TextBox1.Value
'Si Code est non vide
If Code <> "" Then
'F1 sur la méthode Find (on cherche la valeur de Code dans la colonne G de notre feuille)
'c est la cellule de la colonne G contenant éventuellement la valeur de Code
    Set c = Worksheets("MESUP_FC").Range("G:G").Find(Code, LookIn:=xlValues, lookat:=xlWhole)
    'Si une cellule est trouvée (contenant la valeur de Code) c sera différente de rien
    If Not c Is Nothing Then
        'On appelle la procédure de remplissage Remp des TextBox de Fiche en fonction de la ligne c de la cellule trouvée (en l’occurrence: c.Row)
        Call Remp(c.Row)
        'On vide notre variable objet (Range) c
        Set c = Nothing
    End If
End If
End Sub
 
'Procédure de remplissage des TextBox de Fiche en fonction de Lig
Private Sub Remp(ByVal Lig As Long)
Dim i As Byte
 
With Worksheets("MESUP_FC")
    Fiche.TextBox1.Value = .Cells(Lig, 7).Value
    Fiche.TextBox2.Value = .Cells(Lig, 2).Value
    'On boucle sur les textbox de 3 à 22
    'on remarque que le textbox d'index j est rempli par la contenu de la cellule Cells(Lig,j+2)
    For i = 3 To 22
        Fiche.Controls("TextBox" & i).Value = .Cells(Lig, i + 2)
    Next i
End With
End Sub

[kaboche]

Merci je comprend un peu mieux avec tes explications!
je voudrais vraiment maitriser cet outil, mais c'est vraiment complexe!
Malheureusement pour moi, je travail sur un tableur test et non le fichier final. j'espère que j'arriverrai a retranscrir ton code.
Merci encore pour ton aide