[AC-2007] Filtrer les données d'une requête en passant par VBA [Résolu]

[Oliv'83]

Bonjour à tous,

Je voudrais pouvoir filtrer les résultats d'une requête qui me sert à allimenter un état. J'arrive bien à filtrer le résultat sur l'état mais pas sur la requête. Je ne suis pas sûr de mon explication donc voici le code concerné :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Dim periode_debut As Date
Dim periode_fin As Date
Dim stLinkCriteria As String
 
periode_debut = Me.Txt_Date_Debut
 
periode_fin = Me.Txt_Date_Fin
 
stLinkCriteria = "[Date_début] BETWEEN #" & Format(periode_debut, "MM/dd/yyyy") & "# AND #" & Format(periode_fin, "MM/dd/yyyy") & "#"
 
DoCmd.OpenReport "Etat_Cumul_Mensuel_Statistique", acViewPreview, , stLinkCriteria
DoCmd.OpenQuery "rqt_Cumul_Mensuel_Statistique"
 
End Sub

Dans ce cas Etat_Cumul_Mensuel_Statistique s'affiche sans problème avec le filtre mais je n'arrive pas à formuler la même chose pour rqt_Cumul_Mensuel_Statistique, car je ne sais pas comment lui transmettre le filtre stLinkCriteria.

Merci d'avance de votre aide

Oliv'

[Simplifi]

Hello Oliv
Joli filtre, juste une proposition de concentation maximale du code

Code :

DoCmd.OpenReport "Etat_Cumul_Mensuel_Statistique", acViewPreview, ,"[Date_début] BETWEEN #" & Format(Txt_Date_Debut, "MM/dd/yyyy") & "# AND #" & Format(Txt_Date_Fin, "MM/dd/yyyy") & "#"

ou un peu moins maximale

Code :

1
2
3
Dim stLinkCriteria As String
stLinkCriteria = "[Date_début] BETWEEN #" & Format(Txt_Date_Debut, "MM/dd/yyyy") & "# AND #" & Format(Txt_Date_Fin, "MM/dd/yyyy") & "#"
DoCmd.OpenReport "Etat_Cumul_Mensuel_Statistique", acViewPreview, , stLinkCriteria

effectivement, je ne pense pas qu'il soit possible de filtrer une requête

une solution consiste à mettre déja le texte SQL de ta requête dans une variable, puis d'y rajouter le filtre qui t'interresse.

Attentiion, suivant le SQL, le filtre peut se placer à différents endroits.

je ne sais pas non plus récupérer le SQL d'une requête enregistrée mais c'est peut être possible

[LedZeppII]

Bonjour,

Sous réserve que la colonne filtrée soit affichée, on doit pouvoir faire comme ça

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Dim periode_debut As Date
Dim periode_fin As Date
Dim strRequete As String
Dim strFilter As String
Dim fm As Access.Form
 
strRequete = "rqt_Cumul_Mensuel_Statistique"
periode_debut = Me.Txt_Date_Debut
periode_fin = Me.Txt_Date_Fin
strFilter = "[Date_début] BETWEEN #" & Format(periode_debut, "MM/dd/yyyy") & "# AND #" & Format(periode_fin, "MM/dd/yyyy") & "#"
' S'assure que la requête est fermée, puis l'ouvre
DoCmd.Close acQuery, strRequete
DoCmd.OpenQuery strRequete, acViewNormal, acReadOnly
' Filtre l'affichage de la requête
Set fm = Screen.ActiveDatasheet
fm.Filter = strFilter
fm.FilterOn = True

A+

[Oliv'83]

Bonsoir Messieurs,

Et merci pour vos réponses.

Simplifi je reconnais que l'on pouvait bien mieux concentrer le code comme tu me le proposes mais comme je ne suis pas un "professionnel" j'aime bien essayer de trouver des formules assez "bateau" que je puisse réutiliser facilement. Dans ce cas précis il ne me reste qu'à changer une fois les 2 Me.Txt_... pour que cela fonctionne avec un autre formulaire...

LedZeppII, merci ton code fonctionne parfaitement et j'obtiens exactement ce que je souhaitais. Je ne suis pas assez érudit en VBA pour comprendre la ligne 15 mais cela fonctionne alors dès que j’aurais 2 minutes je me concentrerai pour essayer de la comprendre. Pourquoi faut il impérativement contrôler que la requête soit fermée?

Encore une fois merci à vous 2 et bonne soirée et n'oubliez pas d'aller à la chasse aux oeufs demain. Joyeuses Pâques.

Oliv'

[Simplifi]

Merci beaucoup
je ne connaissais pas

Code :

Set fm = Screen.ActiveDatasheet

j'ai donc appris quelquechose
Joyeuses Pâques

[LedZeppII]

Bonsoir,

Envoyé par Oliv'83

Je ne suis pas assez érudit en VBA pour comprendre la ligne 15 mais cela fonctionne alors dès que j’aurais 2 minutes je me concentrerai pour essayer de la comprendre.

L'objet Screen du modèle objet Access permet de récupérer une référence au formulaire actif (.ActiveForm), à l'état actif (.ActiveReport), ou à l'objet table (ou requête) actif (.ActiveDatasheet).
Comme Screen.ActiveDatasheet renvoie une référence à un objet de type Form, on peut y appliquer un filtre.

Envoyé par Oliv'83

Pourquoi faut il impérativement contrôler que la requête soit fermée?

Ce n'est pas un impératif.
C'est juste une précaution que j'ai l'habitude de coder.


A+

[Oliv'83]

Envoyé par LedZeppII

L'objet Screen du modèle objet Access permet de récupérer une référence au formulaire actif (.ActiveForm), à l'état actif (.ActiveReport), ou à l'objet table (ou requête) actif (.ActiveDatasheet).
Comme Screen.ActiveDatasheet renvoie une référence à un objet de type Form, on peut y appliquer un filtre.

Merci de tes précisions mais je n'y comprends pas grand chose . Je vais attendre la fin de ma saison (mi-octobre) et je me repencherai sérieusement dessus.

Bonne journée à tous

Oliv'