Discussion :

[Kalawaya]

Bonjour à tous,

Je suis en train de constituer un formulaire de facture possédant un N° de facture identifié par: 3 lettres (lieu de vente), 2 chiffres (l'année de vente), 4 chiffres (le n° d'ordre de la facture):
Exemple: N° MTL110012: 12ème facture de l'année 2011 pour le lieu de vente à Montréal.
Le lieu de vente et l'année sont mentionnés préalablement par l'utilisateur au moyen d'une liste déroulante dans un formulaire.

Voilà, je ne sais pas quelle est la fonction la plus adaptée (en macro) pour que lorsque l'utilisateur a fini de saisir son lieu de vente et sa date, automatiquement, une macro associée à la case du formulaire contenant le n° de Facture recherche et prenne le N° de facture le plus important (0012) dans
dans le tableau où toutes les factures de tous les lieux de vente ont été enregistrés (tous les n° de facture sont triés du plus récent au plus ancien dans une seule colonne de ce dit tableau et dans le même classeur)

Je suis confronté au problème suivant: lors de la recherche dans le tableau excel, la macro doit analyser les 3 premières lettres de tous les n° de facture contenus dans ce tableau et doit prendre celui qui correspond à la fois au lieu de vente sélectionné (MTL) mais aussi au n° le plus grand (0012).

Je ne sais pas comment faire!

Cette macro me permet ensuite d'incrémenter le nouveau N° de facture (avec le +1 classique...)

Merci pour votre aide!

[Invité]

Salut Kalawaya,

Un petit code sous forme de fonction
En admettant que la feuille qui contient les numéros s'appelle : FacturesEnregistrées

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Sub Test()
  MsgBox "Nouveau numéro : " & NewNumFac("MTL", 11)
End Sub
 
Function NewNumFac(CodeLieu As String, AnVente As Integer)
  Dim Dlig As Long, Lig As Long, nFac As Integer, sFac As String
  Dim nMax As Integer
  ' Initialiser le numéro de la facture à ZERO
  nMax = 0
  ' Avec la feuille contenant les numéros de facture
  With Sheets("FacturesEnegistrées")
    ' Trouver la dernière ligne du tableau de la colonne A
    Dlig = .Range("A" & Rows.Count).End(xlUp).Row
    ' Pour chaque ligne
    For Lig = 2 To Dlig
      ' Récupérer le numéro de la facture
      sFac = .Range("A" & Lig).Value
      ' Si le code ville correspond
      If Left(sFac, 3) = CodeLieu Then
        ' Si l'année correspond
        If Mid(sFac, 4, 2) = AnVente Then
          ' Récupérer le numéro de la facture
          nFac = CInt(Right(sFac, 4))
          ' Si ce numéro est supérieur au numéro max on le mémorise
          If nFac > nMax Then nMax = nFac
        End If
      End If
    Next Lig
    ' Retourne la valeur MAX + 1
    NewNumFac = nMax + 1
  End With
End Function

A+

[Theze]

Bonjour,

Une petite variante à la fonction de Bruno :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
 
Sub NumeroFacture()
 
    Dim NumeroAUtiliser As Long
 
    'passe le code ville et l'année en arguments à la fonction
    NumeroAUtiliser = MaxNumFacture("MTL", 11)
 
    MsgBox NumeroAUtiliser
 
End Sub
 
Function MaxNumFacture(CodeVille As String, _
                       Annee As Long) As Long
 
    Dim TblFacture() As Long
    Dim Plage As Range
    Dim Cel As Range
    Dim I As Integer
    Dim Adr As String
 
    'plage de recherche en colonne A à partir de A2, A1 étant l'entête
    Set Plage = Range([A2], [A65536].End(xlUp))
 
    'effectue la recherche des numéros de factures correspondant
    'au code ville et à l'année
    Set Cel = Plage.Find(CodeVille & Annee & "*", , xlValues, xlPart)
 
    'si trouvé, stocke dans un tableau toutes les factures
    If Not Cel Is Nothing Then
 
        Adr = Cel.Address
 
        Do
 
            I = I + 1
 
            ReDim Preserve TblFacture(1 To I)
 
            'récup des 4 chiffres à droite
            TblFacture(I) = Right(Cel, 4)
 
            Set Cel = Plage.FindNext(Cel)
 
        Loop While Adr <> Cel.Address
 
    End If
 
    'retourne le numéro à utiliser pour la prochaine facture
    MaxNumFacture = WorksheetFunction.Large(TblFacture(), 1) + 1
 
    Set Cel = Nothing
    Set Plage = Nothing
 
End Function

Hervé.

[Kalawaya]

Merci à vous, j'ai introduit l'une de vos macros puis fait quelques ajustements et je vais enfin pouvoir facturer des millions de dollars... merci!