[DATA] Modifier la présentation d'un jeu de donnée [Résolu]

[bailliblaire]

Salut à tous , je suis un peu nouveau avec la programmation sas , es ce que quelqu'un pourrait m'aider avec un programme sas me permettant de passer de la table A à la table B, la variable T est numérique et les autres sont alpha-numériques
merci d'avance

Table A
X Y Z T
1 I a 4
1 I b 5
2 III C 1
2 III H 3
2 III E 4
3 II s 8
3 II u 7

Table B

X Y Z T
1 I a, b 9
2 III c,h,e 8
3 II s, u 15

[olivier.decourt]

Bonjour Blaire.
Je te propose de travailler en 3 temps : d'abord deux transpositions de tes variables Z et T, séparément l'une de l'autre, puis une jointure des 2 tables transposées, au cours de laquelle tu pourras fusionner les valeurs (texte avec CATX et numériques avec SUM).

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
DATA work.tableA ;
  INPUT X $ Y $ Z $ T ;
DATALINES ;
1 I a 4
1 I b 5
2 III C 1
2 III H 3
2 III E 4
3 II s 8
3 II u 7
;
RUN ;
PROC TRANSPOSE DATA=work.tableA OUT=work.tableA1 PREFIX=T ;
  VAR t ;
  BY x y ;
RUN ;
PROC TRANSPOSE DATA=work.tableA OUT=work.tableA2 PREFIX=z ;
  VAR z ;
  BY x y ;
RUN ;
DATA work.tableB (KEEP=x y z t) ;
  MERGE work.tableA1
        work.tableA2 ;
  BY x y ;
  z = CATX(",", OF z1-z3) ;
  t = SUM(OF t1-t3) ;
RUN ;

Bon courage.
Olivier

[olivier.decourt]

Il y a aussi plus rapide, mais je trouve cette solution moins évidente : en une seule étape DATA, on cumule au fur et à mesure les valeurs de T et Z dans de nouvelles variables. Les fonctions utilisées sont les mêmes que précédemment, CATX et SUM. Mais ce qui change, ce sont :
* les FIRST et LAST (disponibles grâce au BY) qui indiquent si on commence ou termine un bloc de valeurs de X*Y
* l'instruction OUTPUT qui écrit le contenu de la mémoire dans la table en sortie (quand OUTPUT est explicite, l'écriture n'intervient que quand la condition est vraie. Quand OUTPUT est implicite, chaque observation est écrite dans la table en sortie)
* le RETAIN qui protège les variables de cumul et évite qu'on perde leurs valeurs d'une ligne à une autre
* le CALL MISSING pour initialiser les variables à chaque nouveau bloc
* le LENGTH qui permet d'indiquer à SAS le type (présence d'un $ = texte) et le nombre d'octets à réserver pour stocker une valeur des nouvelles variables.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
DATA work.tableA ;
  INPUT X $ Y $ Z $ T ;
DATALINES ;
1 I a 4
1 I b 5
2 III C 1
2 III H 3
2 III E 4
3 II s 8
3 II u 7
;
RUN ;
DATA work.tableB (DROP=z t 
                RENAME=(zCum=z tCum=t)) ;
  SET work.tableA ;
  BY x y ;
  LENGTH zCum $ 200
         tCum 8 ;
  RETAIN zCum tCum ;
  IF FIRST.y THEN CALL MISSING(zCum, tCum) ;
  zCum=CATX(",",zCum,z) ;
  tCum=SUM(tCum,t) ;
  IF LAST.y THEN OUTPUT ;
RUN ;

[bailliblaire]

Salut Olivier, tu es un as!
Un gros merci, tu viens de me sauver du temps , tes deux solutions roulent, les deux programmes sont parfaits pour moi
à plus