Instance d'une base frontale [Résolu]

[DevBaldwin]

Bonjour à tous !

Je dev actuellement sur une base access 2010 en frontal / dorsale (concept nouveau pour moi)
La méthode frontal / dorsale est absolument nécessaire à cette base, du à une contrainte de multi-utilisateur.

L'ennui est que la base frontale est assez régulièrement mise à jour (quelques changements mineurs dans les formulaires ou les états) et cela oblige donc à mettre à jour toutes les bases frontale sur tout les postes client. Pas cool ...

Ma question serait donc de savoir s'il est possible de créer des instances de la base frontale sur les poste clients. Une instance serait créer à chaque ouverture de la base frontale.
Je me retrouverais donc avec :

• 1 base dorsale (sur mon serveur)
• 1 base frontale (sur mon serveur, et non plus sur mon client)
• X instances de la base frontale (générer sur mes clients)

L'idée étant que chaque fois que la base frontale est modifié, il n'y ai pas besoin d'aller faire un copier / coller sur les postes clients.

Peut-être je crois encore au père noël en imaginant ça, mais peut-être aussi cela existe t'il déjà ?
Je n'ai pas vu ça actuellement dans mes recherches.

Merci d'avance à ceux qui pourront m'aider

[Dolphy35]

Bonjour,

Tu veux dire que chaque utilisateurs se connectera à la même Frontale, dans ce cas tu auras des très gros ralentissement + des instabilités liées aux multi-utilisateurs. Ceci n'est vraiment pas conseillé.
Si tu créer un fichier Frontale pour chaque utilisateurs sur ton serveur, tu risque d'avoir des gros ralentissements.

Dans ma dernière application j'ai dû diffuser une bêta pour une remontées d'expérience afin de faire évoluer la base. Tous les jours je diffusais une MAJ.
j'utilise deux principes :
1-Au démarrage de la bdd test de la version disponible (table sur la bdd Serveur). Ouverture d'une autre base Access qui copie la base frontale à jour (serveur) vers le poste client. Puis réouverture la nouvelle bdd à jour.
2-Idem précédent sauf qu'au lieu que ce soit une base Access, c'est une application en VB.NET.

Tu peux utiliser une autre techno ou autre fichier (batch, vbs).

Dolphy

[sylvain.thibault]

Ci-joint un petit script vbs que j'installe sur chaque machine client.

Ce script vérifie la dernière version sur le serveur et l'installe sur le poste client si nouvelle version. Lorsque je génère une nouvelle version, je change son nom pour que le script détecte cette nouvelle version.

Le raccourci sur le poste client pointe sur le script vbs.

Cdlt,

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
' #################################
' # déclaration des bibliothèques #
' #################################
Set FSO = CreateObject("Scripting.FileSystemObject")
Set WshShell = WScript.CreateObject("WScript.Shell")
 
' ##########################################################
' # déclaration des variables répertoires local et distant #
' ##########################################################
RepLocal = Replace(WScript.ScriptFullName, WScript.ScriptName, "")
RepServeur = "X:"
 
' ############################################
' # recherche le fichier appli en local #
' ############################################
For each oFl in  FSO.GetFolder(RepLocal).Files
  If InStr(oFl.Name,"nom_appli") > 0 then    
   NomFichierLocal=oFl.Name
  End If
Next
 
' ##################################################
' # recherche le fichier appli sur le serveur #
' ##################################################
For each oFl in  FSO.GetFolder(RepServeur).Files
  If InStr(oFl.Name,"nom_appli") > 0 then
   NomFichierServeur=oFl.Name
  End If
Next
 
' #####################################################################
' # vérifie si le nom du fichier local est le même que sur le serveur #
' #####################################################################
If NomFichierLocal=NomFichierServeur Then
' ###############################
' # lancement de la base locale #
' ###############################
 intReturn = WshShell.Run("." & "\" & NomFichierLocal , 1, TRUE)
Else
' ########################################
' # copie de la base du serveur en local #
' ########################################
fso.CopyFile RepServeur & NomFichierServeur,"." & "\"
 If NomFichierLocal="" Then
 Else
' ############################################
' # suppression de l'ancienne version locale #
' ############################################
  Set FichierASupprimer = fso.GetFile(RepLocal & "\" & NomFichierLocal)
  FichierASupprimer.delete
 End If
 NomFichierLocal=NomFichierServeur
' #########################################################
' # aprés copie du fichier en local, lancement de la base #
' #########################################################
 intReturn = WshShell.Run("." & "\" & NomFichierLocal , 1, TRUE)
End If

[DevBaldwin]

Merci à vous 2 pour vos réponses !!
Vos solutions auraient pu répondre à ma problématique.

J'ai finalement usé des ressources mise à disposition par l'entreprise pour me simplifier la vie (Vive les applications publié sous Citrix )

Problème résolut