[AC-2007] Envoyer un mail d'Access via gmail ? [Résolu]

gsacre · 14/06/2011, 13h49

Bonjour à tous,

Je souhaiterais créer dans ma BD un bouton permettant d'envoyer par mail (via gmail, obligation professionnelle !!) en fichier joint un état en pdf.
Est-ce possible ?
Je débute un peu en access et maitrise encore peu le langage vba...

Chouette forum en tout cas.

Merci d'avance pour votre aide...

LedZeppII · 14/06/2011, 20h08

Bonjour,

Pour exporter en pdf, ça dépend de la version d'Access.

Pour envoyer un email par gmail, voici un exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
' ---------------------------------------------------------
' Email html par Gmail
' ---------------------------------------------------------
Function TestCDOsys_2()
' Microsoft CDO Library for windows 2000
Dim MyMail As CDO.Message
Dim cdoConf As CDO.Configuration
' SMTP GMAIL
Const strSMTPserver = "smtp.gmail.com"
Const strSMTPport = 465
Const strMailUserName = "monAdresse@gmail.com"
Const strMailUserPwd = "mon-mot-de-passe"
 
' Crée un nouvel objet email
Set MyMail = New CDO.Message
' Émetteur (Facultatif)
MyMail.From = """Mon Nom"" <monAdresse@gmail.com>"
' Destinataire
MyMail.To = """Nom Destinataire"" AdresseDestinataire@domaine.com"
' Sujet
MyMail.Subject = "Test CDOSYS"
' Copies (Facultatif)
'MyMail.CC = CopieCarbonne
'MyMail.BCC = CopieCarbonneCachee
 
' Message HTML
'   En-tête du message HTML
MyMail.HTMLBody = _
"<html><head></head><body>"
'   Message
MyMail.HTMLBody = MyMail.HTMLBody & _
"Bonjour" & "<br>" & vbCrLf & "Comment ça va ?<br>" & vbCrLf & _
"<br>" & vbCrLf & _
"<a href=""http://www.developpez.net/forums/d1095248/logiciels/microsoft-office/access/envoyer-mail-daccess-via-gmail/"">Envoyer un mail d'Access via gmail</a><br>" & vbCrLf
'   Fin du message HTML
MyMail.HTMLBody = MyMail.HTMLBody & _
"</body></html>"
 
' Fichier(s) à attacher
'MyMail.AddAttachment "C:\WINDOWS\dsofile.txt"
'MyMail.AddAttachment "C:\WINDOWS\Rhododendron.bmp"
 
' Configuration méthode d'envoie
Set cdoConf = MyMail.Configuration
'   Choix de la méthode d'envoie
'       cdoSendUsingPort   : SMTP à travers le réseau
'                            il faut renseigner cdoSMTPServer et cdoSMTPServerPort
'       cdoSendUsingPickup : Service SMTP local
cdoConf.Fields(CDO.CdoConfiguration.cdoSendUsingMethod) = CDO.CdoSendUsing.cdoSendUsingPort
'   Nom serveur SMTP
cdoConf.Fields(CDO.CdoConfiguration.cdoSMTPServer) = strSMTPserver
'   Port serveur SMTP
cdoConf.Fields(CDO.CdoConfiguration.cdoSMTPServerPort) = strSMTPport
'   Activation SSL True.False
cdoConf.Fields(CDO.CdoConfiguration.cdoSMTPUseSSL) = True
 
' Nom et mot de passe de l'utilisateur se connectant au serveur SMTP
cdoConf.Fields(CDO.CdoConfiguration.cdoSendUserName) = strMailUserName
cdoConf.Fields(CDO.CdoConfiguration.cdoSendPassword) = strMailUserPwd
 
cdoConf.Fields.Update
 
' Envoyer l'email
MyMail.Send
 
End Function

Dans ces lignes ...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Const strMailUserName = "monAdresse@gmail.com"
Const strMailUserPwd = "mon-mot-de-passe"

il faut remplacer monAdresse@gmail.com et mon-mot-de-passe par les valeurs utilisées pour ouvrir Gmail.

A+

gsacre · 14/06/2011, 23h39

Merci, je teste demain.

Je suis sous access 2007.

LedZeppII · 17/06/2011, 13h52

Bonjour,

Sous Access 2007 on peut exporter un état en pdf comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

DoCmd.OutputTo acOutputReport, "Nom de l'etat", acFormatPDF, "C:\Test1.pdf"

Si ça ne fonctionne pas c'est qu'il manque le complément.
Voir Access 2007 et les fichiers PDF, pour l'installer.

A+

gsacre · 05/07/2011, 10h37

GRAND MERCI pour votre aide.

CELA FONCTIONNE

14/06/2011, 13h49	#1
gsacre Invité régulier Inscription : juin 2011 Messages : 34 Détails du profil Informations personnelles : Sexe : Localisation : Belgique Informations forums : Inscription : juin 2011 Messages : 34 Points : 5 Points : 5	Envoyer un mail d'Access via gmail ? Bonjour à tous, Je souhaiterais créer dans ma BD un bouton permettant d'envoyer par mail (via gmail, obligation professionnelle !!) en fichier joint un état en pdf. Est-ce possible ? Je débute un peu en access et maitrise encore peu le langage vba... Chouette forum en tout cas. Merci d'avance pour votre aide...
	00

17/06/2011, 13h52	#4
LedZeppII Rédacteur Maintenance données produits Inscription : décembre 2005 Messages : 3 939 Détails du profil Informations personnelles : Sexe : Localisation : France, Yvelines (Île de France) Informations professionnelles : Activité : Maintenance données produits Secteur : Distribution Informations forums : Inscription : décembre 2005 Messages : 3 939 Points : 6 278 Points : 6 278	Bonjour, Sous Access 2007 on peut exporter un état en pdf comme ceci : Code : Sélectionner tout - Visualiser dans une fenêtre à part DoCmd.OutputTo acOutputReport, "Nom de l'etat", acFormatPDF, "C:\Test1.pdf" Si ça ne fonctionne pas c'est qu'il manque le complément. Voir Access 2007 et les fichiers PDF, pour l'installer. A+
	10

14/06/2011, 23h39	#3
gsacre Invité régulier Inscription : juin 2011 Messages : 34 Détails du profil Informations personnelles : Sexe : Localisation : Belgique Informations forums : Inscription : juin 2011 Messages : 34 Points : 5 Points : 5	Merci, je teste demain. Je suis sous access 2007.
	00

05/07/2011, 10h37	#5
gsacre Invité régulier Inscription : juin 2011 Messages : 34 Détails du profil Informations personnelles : Sexe : Localisation : Belgique Informations forums : Inscription : juin 2011 Messages : 34 Points : 5 Points : 5	GRAND MERCI pour votre aide. CELA FONCTIONNE
	00

Outils de la discussion
Afficher une version imprimable Envoyer un lien vers cette page par email