[AC-2003] Ajouter un filtre dans une fonction d'ouverture de fichier [Résolu]

[Orakle]

Bonjour à tous,

je me suis procuré cette fonction dans la FAQ pour aller chercher un fichier à importer dans ma db.
Tout fonctionne parfaitement, je voudrais juste filtrer sur le nom de fichier à récupérer.

Les paramètre de cette fonction une fois renseignés me donne cette boite de dialogue:



Le titre de la boite me convient
Le type de fichier aussi
Je voudrais simplement forcer le "Nom du fichier" en fonction du choix de mon clic bouton

un bout de code pour montrer les paramètres déjà en place

Code :

1
2
3
4
5
6
7
Private Sub EtqCompany_Click()
 
'on passe le nom du fichier à importer dans une variable
FiltreFichier = TxtTitreTable.Value
'fait appel à une fonction (OuvrirUnFichier) pour ouvrir une bte de dialogue ouvrir
'pour aller chercher le fichier xls qui nous interesse pour import
xlsPath = OuvrirUnFichier(Application.hWndAccessApp, FiltreFichier, 1, "Excel File", "xls")

Je pense que je dois ajouter un paramètre dans la fonction, mais comment...?

Merci de votre aide

ps: j'ai oublié un détail qui a son importance comme vous le constatez dans la boite de fichier ouvrir, vous avez un fichier nommé "Company_LCSL" mais ce n'est pas toujours le même (je peux aussi vouloir importer le fichier "Company_xxx") donc il faudrait que ça filtre sur une partie du nom.
2eme point : ce qui est valable pour Company est aussi valable pour les autres, à savoir (Contact, ParcMachines, Project,...)

[LedZeppII]

Bonsoir,

voici une adaptation possible :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
'Déclaration de l'API
Private Declare Sub PathStripPath Lib "shlwapi.dll" Alias "PathStripPathA" (ByVal pszPath As String)
Private Declare Function GetOpenFileName Lib "comdlg32.dll" Alias _
                   "GetOpenFileNameA" (pOpenfilename As OPENFILENAME) As Long
 
 'Structure du fichier
Private Type OPENFILENAME
    lStructSize As Long
    hwndOwner As Long
    hInstance As Long
    lpstrFilter As String
    lpstrCustomFilter As String
    nMaxCustFilter As Long
    nFilterIndex As Long
    lpstrFile As String
    nMaxFile As Long
    lpstrFileTitle As String
    nMaxFileTitle As Long
    lpstrInitialDir As String
    lpstrTitle As String
    flags As Long
    nFileOffset As Integer
    nFileExtension As Integer
    lpstrDefExt As String
    lCustData As Long
    lpfnHook As Long
    lpTemplateName As String
End Type
 
 'Constantes
Private Const OFN_READONLY = &H1
Private Const OFN_OVERWRITEPROMPT = &H2
Private Const OFN_HIDEREADONLY = &H4
Private Const OFN_NOCHANGEDIR = &H8
Private Const OFN_SHOWHELP = &H10
Private Const OFN_ENABLEHOOK = &H20
Private Const OFN_ENABLETEMPLATE = &H40
Private Const OFN_ENABLETEMPLATEHANDLE = &H80
Private Const OFN_NOVALIDATE = &H100
Private Const OFN_ALLOWMULTISELECT = &H200
Private Const OFN_EXTENSIONDIFFERENT = &H400
Private Const OFN_PATHMUSTEXIST = &H800
Private Const OFN_FILEMUSTEXIST = &H1000
Private Const OFN_CREATEPROMPT = &H2000
Private Const OFN_SHAREAWARE = &H4000
Private Const OFN_NOREADONLYRETURN = &H8000
Private Const OFN_NOTESTFILECREATE = &H10000
 
