[AC-2007] Incrémentation d'un numéro à partir d'une date [Résolu]

[puledad1]

Mesdames, Messieurs

Je suis entrain de créer une base de données sous access 2007.
Elle me permet d'enregister des échantillons de médicaments qui arrivent dans mon laboratoire.

Pour chaque echantillon receptionné je fait un enregistrement.
J'aimerais que dans mon formulaire, il me suffise de cliquer sur un bouton pour donner à mon echantillon un numéro de la forme AA_MM_XX (AA = année au jour de la saisie, MM = mois au jour de la saisie, XX= 01 si c'est le premier enregistrement de la journée, 02 si c'est le deuxiême enregistrement de la journée... etc.....)

J'ai une base de données qui me sert d'exemple que je ne peux malheureusement pas ouvrir en mode création pour un défaut d'autorisation.
Cependant j'observe que le numéro d'échantillons y est créé à partir d'une table ("Sequence") qui contient un champ ("PREFIX") qui contient les données AA_MM et un champ ("NEXTID") qui contient les données XX

Merci de bien vouloir m'aider à developper cette fonctionnalité.

PS : je suis un béotien de la programmation VBA, je n'utilise que la boite à outils. Si il est possible de ne pas rendre la réponse trop compliqué ce serait au top.

Merci à vous.

[f-leb]

Bonjour,

J'aimerais que dans mon formulaire, il me suffise de cliquer sur un bouton pour donner à mon echantillon un numéro de la forme AA_MM_XX (AA = année au jour de la saisie, MM = mois au jour de la saisie, XX= 01 si c'est le premier enregistrement de la journée, 02 si c'est le deuxiême enregistrement de la journée... etc.....)

Par exemple avec ce système, le 1er échantillon de la journée d’aujourd’hui et le 1er échantillon de la journée de demain auront tous les deux le même numéro : 11_08_01, ainsi que tous les 1ers échantillons du mois d’Aout.
C’est voulu comme système ?

Cependant j'observe que le numéro d'échantillons y est créé à partir d'une table ("Sequence") qui contient un champ ("PREFIX") qui contient les données AA_MM et un champ ("NEXTID") qui contient les données XX

C’est efficace comme système, surtout en fonctionnement multi-utilisateurs simultanés. Est-ce que c’est le cas ?

[puledad1]

Je me suis trompé.
01 si c'est le premier enregistrement du mois
02 si c'est le deuxieme enregistrement du mois
etc....

[puledad1]

C’est efficace comme système, surtout en fonctionnement multi-utilisateurs simultanés. Est-ce que c’est le cas ?

Oui c'est le cas. Mais par contre je sais pas du tout comment m'y prendre.

[puledad1]

Visiblement pas mal de gens lisent ma question. Peut être n'y répondez vous pas car ma question est trop vague et necessite une reponse trop longue.

Est il possible de nommé ce que je cherche à faire afin que je puisse mieux effectuer mes recherches.

[User]

Oui,

Il te faut créer ton propre numéro, comme on définirait ses propres numéros de factures mensuelles :

Fait une recherche dans le forum sur "numéro de facture" par exemple...

Pour le préfixe il faut utiliser la formule:

Code :

Me.PREFIX = Format(Date, "YY-MM")

et pour l'ID:

Code :

Me.NEXTID = Format(Nz(DMax("NEXTID", "Sequence", "PREFIX='" & Format(Date, "YY-MM") & "'") + 1, 1), "00")

Sans aucune garantie niveau fonctionnement multi-utilisateurs simultanés

A+

[f-leb]

Hé hé, pendant que User répondait, je concoctais une petite fonction permettant de récupérer le prochain indice.

Je la mets quand même hein !

Il faut d’abord créer la table Sequence(PREFIX(texte), NEXTID(entier long)) avec éventuellement une ligne déjà remplie, par exemple :
PREFIX="11-08" et NEXTID=1

Puis copier/coller le code ci-dessous dans un module VBA (ALT F11 puis Insertion>Module)

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Public Function GetIndice() As Long
'
   On Error GoTo ErrorHandler
'
Dim LeNouvelIndice As Long
Dim rs As DAO.Recordset
Dim db As DAO.Database: Set db = CurrentDb()
'
  Set rs = db.OpenRecordset("Sequence", dbOpenDynaset) ' on ouvre le jeu d'enregistrements de la table Sequence
 
  rs.FindFirst "[PREFIX]='" & Format(Date, "yy-mm") & "'" ' on cherche dans Sequence le préfixe du jour
 
    If rs.NoMatch Then ' un nouveau mois a commencé
        With rs
          .AddNew
          .Fields("[PREFIX]") = Format(Date, "yy-mm")
          .Fields("[NEXTID]") = 2 'puisqu'on récupère le 1
          .Update
        End With
 
    LeNouvelIndice = 1
 
  Else ' il y a déjà des échantillons ce mois-ci
    With rs
        .Edit
        LeNouvelIndice = .Fields("[NEXTID]")
        .Fields("[NEXTID]") = LeNouvelIndice + 1
        .Update
    End With
  End If
