[XL-2003] SommeProd une condition bloque [Résolu]

[debdev]

Bonsoir à tous,

Depuis hier, je bloque sur une formule, pourtant adaptée d'une autre qui fonctionne bien !

Si je tape la formule suivante, ça marche:

Code :

1
2
3
4
5
6
7
8
9
=SOMMEPROD(
 (TEXTE(DECALER('CExcel'!$B$2;0;0;NBVAL('CExcel'!$B:$B)-1;1);"mmmm")=$D40)
*
 (TEXTE(DECALER('CExcel'!$B$2;0;0;NBVAL('CExcel'!$B:$B)-1;1);"aaaa")=$C40)
*
 (GAUCHE(DECALER('CExcel'!$N$2;0;0;NBVAL('CExcel'!$N:$N)-1;1);1)="C")
*
 1
)

Mais si j'ajoute une condition, ça ne marche plus, ça me met #N/A:

Code :

1
2
3
4
5
6
7
8
9
10
11
=SOMMEPROD(
 (TEXTE(DECALER('CExcel'!$B$2;0;0;NBVAL('CExcel'!$B:$B)-1;1);"mmmm")=$D40)
*
 (TEXTE(DECALER('CExcel'!$B$2;0;0;NBVAL('CExcel'!$B:$B)-1;1);"aaaa")=$C40)
*
 (GAUCHE(DECALER('CExcel'!$N$2;0;0;NBVAL('CExcel'!$N:$N)-1;1);1)="C")
*
 (DECALER('CExcel'!$Y$2;0;0;NBVAL('CExcel'!$Y:$Y)-1;1)="ABC")
*
 1
)

La ligne en gras qui pose problème a été testée avec:
- la colonne Y
- la colonne X
- la colonne U

La colonne Y est de format standard.
La colonne Y est un paste special values de la colonne X.

La colonne X est de format standard.
La colonne X est un texte(U;0) de la colonne U.

La colonne U est de format standard.
La colonne U est un mix d'index et equiv.


J'espère être assez claire. Je vous remercie pour votre aide.

[alsimbad]

la seule difference que je vois dans ton rajout, c'est texte ou gauche. as tu essayer de rajouter ça pour voir?
mais en fait, ce qui doit bloquer, c'est le nombre de valeur de chaque colonne, si il est differend, sommeprod ne fonctionne pas. pour eviter ça, prend le nbval toujour sur la même colonne, dans ton cas, a priori la colonne B comme dans les deux premieres conditions

[debdev]

EXCELLENT !!!!!!!!!!


Le problème n'était pas Gauche ou Texte que j'avais déjà testé mais effectivement nbval. Je savais qu'il fallait le meme nombre de valeurs dans chaque colonne de sommeprod mais j'avais pas fait gaffe à ma colonne posant problème: j'avais tiré une formule jusqu'à très très loin (plus loin que les autres colonnes).

Un grand merci à toi.
J'ai passé des heures sur ce problème depuis hier, tu me sauves !
Bonne soirée.