[XL-2007] combinaison des fonctions si ou et sommeprod [Résolu]

[Iichham]

bonjour

j'ai besoin de votre aide
je veux faire une condition sur les valeurs de la colonne H pour que si elles sont egales à "achat", "liquidation","sortie de fonds", "liquidation total" -et cela autant de fois que ces valeurs se répètent- faire la somme des montants de la colonne M (cellules correspondantes) et cela si les dates qui sont dans F sont entre le debut et la fin du mois de juin

j'ai essayé :

Code :

=Si(ou(H2:H60="achat";H2:H60="liquidation";H2:H60="sortie de fonds";H2:H60="liquidation total");sommeprod((F2:F60>=Date(2011;6;1))*(F2:F60<=date(2011;6;30))*(M2:M60));"")

malheureusement ça ne marche pas ...

[philo6]

Bonjour
Tu peux tester cela?

Code :

=SI(SOMMEPROD((H2:H60="achat")+(H2:H60="liquidation")+(H2:H60="sortie de fonds")+(H2:H60="liquidation total"));SOMMEPROD((F2:F60>=DATE(2011;6;1))*(F2:F60<=DATE(2011;6;30))*(M2:M60));"")

[corona]

Bonjour,
Pour cela, tu peux utiliser la formule SOMMEPROD Les additions sont les OU, les multiplications les ET.
Voici un petit exemple à adapter à ton cas

Code :

=SOMMEPROD(((($A$2:$A$7="Achat")+($A$2:$A$7="Liquidation"))>0)*((MOIS($B$2:$B$7)=6)*($C$2:$C$7)))

En colonne A les libellés, en B des dates, en C les montants
Ici dans l'exemple on fait la somme de la colonne C si Achats ou Liquidation dont la date est au mois de juin

[Iichham]

en fait si j'ai ajouté une autre condition : par exemple dans la colonne E il faut que j'ai comme valeur "complet", j'ai repris l'exemple précedant :

Code :

1
2
 
=SOMMEPROD(($E$2:$E$7="complet")*((($A$2:$A$7="Achat")+($A$2:$A$7="Liquidation"))>0)*((MOIS($B$2:$B$7)=6)*($C$2:$C$7)))

mais ça donne rien,

[corona]

Bonjour,
Ne pas mélanger les OU et les ET

Code :

=SOMMEPROD(  ( ( (condit1) + (condit2) + (condit3) )>0) * (condit4) * (condit5) * (plageASommer) )

Ce qui est souligné, c'est l'ensemble des OU qui se termine par >0 qui renverra VRAI (soit 1)
UN peu de lecture sur le sujet