'
rs.Close: Set rs = Nothing
'
GetIndice = LeNouvelIndice
'
Exit Function
'
ErrorHandler:
MsgBox ("erreur n°" & err.Number & " :" & err.Description)
'
End Function

Dans la fenêtre d’exécution (CTRL+G), faire des essais en tapant :

Code :

? GetIndice()

Regarder l’indice retourné et voir si le compteur est mis à jour dans la table Sequence.
Faire d’autres essais en bidouillant PREFIX et NEXTID.

A tester puis on verra après comment utiliser la fonction dans le formulaire.

Avec l’aide de User en plus, ça devrait le faire…

[puledad1]

Voilà F leb, ça à l'air de marcher pas mal là, merci beaucoup.
Pouvez vous m'aider à integrer cela dans un formulaire?

J'ai un peu de mal à obtenir un Textbox avec UN numero sous la forme MM_AA_XX en partant de deux champs différents : MM_AA et XX. Ainsi qu'un bouton next.

Je continue à bricoler un peu...

[f-leb]

bonjour,

essaye sur l'évènement "Avant insertion" de ton formulaire de saisie des échantillons:

Code :

1
2
3
Private Sub Form_BeforeInsert(Cancel As Integer)
Me.CodeEchantillon = Format(Date, "yy-mm") & "-" & Format(GetIndice(), "00")
End Sub

[puledad1]

Voilà ce que j'ai fait :

Je suis retouner dans mon formulaire.
J'ai ajouter le champ "Sample NR" (numero déchantillons)

J'ai creer un bouton, je suis aller dans la feuille de prorietés du bouton dans l'évenement On click j'ai copier :

Code :

1
2
3
Private Sub Command124_Click(Cancel As Integer)
Me.SampleNR = Format(Date, "yy_mm") & "-" & Format(GetIndice(), "00")
End Sub

Mais apparement c'est pas comme ca que ca marche

[f-leb]

je ne vois pas d'erreur, sinon qu'entre les deux:

Envoyé par puledad1

... le champ "Sample NR"

Envoyé par puledad1

Code :

Me.SampleNR =...

je vois un <espace> qui pourrait bien fiche la pagaille...

[puledad1]

Mais ¨je ne comprend pas alors pourquoi on a creer la table "Sequence" du coup, ne pourrait on pas faire un code qui ressemble à ca (j'invente totalement mais je pemse que vous saisirez l'idée)

Code :

1
2
3
Private Sub Command124_Click(Cancel As Integer)
Me.SampleNR = Format(Fields("[PREFIX]") & "-" & Format(Fields("[NEXTID]")
End Sub

Puis pour afficher l'info dans le formulaire faut il creer un text box ou un combo box?

[f-leb]

Envoyé par puledad1

…mais je pense que vous saisirez l'idée

Non, pas bien…

La table Sequence permet de stocker le prochain indice à utiliser. La table est bien sûr disponible pour tous les utilisateurs sur la dorsale.

Pour récupérer le prochain indice, on passe par la fonction GetIndice() car il faut aussi mettre à jour l’indice en l’incrémentant à chaque nouvel appel.

Code :

1
2
LeNouvelIndice = .Fields("[NEXTID]")
        .Fields("[NEXTID]") = LeNouvelIndice + 1

Puis lorsqu’on change de mois par rapport au dernier enregistrement créé, la fonction remet le compteur à 1 comme tu l’as demandé.

Code :

1
2
3
4
5
6
7
8
9
    If rs.NoMatch Then ' un nouveau mois a commencé
        With rs
          .AddNew
          .Fields("[PREFIX]") = Format(Date, "yy-mm")
          .Fields("[NEXTID]") = 2 'puisqu'on récupère le 1
          .Update
        End With
 
    LeNouvelIndice = 1

Le plus simple, dans ta table échantillon, tu créés un champ texte SampleNR.

Dans ton formulaire en mode création, dans le ruban en haut tu as un bouton "Ajouter des champs existant", tu fais glisser SampleNR dans le formulaire. Une textbox portant le même nom SampleNR lié au champ de la table est automatiquement ajouté.

[puledad1]

Bon,
Malgré toute votre aide, je n'y arrive pas
J'abandonne.

Merci en tout cas, du temps que vous m'avez accordé.

Bonne continuation.

[f-leb]

Envoyé par puledad1

J'abandonne.

Pas maintenant, tu y es presque

Pourrais-tu mettre un extrait de ton fichier en pièce-jointe (compacté puis zippé) ?

[puledad1]

YUHUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUU

En voulant faire du rangement dans les lignes de codes pour ne pas avoir honte devant vous, j'ai réussi.

Je ne comprend vraiment rien, j'ai fait tout comme d'hab.

Merci, Merci, Merci