Lire les noms de tables SAS [Résolu]

[damien29]

Bonjour,

Est ce qu'il est possible de récupérer les noms des tables sas dans un dossier (comme la Work) et d'ensuite les ajouter dans une autre table, afin d'utiliser les noms des tables dans une étape data?

Merci.

[olivier.decourt]

Bonjour Damien.
Tu peux faire ça :

Code :

1
2
3
ODS OUTPUT members = work.liste_tables ;
PROC CONTENTS DATA=work._ALL_ ;
RUN ;

Ou sinon piocher directement dans une vue système comme SASHELP.VSTABLE.

Code :

1
2
3
DATA work.liste_tables ;
  SET sashelp.vstable (WHERE=(libname="WORK")) ;
RUN ;

Olivier

[s_a_m]

sinon il y a :

Code :

1
2
3
proc Sql;
	CREATE TABLE TABLES AS SELECT memname FROM dictionary.TABLES WHERE upcase(libname)='SASHELP' AND upcase(memtype)='DATA';
quit;

[damien29]

Merci beaucoup

[s_a_m]

Envoyé par olivier.decourt

Ou sinon piocher directement dans une vue système comme SASHELP.VSTABLE.

Code :

Olivier

Pour éviter les surprises, il faut rajouter un upcase ou lowcase pour le nom du libname, car pour SAS il n'existe pas de WORK mais plutot Work :

Code :

1
2
3
DATA work.liste_tables ;
  SET sashelp.vstable (WHERE=(UPCASE(libname)="WORK")) ;
RUN ;

l'avantage de la PROC SQL;c'est qu'on peut récupérer le résultat dans une macro variable, toute fois il faut faire attention à la longueur de la macro variable:

Code :

1
2
3
4
5
 
proc Sql noprint;
   SELECT memname INTO :noms separated BY ',' FROM dictionary.TABLES WHERE upcase(libname)='SASHELP' AND upcase(memtype)='DATA';
quit;
%put &nom.;

[damien29]

Et pour récupérer de la même façon les variables d'une table, qu'est ce qu'il faut modifier?

[s_a_m]

Envoyé par damien29

Et pour récupérer de la même façon les variables d'une table, qu'est ce qu'il faut modifier?

avec ce code tu peux récupérer tout ce que tu veux :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
 
OPTION nolabel;
 
proc Sql;
	CREATE TABLE  a AS  SELECT DISTINCT (memname) FROM dictionary.dictionaries;
quit;
 
DATA _null_;
	SET a;
	call symput ('n', (_n_));
	call symput ('var'!!LEFT (_n_),memname);
run;
 
%macro tout;
	%do i=1 %TO &n.;
 
		proc Sql;
			reset noprint;
			CREATE TABLE  &&var&i AS SELECT * FROM  dictionary.&&var&i;
		quit;
 
	%end;
%mend;
 
%tout;

[MEGAMIND2]

Une autre approche

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
PROC CONTENTS DATA=SASHELP.SHOES OUT=OUT;
RUN;
 
PROC SORT DATA=OUT;
BY VARNUM;
RUN;
 
DATA _NULL_;
SET OUT END=EOF;
IF EOF THEN CALL SYMPUT("NB_variable",_N_);
CALL SYMPUT("VARIABLE"!!LEFT(_N_),NAME);
RUN;
 
/* Si jamais tu veux l'utilise dans une boucle*/
 
%MACRO AFFICHAGE;
	%DO i=1 %TO &NB_variable.;
	%PUT &&VARIABLE&i.;
	%END;
%MEND;
 
%AFFICHAGE;

[s_a_m]

sorry megamed ,mais ta méthode n'est pas optimisée. Enfin la proc contents est coûteuse.

[MEGAMIND2]

Et tu crois que du SQL est pas lourd en temps de traitement?
Chacun a sa manière de procéder et je ne dirai pas que la mienne est plus optimale

[damien29]

Merci, ça marche très bien