[XL-2007] Je voudrais le contenu des cellules trouvées qui correspondent à la référence que je saisirais dans une autre. [Résolu]

[manuseverine]

Bonjour,

J'aurais une petite question.

J'ai un tableau avec dans la colonne A, les n° de factures, en colonne H les références de pièces correspondantes sur la facture. Par exemple dans une facture 20325478 j'ai 2 pièces et donc 2 lignes H1 et H2 avec les références 1024510 et 1901040.

Je voudrais réaliser la chose suivante :

lorsque je saisie dans une cellule, par exemple L440 la référence d'une pièce, par exemple 1901040 il recherche dans la colonne H s'il trouve cette référence et me donne le n° de la facture correspondante dans la même ligne.
Je ne sais pas si vous avez compris. En tout cas j'ai fais ça :

Code :

=SI(OU(L440="";ESTERREUR(EQUIV(L440;'HISTORIQUE FACTURES'!$H$4:'HISTORIQUE FACTURES'!$H$1681;0)));"";INDEX('HISTORIQUE FACTURES'!$A$4:'HISTORIQUE FACTURES'!$A$1681;EQUIV(L440;'HISTORIQUE FACTURES'!$H$4:'HISTORIQUE FACTURES'!$H$1681;0)))

ça marche mais le problème c'est que si j'ai plusieurs factures, donc si j'ai commandé cette pièce plusieurs fois, tous les n° de facture ne s'affiche pas.
Comment je pourrais faire. Je voudrais toutes les factures qu'il trouve qui correspondent à la référence que je saisirais.

Merci pour votre aide

[Daniel.C]

Bonjour,
Formule matricielle (valider avec Ctrl+Maj+Entrée) :

Code :

=SIERREUR(INDEX('HISTORIQUE FACTURES'!$A$1:$A$30;PETITE.VALEUR(SI('HISTORIQUE FACTURES'!$H$1:$H$30=$L$440;LIGNE($H$1:$H$30));LIGNE(A1));1);"")

[manuseverine]

merci beaucoup mais à moins que j'ai mal compris ta formule, celle-ci en fait ne fait que me donner le n° de facture qui se trouve sur la même ligne que la cellule ou je saisie ma référence.

Est-ce que je me suis mal expliqué, peut-être que vous ne comprenez pas ce que je veux car je m'explique mal.

ma formule en fait elle marche mais elle me donne un seul n° de facture, alors qu'elle aurait du m'en donner 2 car je l'ai commandé 2 fois, cette pièce.

[Daniel.C]

C'est moi qui me suis mal expliqué. En fait, tu mets la formule dans une cellule et tu la recopies vers le bas. Tu obtiens la liste des factures contenant la référence.

[manuseverine]

Je ne comprends pas ça ne marche pas, je fais peut-être quelque chose de mal.
Sans vouloir abuser, pourrais tu faire un petit fichier exemple pour me faire voir que ça marche ca rmoi je n'arrive pas à l'appliquer apparemment.

Merci beaucoup pour ton aide

[Daniel.C]

Regarde le classeur joint (c'est un classeur xls, donc je ne sais pas si la formule sera lisible - la fonction SIERREUR n'est pas supportée-) Si c'est le cas, dis-le moi.

[manuseverine]

merci beaucoup c'est très sympa

j'ai ouvert ton fichier et ça marche, j'avais pourtant bien compris mais je n'arrive pas à l'appliquer même en copier coller. Quelque chose doit m'échapper. J'ai donc essayer de reprendre ta formule et j'avais une petite question. Pourquoi quand j'étend simplement ta formule à plus de ligne, ça ne marche plus. Regardes le fichier joint en espérant que ça marche

Merci encore

manuseverine(1).xls

[Daniel.C]

La formule est une formule matricielle, c'est à dire que, au lieu d'appuyer sur la touche Entrée pour la valider comme une formule, tu dois maintenir les touches Ctrl et Maj enfoncées et appuyer sur la touche Entrée. Si c'est correct, la formule apparaît entre crochets ({=formule}). Si tu colles la formule dans une cellule, tu dois cliquer dans la barre de formule et valider avec les trois touches comme indiqué précédemment.
Ceci dit, dans ton classeur, il n'y a qu'une facture ayant la référence "référence8". Donc tu n'auras qu'une facture dans la zone résultat.

[manuseverine]

merci beaucoup, j'avais bien compris mais ça ne marchais pas à cause d'une bétise de ma part. Je me suis trompé de touche majuscule. Quand je passe en minuscule ou en majuscule mon clavier me demande toujours d'appuyer sur la même touche (ce que je trouve très pénible car je ne sais pas quand je suis en majuscule d'ailleurs) et donc j'ai appuyer par habitude sur cette touche alors que c'était celle d'en dessous. C'est grace aux crochets dont tu m'as parlé que j'ai remarqué que ça ne marchait pas.

Merci encore beaucoup pour ta patience, maintenant ça marche, c'est super je suis ravis

je vais en profiter pour aller voir si je trouve un tuto sur les formules matricielles sur le forum, comme ça je comprendrais mieux cette formule.

Bonne journée à toi

[manuseverine]

Bonjour,
j'ai réouvert le sujet plutôt que d'en créer un autre car ma question a un rapport direct avec la formule créer ci-dessus.
Tout va bien mais j'ai quand-même un petit soucis :
quand j'essaie de faire une recherche pour une référence de pièce alors que le n° de facture n'est pas directement sur la même ligne ça ne marche pas, je n'y avais pas pensé. Voici un exemple :

[IMG][/IMG]

j'ai justifié et centré le n° de facture et donc je ne sais pas s'il y a une solution ?

Quand je cherche une référence qui est sur la première ligne ça marche mais autrement non forcément. Il faudrait qu'il recherche la ligne en face et la première cellule remplie vers le haut

[Daniel.C]

Poste un petit classeur exemple, parce que ton image, elle est illisible.

[manuseverine]

j'ai repris ton classeur je l'ai juste un peu modifié

manuseverine(1).xls

[Daniel.C]

C'est joli, les cellules fusionnées, mais c'est la plaie pour les formules.
En K1, mets (formule matricielle) :

Code :

=SI(A1="";INDEX($A$1:$A$30;MAX(SI($A$1:A1<>"";LIGNE($A$1:A1)));1);A1)

et recopie vers le bas.

Modifie la formule en J2 (matricielle également) :

Code :

=SIERREUR(INDEX('HISTORIQUE FACTURES'!$K$1:$K$30;PETITE.VALEUR(SI('HISTORIQUE FACTURES'!$H$1:$H$30=$L$440;LIGNE($H$1:$H$30));LIGNE(A1));1);"")

Recoopie vers le bas.

[manuseverine]

Merci beaucoup, je n'avais pas pensé à rajouter une colonne masqué.
Merci encore pour ton aide