filesearch access 2007 [Résolu]

[myriame]

Bonjour tous le monde !

Après de multiple recherche, je n'arrive toujours pas à résoudre mon problème, c'est-à-dire remplacer le filesearch qui fonctionne sous access 2003 et non sous access 2007 ! N'y aurait-il pas une solution simple à ce problème ?

[loufab]

Bonjour,

Il y a le Filedialog avec la bibliothèque Microsoft Office 12.0 Object Library.
L'api windows également qui fonctionne quelque soit la version.

regarde dans la faq il y a des exemples.

Cordialement,

[myriame]

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
REPERTOIRE = Me.import 'définie le réperoire où se trouve le document
'----------------------------------------------------------------------------------------------------------------------------------
'recherche les fichiers correspondant au code actif sur le formulaire
Me.NomDocument.RowSource = ""
Me.NomDocument.Value = "Sélectionner le fichier"
With Application.FileDialog
    .NewSearch
    .LookIn = REPERTOIRE
    .SearchSubFolders = False
    .FileName = "abc_"
    .MatchTextExactly = False
End With
'----------------------------------------------------------------------------------------------------------------------------------
With Application.FileSearch
    If .Execute() > 0 Then
        For i = 1 To .foundfiles.Count
            AdresseFichier = .foundfiles(i) 'AdresseFichier = explorateur Windows
            Me.NomDocument.RowSource = StrConv(Right(AdresseFichier, Len(AdresseFichier) - Len(REPERTOIRE)) & ";" & Me.NomDocument.RowSource, vbUpperCase)
 
        Next i
'----------------------------------------------------------------------------------------------------------------------------------
    Else
        MsgBox "Aucun fichier trouvé."
    End If
 
End With

voilà mon code de départ, quand je remplace

Code :

filesarch

par

Code :

filedialog

sa ne me donne pas le résultat attendu!

[Orakle]

Salut,

moi j'ai ça qui fonctionne pour 2003 et 2007
C'est du VBE mais c'est du pareil au même.

en modifiant ce qu'il faut tu devrais arriver à tes fins!!

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
 
    wwFichierTarifs = InputBox("Nom du fichier tarifs à intégrer ", "Mise à jour des tarifs")
 
    If Not wwFichierTarifs = "" Then
        repertoire = ThisWorkbook.Path
        wwFichierTarifs = wwFichierTarifs
        With Application.FileSearch
            .LookIn = repertoire & ".xls"
            .Filename = wwFichierTarifs
                If .Execute > 0 Then 'Workbook existe
                    Workbooks.Open Filename:=repertoire & "\" & wwFichierTarifs & ".xls"
                    MAJTarifs
                Else
                    MsgBox wwMSG(5) & " " & wwFichierTarifs   
                End If
        End With
    End If

[Philippe JOCHMANS]

Bonjour

Regardes là : http://access.developpez.com/faq/?page=FD

Philippe

[myriame]

j'utilise vba sous access 2007, utiliser vbe c'est possible ? si oui comment ?

[loufab]

VBE veut dire Visual Basic Editor. C'est l'éditeur que tu utilises pour écrire le code VBA (Visual Basic Application).

Je ne sais pas pourquoi Orakle à écrit ça :

C'est du VBE mais c'est du pareil au même.

L'un est un éditeur l'autre un langage.

[Philippe JOCHMANS]

Re

Loufab t'a donné l'explication.

Orakle t'a donnée un code qui fonction sous Excel.

Je te conseille d'aller voir du coté du lien que je t'ai donné qui est ce que t'expliquait Loufab.

Philippe

[Arkham46]

bjr,

filedialog peut-il vraiment remplacer filesearch? ce n'est pas pour moi la même fonctionnalité

quand au code de Orakle, c'est du code qui utilise la méthode filesearch qui justement ne fonctionne pas sous 2007

je ne comprend pas tout

vous me dites si je me trompe

sinon pour remplacer filesearch, il y a des idées à prendre ici :
http://silkyroad.developpez.com/vba/classefilesearch/
c'est du excel mais ça a bien pour vocation de remplacer filesearch

pensez aussi à cherchez sur le support microsoft :
http://support.microsoft.com/kb/935402/fr

