[DATA] Tableaux et des boucles : do until et array [Résolu]

[maysa]

Bonjour,

je commence l'apprentissage des tableaux et des boucles sous SAS.

J'ai une table, avec différentes dates de visite, une date peut etre vide. J'ai besoin de savoir quand à eu lieu la dernière visite.
Je fais donc un tableau, où je commence par insérer la dernière visite qui était prévue..
Dans ma boucle je lui dis d'initialiser ma variable jusqu'a ce que la variable est vide (comme ça je sais quand a eu lieu ma dernière visite) mais visiblement il ne boucle pas.
Exemple : dans ma table j'ai VS_1 de vide mais pas M9 donc il doit m'initialiser ma date de dernière visite à M9 et non VS_1 . Et bien non..
voici mon code :

Code :

1
2
3
4
5
6
7
8
9
10
 
DATA datevis;
SET datevis;
 ARRAY vis {*} VS_1 M9 M8 M7 J195 M6 J165 M5 M4 M3 J75 M2 J45 M1 J15 dchir M_3 J_7 M_6;
 DO UNTIL (i ^= .);
  dernvis = vis{i};
  i+1;
END;
attrib dernvis label ="date dernière visite" format= DDMMYY10.;
run;

merci pour votre aide !

[jerome_pdv2]

Bonjour maysa

Personnellement j'ai toujours du mal avec les "DO UNTIL"...

ne sachant pas si tes variables sont classées par date croissante, voici un code dérivé a base de boucle DO i TO max

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
 
 
 
DATA datevis;
SET datevis;
 ARRAY vis {*} date1 date2 date3 date4;
 DO i=1 TO dim(vis);
  IF vis{i}>dernvis  then dernvis = vis{i};
END;
attrib dernvis label ="date dernière visite" format= DDMMYY10.;
run;
 
proc print DATA=datevis;run;

Code :

1
2
3
4
5
6
7
 
         Obs         date1         date2         date3         date4    i       dernvis
 
         1              .    09/12/2003    09/12/2004    09/12/2005    5    09/12/2005
         2     09/12/2003             .    09/12/2001             .    5    09/12/2003
         3     09/12/2004    09/12/2008             .    09/12/2003    5    09/12/2008
         4     09/12/2005             .             .             .    5    09/12/2005

sinon avec DO UNTIL en partant de l'envers et avec l'utilisation de dim()

sans dim() je n'y arrive pas...

Code :

1
2
3
4
5
6
7
8
9
10
11
 
DATA datevis;
SET datevis;
 ARRAY vis  {*}  date1 date2 date3 date4;
 i=dim(vis);
DO until (i=0) ;
IF dernvis<vis{i}  then dernvis = vis{i};
  i=i-1;
END;
attrib dernvis label ="date dernière visite" format= DDMMYY10.;
run;

[olivier.decourt]

Bonjour.
Ca ne boucle pas parce que i n'est pas initialisé. Donc i=. dès le début de la boucle donc on n'y entre pas.
La solution de Jérôme est très bien.
On peut aussi se passer de l'array : la fonction COALESCE renvoie la 1e valeur non manquante parmi une liste de variables. Il faut donc écrire :

Code :

derVis = COALESCE(visite10, visite9, visite8, etc., visite1) ;

A adapter avec les bons noms de variables, rangés par ordre chronologique décroissant (de la dernière visite à la plus ancienne).
Bon courage.
Olivier

[olivier.decourt]

Si tu souhaites conserver ton array et sa boucle, il serait plus optimal de le parcourir à l'envers (en partant de la visite la + récente), si j'ai bien compris ton besoin.

Code :

1
2
3
4
5
6
7
8
DATA datevis;
SET datevis;
 ARRAY vis {*} VS_1 M9 M8 M7 J195 M6 J165 M5 M4 M3 J75 M2 J45 M1 J15 dchir M_3 J_7 M_6;
 DO i=DIM(vis) TO 1 BY -1 WHILE(MISSING(vis{i})) ;
 END ;
 dernvis = vis{i};
 attrib dernvis label ="date dernière visite" format= DDMMYY10.;
run;