Private Const OFN_SHAREFALLTHROUGH = 2
Private Const OFN_SHARENOWARN = 1
Private Const OFN_SHAREWARN = 0
 
 
Public Function OuvrirUnFichier(Handle As Long, _
                                Titre As String, _
                                TypeRetour As Byte, _
                                Optional TitreFiltre As String, _
                                Optional MasqueFichier As String, _
                                Optional RepParDefaut As String) As String
 'OuvrirUnFichier est la fonction a utiliser dans votre formulaire pour ouvrir _
 'la boîte de dialogue de sélection d'un fichier.
 'Explication des paramètres
    'Handle = le handle de la fenêtre
    'Titre = Titre de la boîte de dialogue
    'TypeRetour (Définit la valeur, de type String, renvoyée par la fonction)
        '1 = Chemin complet + Nom du fichier
        '2 = Nom fichier seulement
    'TitreFiltre = Titre du filtre
        'Exemple: Fichier Texte
        'N'utilisez pas cet argument si vous ne voulez spécifier aucun filtre
    'MasqueFichier = Critère sur le nom de fichier
        'Exemple: toto*.txt
        '           -> fichiers dont le nom commence par toto et dont l'extension est txt
        '         toto*.txt;toto*.tab;toto*.prn
        '           -> fichiers dont le nom commence par toto et dont l'extension
        '              est txt ou tab ou prn
    'RepParDefaut = Répertoire d'ouverture par defaut
        'Exemple: C:\windows\system32
        'Si vous laissez l'argument vide, par defaut il se place dans le répertoire de votre application
 
Dim StructFile As OPENFILENAME
Dim sFiltre As String
Dim sMasquesF() As String, sTypesF() As String
Dim i1 As Integer, i2 As Integer
 
 'Construction du filtre en fonction des arguments spécifiés
If Len(TitreFiltre) > 0 And Len(MasqueFichier) > 0 Then
   sFiltre = TitreFiltre & Chr$(0) & MasqueFichier & Chr$(0)
End If
sFiltre = sFiltre & "Tous (*.*)" & Chr$(0) & "*.*" & Chr$(0)
 
 'Configuration de la boîte de dialogue
  With StructFile
    .lStructSize = Len(StructFile) 'Initialisation de la grosseur de la structure
    .hwndOwner = Handle 'Identification du handle de la fenêtre
    .lpstrFilter = sFiltre 'Application du filtre
    .lpstrFile = String$(254, vbNullChar) 'Initialisation du fichier '0' x 254
    .nMaxFile = 254 'Taille maximale du fichier
    .lpstrFileTitle = String$(254, vbNullChar) 'Initialisation du nom du fichier '0' x 254
    .nMaxFileTitle = 254  'Taille maximale du nom du fichier
    .lpstrTitle = Titre 'Titre de la boîte de dialogue
    .flags = OFN_HIDEREADONLY  'Option de la boite de dialogue
    If ((IsNull(RepParDefaut)) Or (RepParDefaut = "")) Then
        RepParDefaut = CurrentDb.Name
        PathStripPath (RepParDefaut)
        .lpstrInitialDir = Left(CurrentDb.Name, Len(CurrentDb.Name) - Len(Mid$(RepParDefaut, 1, _
InStr(1, RepParDefaut, vbNullChar) - 1)))
        Else: .lpstrInitialDir = RepParDefaut
    End If
  End With
 
If (GetOpenFileName(StructFile)) Then 'Si un fichier est sélectionné
    Select Case TypeRetour
      Case 1: OuvrirUnFichier = Trim$(Left(StructFile.lpstrFile, InStr(1, StructFile.lpstrFile, vbNullChar) - 1))
      Case 2: OuvrirUnFichier = Trim$(Left(StructFile.lpstrFileTitle, InStr(1, StructFile.lpstrFileTitle, vbNullChar) - 1))
    End Select
  End If
 
End Function

J'ai remplacé l'argument TypeFichier de la fonction OuvrirUnFichier par un argument MasqueFichier.
Ce que ça change :
Au lieu de mettre le type xls on met le masque *.xls.
Il suffit de remplacer * par autre chose.
Company_*.xls -> tous les fichiers excel commençant par Company_.
*_ABC.xls -> tous les fichiers excel dont le nom finit par _ABC.

Par rapport à ton code, ça devrait donner :

Code :

xlsPath = OuvrirUnFichier(Application.hWndAccessApp, FiltreFichier, 1, "Excel File", FiltreFichier & ".xls")

A+

[Orakle]

Super!

Merci beaucoup de ton aide, je vois ça lundi et je reviens ici pour donner des news!... et accessoirement passer le thread en résolu.

Edit : ça marche au poil! l'ouverture n'affiche bien que le fichier que je souhaite utiliser.

Merci encore et bonne journée!!