[XL-2007] Formule somme texte et nombre [Résolu]

[Debinfo75]

Bonjour à tous,

je planche sur une question pour la réalisation d'un tableau de notes d'élèves.
Je cherche une formule me permettant de calculer le total des points obtenu dans 4 matières qui se décomposent en Contrôle Continu, TP et Examen.
Sachant que une absence en TP ou à l'examen ("Abs") renvoie "Abs" pour ce total. L'absence au CC ("Abs" dans mon tableau) permet néanmoins l'attribution d'une note finale.
Je parviens jusque là à faire la formule, mais cela ne fonctionne plus quand je cherche à associer par matière un coefficient à chaque composante de la note.

Je mets en copie ma formule, et vous remercie par avance de l'aide que vous pourrez m'apporter.

[rjamin]

Bonjour,

Je mets en copie ma formule, et vous remercie par avance de l'aide que vous pourrez m'apporter.

Il n'y a rien, oubli ou suppression par un modérateur ?
Les explications données ne permettent pas une bonne compréhension du problème, il faudrait étoffer ces explications. Vous connaissez le problème vous, car c'est votre idée, mais de l'extérieur!!!

[Debinfo75]

Il est vrai qu'à la lecture,ce n'est pas très clair, mais mon tableau et ma formule ne sont pas apparus dans la discussion.

Alors voilà:
je forme une ligne avec des coefficients
Dans chaque matière, il y a du Contrôle Continu, un TP et un Examen.
Il y a 4 matières : Maths, Physique, Chimie, Mécanique
La ligne des coefficients est donc:
Maths Méca Chimie Physique
25 10 65 / 25 50 / 20 30 50 / 20 20 60
La ligne du dessous est celle des notes.
Mon problème est que je souhaite faire le total des notes par leur coef respectifs, soit sur 375, sachant qu'une absence à un TP ou à un Examen quelconque notée "Abs" (chaine de caractères) implique que l'élève est considéré comme "Abs" pour le résultat final sur 375. L'"Abs" en contrôle continu n'implique pas forcément une "Abs" pour le résultat final, si tous les TP et Examens sont notés.

J'ai une formule qui fonctionne pour les cas ou un élève reçoit "Abs" en TP ou Examen, mais elle ne fonctionne plus dans les cas d'une absence non rédibitoire en CC avec des notes pour chaque TP et Examen.

J'espère être plus clair et vous remercie de votre aide.

Cordialement.

Code :

SI(OU(LC(-10)="Abs";LC(-9)="Abs";LC(-7)="Abs";LC(-5)="Abs";LC(-4)="Abs";LC(-2)="Abs";LC(-1)="Abs");"Abs";(LC(-11)*25+LC(-10)*10+LC(-9)*65+LC(-8)*25+LC(-7)*50+LC(-6)*20+LC(-5)*30+LC(-4)*50+LC(-3)*20+LC(-2)*30+LC(-1)*50)/20)

[rjamin]

Bonjour,
Vous dites

Il y a 4 matières : Maths, Physique, Chimie, Mécanique
Dans chaque matière, il y a du Contrôle Continu, un TP et un Examen
La ligne des coefficients est donc:
Maths Méca Chimie Physique
25 10 65 / 25 50 / 20 30 50 / 20 20 60

Or je ne vois que 2 Coéfficients pour Mécanique, est-ce normal?

Autre question, vous dites

L'"Abs" en contrôle continu n'implique pas forcément une "Abs" pour le résultat final, si tous les TP et Examens sont notés.

Désolé mais je ne vois toujours pas ce qu'il faut obtenir dans ce cas.
Mettez un ou deux exemples chiffrés pour voir ce que vous voulez.

[Debinfo75]

Bonjour,
en effet, il n'y a pas de CC en Mécanique.
Je souhaite mettre la chaine de caractères "Abs" pour toute note non obtenue dans chaque matière et type de note, sachant qu'une absence en TP ou en Examen entraine la non validation de l'année et l'on retrouve "Abs" pour le total.
Une absence en Contrôle Continu est notée "Abs" mais équivaut à zéro dans le calcul de mon total sur 375 points.

Il ne m'est pas possible de joindre un tableau, voici quelques exemples de calcul.
La ligne des coefficients est donc:
Maths Méca Chimie Physique
25 10 65 / 25 50 / 20 30 50 / 20 20 60
CC TP Ex / TP Ex / CC TP Ex / CC TP Ex
10 10 10 10 10 10 10 "Abs" / 10 10 10 OK avec la formule de mon precedent post Le total est bien "Abs" (du fait examen de chimie).