et sur le forum (il y a bien évidemment d'autres personnes qui ont déjà eu ce problème)

[myriame]

je suis d'accord, filedialog n'a pas les même fonction que fiilesearch! pour information le code que j'avais écrit sous Access 2003 me servait à rechercher dans un répertoire donné tous les fichiers commencant par "abc" est de les inscrire dans la zone de liste modifiable!

j'ai regarder le liens que vous m'avez fournit mais je ne comprend pas

[LedZeppII]

Bonjour,

Voici un exemple de recherche simple avec la fonction VBA Dir(..)

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Dim arrFiles() As String, lFilesCnt As Long, l As Long
Dim REPERTOIRE As String, strCriteria As String
Dim strFichier As String
 
' Dossier où chercher
REPERTOIRE = "C:\G\Ops"
' Critère de recherche = Dossier & "\" & "critère nom fichier"
strCriteria = REPERTOIRE & "\" & "E*.zip"
' Recherche
strFichier = Dir(strCriteria, vbNormal)
lFilesCnt = 0
Do While Len(strFichier) > 0
   lFilesCnt = lFilesCnt + 1
   ReDim Preserve arrFiles(0 To lFilesCnt - 1)
   arrFiles(lFilesCnt - 1) = strFichier
   ' Fichier suivant
   strFichier = Dir()
Loop
' S'il y au moins un fichier trouvé
If lFilesCnt > 0 Then
   For l = LBound(arrFiles) To UBound(arrFiles)
       Debug.Print arrFiles(l)
   Next
End If

Dans cet exemple on recherche les fichiers E*.zip dans le dossier C:\G\Ops

A+

[myriame]

une question : a quel moment dit on dans le code que les fichier trouvé commençant par "e" doivent etre présent dans la zone de liste modifiable ?

[myriame]

sa ne fonctionne toujours pas quand j'utilise dir, sa me renvoye rien du tous

[LedZeppII]

D'après le 1er code que ta as posté, ça devrait ressembler à

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Dim arrFiles() As String, lFilesCnt As Long, l As Long
Dim REPERTOIRE As String, strCriteria As String
Dim strFichier As String
 
' Dossier où chercher
REPERTOIRE = Me.import 'définie le réperoire où se trouve le document
' Critère de recherche = Dossier & "\" & "critère nom fichier"
strCriteria = REPERTOIRE
if Right(strCriteria, 1) <> "\" Then strCriteria = strCriteria & "\"
strCriteria = strCriteria & "abc_*.*"
' Recherche
strFichier = Dir(strCriteria, vbNormal)
lFilesCnt = 0
Do While Len(strFichier) > 0
   lFilesCnt = lFilesCnt + 1
   ReDim Preserve arrFiles(0 To lFilesCnt - 1)
   arrFiles(lFilesCnt - 1) = strFichier
   ' Fichier suivant
   strFichier = Dir()
Loop
' S'il y au moins un fichier trouvé
If lFilesCnt > 0 Then
   For l = LBound(arrFiles) To UBound(arrFiles)
       AdresseFichier = arrFiles(l) 'AdresseFichier = explorateur Windows
       Me.NomDocument.RowSource = StrConv(Right(AdresseFichier, Len(AdresseFichier) - Len(REPERTOIRE)) & ";" & Me.NomDocument.RowSource, vbUpperCase)
   Next
Else
   MsgBox "Aucun fichier trouvé." 
End If

A+

[myriame]

MERCI MERCI MERCI MERCIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIII

[Orakle]

Désolé pour le coup du VBE, c'est une déformation chez moi pour parler de VB pour Excel.

[loufab]

C'est ce que j'ai compris à la relecture.

[myriame]

GRAND PROBLEME le programme effectue bien une recherche mais renvoie que une partie du nom du fichier rechercher, c'est-à-dire au lieu de récupérer "abc0101" je vais plutôt avoir "0102" voir quelque fois"102"!!!
A quoi est ce du ?

[LedZeppII]

Bonjour,

ça doit venir de cette ligne

Code :

       Me.NomDocument.RowSource = StrConv(Right(AdresseFichier, Len(AdresseFichier) - Len(REPERTOIRE)) & ";" & Me.NomDocument.RowSource, vbUpperCase)

Dir(..) renvoie un nom de fichier sans le chemin.
Essaie en la remplaçant par

Code :

       Me.NomDocument.RowSource = StrConv(AdresseFichier, vbUpperCase) & ";" & Me.NomDocument.RowSource

A+