Problème création de macrovariables dans une boucle [Résolu]

[Misspatate]

Bonjour

J'ai un petit problème avec des macro-variables créées par des call symput qui se trouvent elles-mêmes dans des macros...
Normalement, si elles sont créées ainsi, il n'y a pas de soucis pour les réutiliser hors de la macro. Le problème que j'ai constaté, est que lorsqu'elles sont créées dans une boucle, elles ne peuvent être utilisées hors de la macro.

Voici mon code qui a pour but de récupérer les moyennes de mes données.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
DATA theta;
	input compteur1 lambdat;
	cards;
	1 2
	2 4
	3 6 
	4 8
	5 10
	6 12
	7 14
	8 16
	9 18
 
	;
run;
proc means DATA=theta noprint;
	class compteur1;
	var lambdat;
	output out=moy mean=moy;
run;
%macro macrovar();
	DATA _null_;
		SET moy;
		IF _n_=1 then call symput("esp",moy);
		call symput("nb",_n_-1);
	run;
	DATA _null_;
		SET moy;
		%do i=2 %TO &nb.;
			IF _n_=&i. then call symput("esp"||LEFT(_n_-1),moy);
		%end;
	run;
	%put &esp1.;
	%put &esp2.;
	%put &esp3.;
	%put &esp4.;
%mend;
%macrovar();
/*Ces macrovariables ne fonctionnent pas :(*/
%put &esp1.;
%put &esp2.;
%put &esp3.;
%put &esp4.;
/*Mais ces deux là fonctionnent!*/
%put &esp.;
%put &nb.;

Je vous remercie pour votre aide

Bonne journée!!

[s_a_m]

Hello,
beaucoup d'anomalies dans ton programme.
il faut procéder par étape.

j te donne un exemple, essaies de t'inspérer:

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
 
%macro test;
 
DATA _null_;
SET sashelp.class end=fin;
IF fin then call symput ('nb', _n_);
call symput   ('age' !!LEFT(_n_),age);
run;
 
%do i=1 %TO &nb;
%put l age de la ligne numéro &i est de : &&age&i.;
%end; 
 
 
%mend;
 
%test;

[datametric]

C'est ce que tu veux ?

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
OPTION mprint;
%macro macrovar;
DATA _null_;
SET moy;
IF _n_=1 then call symputx("esp",moy);
call symput("nb",_n_-1);
run;
DATA _null_;
SET moy;
IF _n_ > 1 then call symputx(cats('esp',_n_-1),moy);
 
run;
 
%mend;
%macrovar;
 
%put _user_;

[Misspatate]

Wouhou! Merci

En m'inspirant de vos deux codes, j'ai fait :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
%macro macrovar();
	DATA _null_;
		SET moy;
		IF _n_=1 then call symput("esp",moy);
		IF _n_>1 then call symput("esp"||LEFT(_n_-1),moy);
		call symput("nb",_n_-1);
	run;
%do i=1 %TO &nb;
%put &&esp&i.;
%end; 
%mend;
%macrovar();

Quelle est la différence entre différence entre "call symput" et "call symputx"?

[s_a_m]

call symputx alligne les macro variables à gauche. Uniquement en V9.

[olivier.decourt]

Le 2e intérêt de CALL SYMPUTX par rapport à CALL SYMPUT est de permettre d'indiquer si une macro-variable est globale (= utilisable en dehors du macro-programme où elle est créée) ou locale (cantonnée au macro-programme et détruite en fin d'exécution du MP).

Code :

1
2
3
4
5
6
7
8
9
10
11
12
%macro macrovar();
	DATA _null_;
		SET moy;
		IF _n_=1 then call symputX("esp",moy,"G");
		IF _n_>1 then call symputX("esp"||LEFT(_n_-1),moy,"G");
		call symput("nb",_n_-1);
	run;
%do i=1 %TO &nb;
%put &&esp&i.;
%end; 
%mend;
%macrovar();

Et comme ça tu peux utiliser &esp, &esp1, &esp2 après l'exécution du macro-programme %MACROVAR.

[Misspatate]

Super! Merci, je ne savais pas qu'on pouvait les déclarer ainsi en global!

[datametric]

Je te rassure elles l'étaient déjà.

Voici un test pour t'en assurer.

Code :

1
2
3
4
5
6
7
8
9
%symdel memoire;
%macro test;
DATA _null_;
SET sashelp.class;
call symputx('memoire',_n_);
run;
%mend;
%test;
%put memoire=&memoire;

[s_a_m]

par défaut, avec le CALL SYMPUT les macro variables sont GLOBAL.

Code :

1
2
3
4
5
6
7
8
 
DATA _null_;
SET sashelp.class;
call symput ('n',_n_);
call symput ('var'!!LEFT(_n_),age);
run;
 
%put _global_;

[olivier.decourt]

Stéphane, SAM, en fait les macro-variables créées dans une étape DATA (CALL SYMPUT ou SYMPUTX) ne sont pas systématiquement globales par défaut. La règle est en effet la suivante (je simplifie un chouia) :

• si la table des macro-variables locales est vide, CALL SYMPUT(X) crée une MV globale
• s'il y a au moins une MV locale, CALL SYMPUT(X) créera une MV aussi locale

Attention, une proc SQL crée systématiquement plusieurs MV locales quand on est dans un macro-programme. D'où des résultats comme

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
%MACRO test ;
  PROC SQL ;
    CREATE TABLE work.toto AS 
	  SELECT *
	  FROM sashelp.class ;
	DROP TABLE work.toto ;
  QUIT ;
  DATA _NULL_ ;
    SET sashelp.class NOBS=nobs ;
	CALL SYMPUTX("n",nobs) ;
	STOP ;
  RUN ;
%MEND ;
%test ;
%PUT &n ;

Si au lieu du SQL on fait un %LET, même problème.
D'où mon conseil de profiter de CALL SYMPUTX pour bien clarifier la portée des macro-variables qu'on crée : "G" pour global, "L" pour local, et éviter d'être à la merci de ce genre de règles à la !

[s_a_m]

Merci Olivier.
Personnellement j'ai toujours utilisé le %GLOBAL et %LOCAL pour référer mes macros.
C’est vrai qu'avec le Call SYMPUX c'est encore plus simple à coder et à déterminer le champs d’exécution de nous macro variables. Et oui il faut vivre avec son époque.