zone de liste par valeurs

[myriame]

bonjour à tous !!
j'ai crééer dans mon formulaire une zone de liste dont les valeurs sont écrites par moi meme, cependant est-il possible que les valeurs inscrites soivent tous les noms de fichier se trouvant dans le chemin c:\.... ??????????
merci

[LedZeppII]

Bonjour,

Voici un exemple de code, pour l'événement "sur clic" d'un bouton CmdRefreshLstFichiers.
Il lit le dossier "C:\Documents and Settings\Moi\Mes documents" et met les fichier trouvés dans la zone de liste lstFichiers.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Private Sub CmdRefreshLstFichiers_Click()
Dim strDossier As String, strFichier As String
Dim strList As String
 
strDossier = "C:\Documents and Settings\Moi\Mes documents"
strFichier = Dir(strDossier & "\*.*", vbNormal)
Do While Len(strFichier) > 0
   strList = strList & strFichier & ";"
   ' fichier suivant
   strFichier = Dir
Loop
' Enlève dernier point-virgule
If Len(strList) > 0 Then strList = Left(strList, Len(strList) - 1)
' Affecte liste à la zone de liste
Me.lstFichiers.RowSource = strList
End Sub

A+

[myriame]

je ne comprends pas où je trouve Cmd RefreshLIstFichiers ????
pourquoi ca commence par private et non par public??? c'est une fnction??

[Jeannot45]

Envoyé par LedZeppII

Voici un exemple de code, pour l'événement "sur clic" d'un bouton CmdRefreshLstFichiers

Il te faut donc poser un bouton sur ton formulaire et dans les propriétés, dans l'ongler "Evènemnts", tu trouves "sur clic".

Tu copies ou tu adaptes le code surtout par rapport au chemin que doit lire le code (ligne 5 du code) afin d'indiquer ton propre chemin.

Bonne continuation

[LedZeppII]

Bonjour,

En complément de ce qu'a écrit Jeannot, pour accéder à la procédure événementielle d'un bouton ...

• Afficher la fenêtre des propriétés du bouton
• Aller dans l'onglet «Autres»
• En face de «Nom» donner un nom "parlant" au bouton (CmdRefreshLstFichiers dans mon exemple)
• Aller dans l'onglet «Événements»
• En face du nom de l'événement (ici, "sur clic"), choisir «Procédure événementielle»
• Cliquer sur le petit bouton à droite (bouton avec trois points).
• Tu arrives dans l'éditeur VB, dans une procédure événementielle vide.
  
  Code :

  1
  2
  3
  Private Sub NomDeMonControleBouton_Click()
   
  End Sub

• Tu insères le code
  
  Code :

  1
  2
  3
  4
  5
  6
  7
  8
  9
  10
  11
  12
  13
  14
  Dim strDossier As String, strFichier As String
  Dim strList As String
   
  strDossier = "C:\Documents and Settings\Moi\Mes documents"
  strFichier = Dir(strDossier & "\*.*", vbNormal)
  Do While Len(strFichier) > 0
     strList = strList & strFichier & ";"
     ' fichier suivant
     strFichier = Dir
  Loop
  ' Enlève dernier point-virgule
  If Len(strList) > 0 Then strList = Left(strList, Len(strList) - 1)
  ' Affecte liste à la zone de liste
  Me.lstFichiers.RowSource = strList

  entre

  Private Sub NomDeMonControleBouton_Click

  et

  End Sub

• Ensuite il faut bien sûr adapter à ton contexte, en remplaçant lstFichiers par le nom de contrôle zone de liste, et en remplaçant "C:\Documents and Settings\Moi\Mes documents" par le chemin vers ton dossier.

A+