[XL-2003] Compter les valeurs uniquement 1 fois? [Résolu]

[Djromé]

Salut les Kracks,

J'ai un tableau avec une colonne comprenant des dates.

11/05/2011
11/05/2011
11/05/2011
13/05/2011
13/05/2011

J'aimerai savoir si il y a une formule (peut-être un countif imbriqué? mais sans utiliser VBA) pour soustraire le nombre de jour unique, à savoir 2 dans mon cas ci-dessus (11/05/2011 & 13/05/2011).

[corona]

Bonjour,
Intéressant comme question.
Une première solution avant d'autres plus intéressantes.
Contraintes: Les dates doivent être triées et la formule occupe une colonne.
Les dates en A2::A13, la formule en B2:B13 et placer la somme de la plage B2:B13 dans une autre cellule.

Code :

=SI(A1=A2;0; 1*(NB.SI($A$2:$A$13;A2)<>0 ))

Et plus court, sans la formule SI

Code :

=(A1<>A2) * (1 * (NB.SI($A$2:$A$13;A2)<>0))

[Djromé]

Bonsoir Philippe,

Effectivement, il me suffirait de pouvoir imbriquer un compte
NB.SI(maplage;1) pour compter les jours existant, mais je ne sais pas si c'est faisable sans VBA. Je pensais qu'il existait une formule comptant les valeurs uniques dans une plage données???
Surtout qu'il y en a beaucoup!
Merci pour ton temps...

Bon week-end.

[corona]

Bonjour,
Cette question me taraudait.
Avec les dates en A2:A13 et sans contrainte de tri. Formule à placer sur une cellule quelconque.

Code :

=SOMMEPROD(1/NB.SI(A2:A13;A2:A13))

[Djromé]

Merci Philippe,

Effectivement, ta formule marche impeccablement!
Elle mériterait à être connu car les doublons sont légions dans de nombreuses base de données, j'aurai même pensé que Microsoft aurait développé une formule plus simple!

Encore merci, je vais la retenir par coeur car mon utilisation de sommeprod (sumproduct) est marginale!

Salutations

[mercatog]

Bonsoir

Cette formule matricielle ne tient pas compte des cellules vides (dans n'importe quelle cellule. à valider par Ctrl Maj Entrée)

=SOMME((A2:A12<>"")/SI(A2:A12="";1;NB.SI(A2:A12;A2:A12)))

Et cette formule avec un autre critère (compter sans doublons et en ne tenant pas compte des cellules vides les données commençant par la lettre D)

=SOMME((GAUCHE(A2:A12;1)="D")/SI(A2:A12="";1;NB.SI(A2:A12;A2:A12)))

[corona]

Bonjour,
Mercatog, bravo, je n'avais pas testé suffisamment.
Une autre solution. Sans Ctrl+MAj+Enter

Code :

=SOMMEPROD(N(FREQUENCE(A2:A14;A2:A14)>0))

Attention : Ne fonctionne pas avec du texte