rapport pixels / Twips [Résolu]

[User]

Bonjour,

Je suis entrain de mettre à jours des agendas...(gestion d'erreurs...) et suis confronté à 1 problème de conversion.

J'ai trouvé sur le net ceci:

Il y a "normalement" 96 pixels par inch (pouce).
Et 1440 Twips par inch.

Donc

1 pixel vaut normalement 1440/96=15 twips

Mais le nombre 96 de pixels par inch peut varier suivant certains paramétrages de l'affichage sous windows.


Je cherche donc un exemple VBA d'utilisation de la fonction api GetDeviceCaps, qui me permette de connaitre le nombre de Twips dans 1 Pixel, car je manque d'infos.

Merci beaucoup à tous !

[ClaudeLELOUP]

Salut,

Connais-tu ceci ?

[User]

Salut Claude,

Oui j'ai parcouru ce lien, mais je souhaiterai juste 1 exemple de code VBA, car j'avoue que je n'ai pas trop l'habitude d'utiliser ce genre d'api

Edit: je reviens vers 21 heures...

[LedZeppII]

Bonsoir,

Voila comment je fais.

Dans la section déclarations d'un module de code :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
' --------------------------------------------------------------
' Pour retrouver caractéristiques écran
' --------------------------------------------------------------
Public Declare Function GetDC Lib "user32.dll" _
        (ByVal hWnd As Long) As Long
'
Public Declare Function ReleaseDC Lib "user32.dll" _
        (ByVal hWnd As Long, ByVal hDc As Long) As Integer
 
Public Const LOGPIXELSX As Long = 88 ' pixels dans 1 inch
Public Const LOGPIXELSY As Long = 90 ' pixels dans 1 inch
' 1 inch contient 1440 twips
'
Public Declare Function GetDeviceCaps Lib "Gdi32.dll" _
        (ByVal hDc As Long, ByVal nIndex As Integer) As Integer

Fonction me retournant le nombre de twips dans un pixel :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
Function GetTwipPerPix(strDirection As String) As Single
Dim sglRes As Single, hDc As Long
' twip/inch divisé par pixel par inch -> twip/pixel
hDc = GetDC(0)
Select Case strDirection
    Case "x", "X"
        sglRes = 1440 / GetDeviceCaps(hDc, LOGPIXELSX)
    Case "y", "Y"
        sglRes = 1440 / GetDeviceCaps(hDc, LOGPIXELSY)
End Select
ReleaseDC 0, hDc
GetTwipPerPix = sglRes
End Function

L'argument de ma fonction est "x" ou "X" pour le nombre de twips par pixel horizontalement.
"y" ou "Y" verticalement.

A+

[User]

Un grand Christophe,

ça fonctionne exactement comme je le souhaitais.

J'en profite pour saluer tout ce que tu fais pour les membres du forum. C'est vraiment super

A+