Macro pour Tableau d'amortissement [Résolu]

[funkymam69]

Bonjour, je travaille actuellement sur une Macro qui calcule pour chaque personne de ma table le tableau d'amortissment associé a son pret.
Voici le code :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
DATA tarif.test_devis;
INPUT Id_Assure:1. Montant_emp:6. N_ech:3. Tx_per:6.5;
CARDS;
1 350000 360 0.00333 20100101
2 120000 300 0.00404 20100501
3 200000 240 0.00500 20101101
RUN;
 
DATA tarif.Var1;
    SET tarif.test_devis;
    CALL SYMPUT(COMPRESS("Montant_emprunte"!!_N_),Montant_emp);
RUN;
 
DATA tarif.Var2;
    SET tarif.test_devis;
    CALL SYMPUT(COMPRESS("Nombre_echeances"!!_N_),N_ech);
RUN;
 
DATA tarif.Var3;
    SET tarif.test_devis;
    CALL SYMPUT(COMPRESS("Taux_periodique"!!_N_),Tx_per);
RUN;
 
%MACRO AMORTISSMT(Mt_emprunt,Nb_echeance,Taux_periodiq,tab_amortissement); 
DATA TARIF.&tab_amortissement;
    Montant_emp=&Mt_emprunt;
    N_ech=&Nb_echeance;
    Tx_per=&Taux_periodiq;
        CRD=Montant_emp;
        Interets=CRD*Tx_per;
        Capital_remb=Montant_ech-CRD*Tx_per;
        Montant_ech=ROUND(Montant_emp*Tx_per*(1+Tx_per)**N_ech/((1+Tx_per)**N_ech-1),0.01);
            DO i=1 TO N_ech BY 1;
                Interets=ROUND(CRD*Tx_per,0.01);
                Capital_remb=ROUND(Montant_ech-Interets,0.01);
                CRD=ROUND(CRD-Capital_remb,0.01);
                OUTPUT;
            END;
RUN;
%MEND AMORTISSMT;
 
%MACRO BOUCLE;
DATA _NULL_;
  SET tarif.test_devis END=FIN;
  IF FIN THEN CALL SYMPUT('FIN',Id_Assure);
RUN; 
 
%DO j=1 %TO &FIN;
    %AMORTISSMT(&&Montant_emprunte&j.,&&Nombre_echeances&j.,&&Taux_periodique&j.,tab_amort&j.);
%END;
%MEND BOUCLE;
%BOUCLE;

Ce code fonctionne mais mon soucis est qu'il me créer une table pour chaque tableau d'amortissement. Cela ne pose pas de problème dans ce cas car j'en ai que trois mais je souhaite l'appliquer à une base contenant environ 100 000 prêts. J'aimerais donc créer une table vide qui se remplierait au fur et à mesure avec les différents tableaux d'amortissement les uns à la suite des autres et donc ne plus avoir une table par tableau.

Si vous avez une idée, n'hésitez pas !
Merci d'avance.
Cordialement

[boutchiwah]

alors voila la solution que je te propose, tu copies le code ci-dessous dans ta macro "BOUCLE" juste après l'execution de la macro "%AMORTISSMT"

Code :

1
2
3
4
5
proc datasets lib=tarif nolist;
	append out = TAB_TOT
	DATA = tab_amort&j. ;
	DELETE tab_amort&j.;
run;

ça va te créer une nouvelle table "TAB_TOT" qui contiendra toutes tes tables "tab_amort&j." et ça supprimera ces derniere à chaque fois

[MEGAMIND2]

Je t'ai simplifié le programme, et j'espere que ça répond à tes besoins.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
DATA test_devis;
INPUT Id_Assure:1. Montant_emp:6. N_ech:3. Tx_per:6.5;
CARDS;
1 350000 360 0.00333 20100101
2 120000 300 0.00404 20100501
3 200000 240 0.00500 20101101
RUN;
 
DATA _NULL_;
	SET test_devis END=EOF;
	CALL SYMPUT(COMPRESS("Montant_emprunte"!!_N_),Montant_emp);
	CALL SYMPUT(COMPRESS("Nombre_echeances"!!_N_),N_ech);
	CALL SYMPUT(COMPRESS("Taux_periodique"!!_N_),Tx_per);
	IF EOF THEN CALL SYMPUT("NB",_N_);
RUN;
 
 
 
%MACRO AMORTISSMT; 
 
%DO i=1 %TO &NB.;
 
	DATA tab_amortissement_&i.;
	Montant_emp=&&Montant_emprunte&i.;
	N_ech=&&Nombre_echeances&i.;
	Tx_per=&&Taux_periodique&i.;
	CRD=Montant_emp;
	Interets=CRD*Tx_per;
	Capital_remb=Montant_ech-CRD*Tx_per;
	Montant_ech=ROUND(Montant_emp*Tx_per*(1+Tx_per)**N_ech/((1+Tx_per)**N_ech-1),0.01);
	DO i=1 TO N_ech BY 1;
	Interets=ROUND(CRD*Tx_per,0.01);
	Capital_remb=ROUND(Montant_ech-Interets,0.01);
	CRD=ROUND(CRD-Capital_remb,0.01);
	OUTPUT;
	END;
		DROP i;
	RUN;
 
%END;
 
DATA tab_amortissement; SET %DO i=1 %TO &NB.; tab_amortissement_&i. %end;; RUN;/* concaténation des tables*/
 
 
%MEND AMORTISSMT;
 
%AMORTISSMT;

Bon wk!

[olivier.decourt]

Euh... pourquoi tant de macros ?
Si le but est de faire une table avec tous les amortissements de tous les devis, il suffit de prendre l'étape DATA au centre de ta macro et d'y greffer le SET qui se trouve avant (là où tu fais actuellement les CALL SYMPUT)... non ?

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
DATA tab_amortissement (DROP=i) ;
  SET tarif.test_devis;
	CRD=Montant_emp;
	Interets=CRD*Tx_per;
	Capital_remb=Montant_ech-CRD*Tx_per;
	Montant_ech=ROUND(Montant_emp*Tx_per*(1+Tx_per)**N_ech/((1+Tx_per)**N_ech-1),0.01);
	DO i=1 TO N_ech BY 1;
	Interets=ROUND(CRD*Tx_per,0.01);
	Capital_remb=ROUND(Montant_ech-Interets,0.01);
	CRD=ROUND(CRD-Capital_remb,0.01);
	OUTPUT;
	END;
	RUN;

[funkymam69]

Merci à tous pour vos réponses !!!

Je m'excuse pour ces remerciements tardifs mais n'étant pas un utilsateur avéré de ce site, je n'avais malheureusement pas vu vos messages.

Je m'empresse de tester vos solutions afin de vous informer des résultats.

Merci encore.

Bonne journée

[funkymam69]

Bonjour, je poste ce message juste pour tous vous remercier pour vos conseils.

La PROC DATASETS m'a permis de faire exactement ce que je souhaitais.

Merci egalement pour la simplification du code c'était cool.

EN vous souhaitant une bonne journée,

Cordialement.