[AC-2003] Exporter un état vers Excel

[Williamm]

Bonjour,

Je souhaite exporter un état vers excel de maniere automatique. J'ai trouvé ce code VBA qui permet d'exporter une table.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
Function TransfertExcelAutomation()
 
    Dim xlApp As Excel.Application
    Dim xlSheet As Excel.Worksheet
    Dim xlBook As Excel.Workbook
    Dim I As Long, J As Long
    Dim t0 As Long, t1 As Long
 
    t0 = Timer
    Dim rec As Recordset
 
    Set rec = CurrentDb.OpenRecordset("Nom table", dbOpenSnapshot)
 
    'Initialisations
    Set xlApp = CreateObject("Excel.Application")
    Set xlBook = xlApp.Workbooks.Add
 
    'Ajouter une feuille de calcul
    Set xlSheet = xlBook.Worksheets.Add
    xlSheet.Name = "Horraire"
 
    ' le titre
    '  écriture dans la cellule de ligne 1 et de colonne 1
    xlSheet.Cells(1, 1) = "Export du planning LC"
 
 
    ' les entetes
    '  .Fields(Index).Name renvoie le nom du champ
    For J = 0 To rec.Fields.Count - 1
        xlSheet.Cells(2, J + 1) = rec.Fields(J).Name
        ' Nous appliquons des enrichissements de format aux cellules
        With xlSheet.Cells(2, J + 1)
            .Interior.ColorIndex = 15
            .Interior.Pattern = xlSolid
            .Borders(xlEdgeBottom).LineStyle = xlContinuous
            .Borders(xlEdgeBottom).Weight = xlThin
            .Borders(xlEdgeBottom).ColorIndex = xlAutomatic
            .HorizontalAlignment = xlCenter
        End With
    Next J
 
    ' recopie des données à partir de la ligne 3
    I = 3
    Do While Not rec.EOF
        For J = 0 To rec.Fields.Count - 1
            ' .Fields(Index).Type renvoie le type du champ
            '   si c'est un Texte (dbText) nous insérons "'" pour
            '   qu'il soit reconnu par Excel comme du Texte
            If rec.Fields(J).Type = dbText Then
                xlSheet.Cells(I, J + 1) = "'" & rec.Fields(J)
            Else
                xlSheet.Cells(I, J + 1) = rec.Fields(J)
            End If
        Next J
        I = I + 1
        rec.MoveNext
    Loop
 
    ' code de fermeture et libération des objets
    xlBook.SaveAs "C:\Excel import\Planning.xls"
    xlApp.Quit
    rec.Close
    Set rec = Nothing
    Set xlSheet = Nothing
    Set xlBook = Nothing
    Set xlApp = Nothing
 
    t1 = Timer
    Debug.Print I & " enregistrements", Format(t1 - t0, "0") & " secondes"
 
End Function

Je pensais qu'en remplaçant "Nom table" par un état, l'exportation se ferait mais ce n'est pas le cas.
Quelqu'un aurait t-il une solution pour se faire?
Merci

[jpcheck]

salut,

un etat etant au final un formulaire fige, je ne comprends pas l'export vers Excel...

Peux-tu nous en dire un peu plus sur ce que tu souhaites faire de cet etat dans Excel stp ?

[Williamm]

Mon état représente en fait un planning d'effectif qui évolue donc en fonction des jours (car certain employé prenne des congés).

Ce planning ou plutôt son contenu doit alimenter un fichier excel qui donne le nombre de personne présente.

Je sais pas s'il y a d'autres solutions mais du coup je pensais exporter mon planning en format excel pour faciliter les liens entres les différents fichier excel.

Edit: Effectivement, je ne sais pas pourquoi je me suis entêté à vouloir exporter l'état en lui même. J'y pensais pas mais c'est en fait plus simple d'exporter la requête qui est la source de l'état.

Es tu d'accord Jpcheck ?

[jpcheck]

C'est exactement la solution que je pensais te proposer