[XL-2003] Création classeur + feuille + copie

[tioch]

Bonjour à tous,

Alors voila j'aimerai réaliser une macro avec plusieurs étapes. Le projet est le suivant.
En appuyant sur un bouton :
- créer un nouveau classeur
- nommer ce nouveau classeur en fonction de cellules définies
- enregistrer ce classeur dans "Documents and settings"
- copier la feuilleoùu se trouve le bouton dans le nouveau classeur
- supprimer des lignes et des cellules et des boutons dans cette nouvelle feuille créée.
Tout cela dans une seule et meme macro.
Donc si vous avez des idées pour tout ou au moins me donner des pistes pour chaque partie ca serait cool.
Merci bien d'avance

Tioch

[tioch]

J'ai vu la piste

Code :

1
2
Workbooks.Add
ActiveWorkbook.SaveAs "C:\Documents and Settings"

Pour les premières étapes mais ca ne marche pas pour la sauvegarde.
Est-ce parce que c'est mal écrit?
Merci encore

[mercatog]

Fais un F1 sur SaveAs et regarde ton erreur.

Sinon, ci joint proposition à adapter en lisant bien les commentaires

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Sub TEST()
Dim Chemin As String, NomFichier As String
Dim Sh As Shape
 
Application.ScreenUpdating = False
Chemin = "C:\Users\user\Documents"                                                                 'à adapter
With ThisWorkbook.Worksheets(1)
    NomFichier = .Range("C1")                                                                      'En C1, nom du fichier
    .Copy
End With
With ActiveWorkbook
    With .Worksheets(1)
        .Rows(1).Delete                                                                            'On supprime le ligne 1
        .Columns("A:B").Delete                                                                     'On supprime les colonnes A et B
        For Each Sh In .Shapes                                                                     'on supprime toutes les shapes
            Sh.Delete
        Next Sh
    End With
    Application.DisplayAlerts = False                                                              'au cas où le fichier portant le même nom existe déjà
    .SaveAs Chemin & "\" & NomFichier                                                              'on enregistre dans le chemin sous nomfichier
    Application.DisplayAlerts = True
End With
End Sub

[jfontaine]

Bonjour,

Il te restera à faire la suppression des lignes et objets de ta la feuille copié

Code :

1
2
3
4
5
6
Dim wrk As Workbook
 
Set wrk = Application.Workbooks.Add
Sheets("Feuil2").Copy wrk.Sheets(1)
 
wrk.SaveAs Environ("USERPROFILE") & "\" & Range("A1").Value

[tioch]

Vraiment un grand merci pcq ca marche très très bien.
Est-ce que je peux demander encore plus?
Je voudrais pour les lignes à supprimer, ne supprimer que les lignes cachées.

Et j'ai un problème dans le codage pcq il dit que j'ai des cellules (une seule dans mon cas) qui dépasse 255 caractères du coup il ne peut pas copier la feuille. Il me propose donc plutot de copier les cellules. Est ce la bonne solution et comment le faire?

Encore merci ca me fait avancer beaucoup plus vite

Tioch