[AC-2003] Creation multi tables

[BAYRAL]

Bonjour,
A partir d'une table j'ai besoin d'éclater celle-ci en plusieurs tables en fonction d'un code région.
Y a t'il un moyen d'automatiser ce besoin ?
Merci par avance

[pgz]

Bonjour.

A mon avis, tu peux commencer par une requête "DISTINCT ROW" sur le champ code region de la table mère. Cela te donne la liste des codes de région.

Pour chaque code de cette liste, tu crées une nouvelle table (copie d'un modèle vide), tu ouvres une requête sur la table mère avec un filtre sur le code de région, tu ouvres une autre requête sur la table fille vide, et tu copies tous les enregistrement de la première requête dans la seconde.

Voilà dans le principe.

Cordialement,

PGZ

[Philippe JOCHMANS]

Bonjour

Voici une routine que j'avais remis au goût du jour en début de semaine.

Cette routine va te permettre en passant en paramètre le nom de la table et le nom du champ où se trouve les critère d'éclatage.

Exemple d'appel :

Code :

Call EclatageTable("Table1", "Civ")

on éclate la table Table1 par rapport au champ Civ, cela va créer autant de tables qu'il y a de données Civ différentes.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Public Sub EclatageTable(strTable As String, strChamp As String)
    '---------------------------------------------------------------------------------------
    ' Procedure      : EclatageTable
    ' Auteur         : Philippe JOCHMANS - http://starec.developpez.com
    ' Date           : 02/05/2011
    ' Commentaires   : Routine d'éclatage de table
    ' Paramètres en entrée :
    '               strTable    : Nom de la table qui doit être éclatée
    '               strChamp    : Nom du champ de référence
    '
    '  Remarques      : Ne pas oublier de cocher la bibliothèque Microsoft DAO 3.6
    '---------------------------------------------------------------------------------------
 
    ' déclaration des variables
 
    Dim db As DAO.Database
    Dim rstChamp As DAO.Recordset           ' recordset pour récupérer les informations sur le champ qui sert de référence à l'éclatage
    Dim strSQL As String                    'stockage des chaines SQL
 
    ' affectation
 
    Set db = CurrentDb
 
    ' utilisation d'un recordset en fonction du champ de critère pour récupérer les différents critères d'éclatage
 
    strSQL = "SELECT " & strChamp & " FROM " & strTable & " GROUP BY " & strChamp
    Set rstChamp = db.OpenRecordset(strSQL)
    While Not rstChamp.EOF
        ' création des différentes tables
        db.Execute "SELECT * INTO " & strTable & "_" & rstChamp(strChamp) & " FROM " & strTable & " WHERE " & strChamp & "='" & rstChamp(strChamp) & "'"
        rstChamp.MoveNext
    Wend
 
    ' mise à jour de la fenêtre base de données
    Application.RefreshDatabaseWindow
 
    ' libération des  objets
    rstChamp.Close
    Set rstChamp = Nothing
 
    MsgBox "Fin de traitement"
 
End Sub

Edit : Il faudra adapter si le champ est de type numérique.
Philippe

[Philippe JOCHMANS]

RE

Un complément ici : http://www.developpez.net/forums/d10...critere-champ/

Philippe

[Mat.M]

Envoyé par pgz

Pour chaque code de cette liste, tu crées une nouvelle table (copie d'un modèle vide), tu ouvres une requête sur la table mère avec un filtre sur le code de région, tu ouvres une autre requête sur la table fille vide, et tu copies tous les enregistrement de la première requête dans la seconde.

PGZ

un bête SELECT INTO comme le montre Philippe ça suffit

Sinon les recordsets ont une propriétés qui s'appellent "clone" il me semble.

[pgz]

Hello!

Envoyé par Mat.M

un bête SELECT INTO comme le montre Philippe ça suffit

C'est vrai que c'est bête!

Merci!

PGZ