A la sortie de la boucle (à cause de la condition, sauf si toutes les dates sont manquantes) i est le numéro du 1er élément non manquant de l'array, parcouru de droite à gauche. Il suffit donc de l'affecter à la nouvelle variable.
L'avantage si seule un petit nombre de dates manque, c'est qu'on fera moins de passages dans la boucle (aucun si la dernière date est renseignée) et qu'on gagnera donc du temps.

[Manoutz]

Bonjour,

Remarque peut être hors contexte, mais je ne vois pas pourquoi passer par les array. Si j'ai bien compris Mayssa a en entrée un ensemble de variables date ( VS_1 M9 M8 M7 J195 M6 J165 M5 M4 M3 J75 M2 J45 M1 J15 dchir M_3 J_7 M_6) et l'idée est de retenir la date max. Pourquoi ne pas utiliser la finction max dans une étape data ou sql?

[maysa]

Merci pour vos réponses, je vais tenter d'y répondre individuellement..

oui mes variables sont classées par ordre chronologique... soit ordre décroissant.

Alors j'ai essayé ton code est ça fonctionne ! merci je n'ai même pas pensé à faire de comparaison de date, puisque normalement elles sont dans l'ordre chronologique...

Envoyé par jerome_pdv2

Bonjour maysa

Personnellement j'ai toujours du mal avec les "DO UNTIL"...

ne sachant pas si tes variables sont classées par date croissante, voici un code dérivé a base de boucle DO i TO max

Code :

Code :

sinon avec DO UNTIL en partant de l'envers et avec l'utilisation de dim()

sans dim() je n'y arrive pas...

Code :

[maysa]

ça foncitonne aussi, sauf que je l'ai fait à l'envers... (parce que mon tableau est créé de façon chronologique..

Code :

DO i=1 TO DIM(vis) WHILE(MISSING(vis{i})) ;

Par contre une chose m'échappe... on initialise dernvis après la boucle ??? . et en dehors de la boucle il connais i ??? y'a que SAS pour faire ça !!

Au final j'ai utilisé la fonction COALESCE, plus rapide , une seule ligne de code...
Merci

Envoyé par olivier.decourt

Si tu souhaites conserver ton array et sa boucle, il serait plus optimal de le parcourir à l'envers (en partant de la visite la + récente), si j'ai bien compris ton besoin.

Code :

A la sortie de la boucle (à cause de la condition, sauf si toutes les dates sont manquantes) i est le numéro du 1er élément non manquant de l'array, parcouru de droite à gauche. Il suffit donc de l'affecter à la nouvelle variable.
L'avantage si seule un petit nombre de dates manque, c'est qu'on fera moins de passages dans la boucle (aucun si la dernière date est renseignée) et qu'on gagnera donc du temps.

[maysa]

Envoyé par Manoutz

Bonjour,

Remarque peut être hors contexte, mais je ne vois pas pourquoi passer par les array. Si j'ai bien compris Mayssa a en entrée un ensemble de variables date ( VS_1 M9 M8 M7 J195 M6 J165 M5 M4 M3 J75 M2 J45 M1 J15 dchir M_3 J_7 M_6) et l'idée est de retenir la date max. Pourquoi ne pas utiliser la finction max dans une étape data ou sql?

Parce que mes dates sont en colonne et non en ligne...

[MEGAMIND2]

Envoyé par maysa

Parce que mes dates sont en colonne et non en ligne...

Dans une étape data, tu peux avoir le max par ligne comme suit:

Code :

datevisite=max(of date1 date2 date3 date4);

[Manoutz]

Justement! Dans une étape data, la fonction max() renvoie le maximum d'un ensemble d'arguments (c'est à dire variable, ou encore colonnes). Cette fonction va renvoyer pour chaque la valeur maximum sur un ensemble de colonnes. Donc ça à l'air de coller avec ce que tu veux faire.

En sql, tu peux utiliser cette fonction sur des lignes ou sur des colonnes (ou les deux), il faut donc faire attention à la syntaxe.

Manoutz

[maysa]

oui mais en sql, je ne peux faire un max que sur une colonne.. soit

Code :

SELECT max(date) FROM TABLE

je ne pense pas pouvoir lui donner plusieurs colonne...
Mais je ne connaissais pas la fonction max() de l'étape data, alors merci