10 10 10 / 10 10 / 10 10 10 / 10 "Abs" 10 OK avec la formule de mon precedent post Le total est bien "Abs" (du fait TP de Physique)

Si j'essaie :
"Abs" 10 10 / 10 10 / 10 10 10 / 10 10 10 qui est le cas d'un élève ayant toutes ses notes sauf un absence non rédibitoire en CC de Maths, la formule ne fonctionne plus car je multiplie "Abs" par le coef 25 => #VALEUR! Ce que je comprends mais n'arrive pas à solutionner.

Ex de Calcul de ma dernière ligne
("Abs"*25+10*10+65*10+25*10+50*10+20*10+30*10+50*10+20*10+20*10+60*10)/20 ne fonctionne pas
Pour l'avant-dernière ligne, avec ma formule
(10*25+10*10+65*10+25*10+50*10+20*10+30*10+50*10+20*10+20*"Abs"+60*10)/20 renvoie bien "Abs" comme valeur de mon total.


J'espère que ces informations vous permettront de vous faire une idée, parfois un tableau vaut mieux que....

Merci à nouveau de votre aide.

[rjamin]

Bonjour,

Avec cette formule peut-être placée dans la ligne 5 les coef en ligne 4

Code :

=SI(OU(A5="Abs";F5="Abs";I5="Abs");0;SI(OU(B5="Abs";C5="Abs";D5="Abs";E5="Abs";G5="Abs";H5="Abs";J5="Abs";K5="Abs");"Abs";(A5*$A$4+B5*$B$4+C5*$C$4+D5*$D$4+E5*$E$4+F5*$F$4+G5*$G$4+H5*$H$4+I5*$I$4+J5*$J$4+K5*$K$4)/20))

A recopier vers le bas pour plusieurs calculs.

J'ai fait l'essai avec Abs dans une des 3 cellules en dessous de CC et cela donne 0 au total

[GerardCalc]

Bonsoir,

Si j'ai bien compris et à la condition que N() renvoie bien 0 pour une valeur texte. (Je n'ai pas Excel pour tester la formule) :

• En ligne 2, les coefficients.
• En ligne 3, CC, TP, Ex
• En ligne 4, les notes.

Code :

=SI(SOMMEPROD((A4:K4="Abs")*($A$3:$K$3<>"CC"));"Abs";SOMMEPROD($A$2:$K$2;N(A4:K4)))

A tester.

[Debinfo75]

Merci beaucoup à vous,

la formule fonctionne, mais le fait d'être absent en CC (que j'assimilais à 0) ne doit pas conduire à ce que le total soit égal à 0.
La chaine de caractères "Abs" figure bien dans la cellule, et le formule doit la prendre comme valant 0 dans le calcul du total. Et c'est là que je bute car en multipliant une chaine par un coefficient, on déclenche une erreur.

Comment faire dans ce cas pour qu'une cellule de note de CC valant "Abs" (élève absent) soit prise en compte non pas comme chaine mais valant 0 dans le calcul du total sur 375.

Il faudrait SI(OU(A5="Abs";F5="Abs";I5="Abs"); alors "Abs" = 0 et non pas total = 0.

Merci à nouveau.

[rjamin]

Bonjour,

Une autre formule inspirée par Gerard calc pour la première partie, letest des Abs en dehors des CC
Pour que cela fonctionne il faut
Les titres CC, TP, EX en ligne 3 de A3:K3
Les Coef de A4:K4
Les données dans les lignes suivantes.
On tire la formule vers le bas sur autant de ligne que désiré.

Code :

=SI(SOMMEPROD((A5:K5="Abs")*($A$3:$K$3<>"CC"));"Abs";(N(A5)*$A$4+N(B5)*$B$4+N(C5)*$C$4+N(D5)*$D$4+N(E5)*$E$4+N(F5)*$F$4+N(G5)*$G$4+N(H5)*$H$4+N(I5)*$I$4+N(J5)*$J$4+N(K5)*$K$4)/20)

J'espère que c'est la bonne. N(Valeur) transforme une valeur numérique en Nombre identique à la valeur Numérique mais elle transforme une valeur texte en 0 ce qu'il faut dans notre cas.

[Debinfo75]

Oui, cela marche!!!!!
Mon problème venait à la base de la méconnaissance de N().

Merci infiniment de votre patience et de votre attention.

Bien cordialement.