[XL-2010] Excel fusion de fichiers [Résolu]

[superstarz]

Bonjour,

J'ai besoin de récupérer de nombreux enregistrement de fichier excel.
Je suis à la recherche donc d'un moyen qui récupérerai la première ligne ( et seulement la premiere ligne) de nombreux fichier excel et qu'elle les insères les une à la suite des autres dans un fichier excel.

Je n'ai aucune notion en VBA.

Merci d'avance.

[bbil]

combien de fichier ? ce nombre est-il susceptible de changer ? ou sont ces fichiers ? ......

[superstarz]

Bonjour,

Alors les fichiers je n'ai pas de chiffres exact, surement un nombre plutôt conséquent (environ 1500).
Ces fichiers, nous les recevrons par mail et nous les mettrons dans un dossier.

[bbil]

Et donc les fichiers ne doivent être traités qu'une fois... Comment savoir si un fichier à été traité par exemple en plaçant les fichiers reçu dans un répertoire "A_TRAITER" puis une fois le traitement effectué déplacer les fichiers dans un autre répertoire.

[superstarz]

Oui mais c'est une opération qui a lieu seulement une fois par an, nous regrouperons tous les fichiers dans un même dossier puis nous lancerions la jointure.
Une fois cela fait l'opération est terminée.

(Travail à but non lucratif je précise ...)

EDIT : excusez moi pour la catégorie je pensais que cela pourais se faire grâce à des outils d'EXCEL, et vu que je n'avais aucune connaissance en VBA je me voyais mal posté dans cette rubrique

[bbil]

Envoyé par superstarz

..
EDIT : excusez moi pour la catégorie je pensais que cela pourais se faire grâce à des outils d'EXCEL, et vu que je n'avais aucune connaissance en VBA je me voyais mal posté dans cette rubrique

1500 fichiers cela fait beaucoup pour une formule...

voici le code suivant à mettre dans un module de ton classeur récap :
- ALt F11 pour lancer l'éditeur VBE
- Insertion module..

pour le lancement ce placer dans le code et actionner la touche F5...
ce code traite tous les fichiers excel présent sous le même répertoire que le fichier récap .. et copie la première ligne de la première feuille

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub MajSynthese()
    Dim stRepSource As String 'Répertoire source
    Dim stFichier As String
    Dim wk As Workbook ' Classeur source
 
    Dim shDest As Worksheet 'Feuille destination (récap=
    Dim iDer As Integer 'Derniére ligne utilisée
    stRepSource = ThisWorkbook.Path ' ...Répertoire Source identique au répertoire courant.
 
    Set sh = ThisWorkbook.Sheets("Feuil1") '>>> A ADAPTER >> défini la feuille destination de la récap
    stFichier = Dir(stRepSource & "\*.xls")
    iDer = sh.Cells(Rows.Count, "A").End(xlUp).Row + 1
    While stFichier <> ""
 
        If Not (stRepSource = ThisWorkbook.Path And stFichier = ThisWorkbook.Name) Then
          Debug.Print "traite fichier : " & stFichier
          Set wk = Workbooks.Open(stRepSource & "\" & stFichier, True, True)  'Ouverture du fichier en lecture seule
 
          wk.Sheets(1).Rows(1).Copy sh.Rows(iDer) '>>> A ADAPTER >>> copie la ligne 1 de la premiére feuille du classeur.
          wk.Close False 'Ferme sans sauver
       Else
            Debug.Print "On ne traite pas le fichier courant "
        End If
        stFichier = Dir 'Passage au fichier suivant
        iDer = iDer + 1 'Passage à ligne suivante
    Wend
End Sub

mais avant un peu de lecture sur le VBA : http://silkyroad.developpez.com/VBA/DebuterMacros/
semble un minimum ...

[superstarz]

Et bien comment te dire ... je touche un peu à tous les domaines de l'informatiques depuis longtemps et j'ai régulièrement dû aller sur des forums pour avoir de l'aide mais une réponse comme ça franchement ... jamais vu ça.

Donc un GROS Merci et encore merci c'est super ton programme fonctionne comme sur des roulettes :