[WD-2010] Appeler des template.dotm depuis un userform

[VayLoe]

Voilà, je travaille comme secrétaire indépendante pour plusieurs entreprises. Du coup, j'ai pleins de templates.dotm différents pour chaque sociétés.

Par exemple pour l'entreprise 1 : facture.dotm - bulletin de livraison.dotm - rapport d'intervention.dotm - etc...

Idem pour les autres entreprises.

J'aimerais pour faire un UserForm qui serait composer de plusieurs boutons (facture - bulletin de livraison - rapport d'intervention - etc..) qui me permettrait d'ouvrir directement le template (format document1.docx) demandé pour l'entreprise 1.

La même chose pour l'entreprise 2, 3 et 4

J'aimerais pouvoir appeler cet UserForm depuis mon normal.dotm, par un bouton "Menu Entreprise 1", "Menu Entreprise 2", etc..

Voilà voilà, comme vous l'aurais certainement compris, je n'y comprends rien en programmation, j'ai bien essayé de chercher sur le net, mais je n'ai rien trouvé de probant.

Donc si quelqu'un à une bonne âme et un petit peu de temps pour m'expliquer comment je peux faire ça, je lui serais très reconnaissante.

Merci beaucoup.

[Heureux-oli]

Salut,

Pourquoi utiliser des UserForm différents en fonction de l'entreprise ?
On peut faire ce choix dans le UserForm.

On peut aussi agencer le ruban pour ne pas devoir utiliser un UserForm.

C'est un peu à toi de voir.

[VayLoe]

Merci pour la réponse

Oui, ce serait tout à fait faisable de faire le choix dans la UserForm, notamment pas onglet par exemple, enfin je dis ça, mais comme j'y connais rien

Par contre pour l'agencement du ruban, je vois pas trop ce que tu entends par là.. newbie inside .

Dans le ruban tu mettrais un bouton "Menu entreprise 1" etc.. ? Parce que mettre tous les templates sur le ruban, ce sera pas possible j'ai quand même entre 5 et 10 templates par entreprise... ça risque de faire un très très long ruban

Merci

[Heureux-oli]

Salut,

Pour le ruban, on peut faire de cette manière.

Pour le UserForm, on pourrait evisager qu'après avoir fait un choix, les modèles présents dans un répertoires soient listés poour pouvoir être cliqués ?

[VayLoe]

Coucou

Pour le ruban, j'aime bien le système bouton "Menu Entreprise 1"

Pour le UserForm, oui, c'est tout à fait possible aussi

[Heureux-oli]

Salut,

Je pense que mettre les UserForm est le code dans le normal.dotm n'est pas une bonne idée.
Il arrive assez souvent que le Normal soit corrompu et que l'on soit obligé de le supprimer ou de le renommer, dans ce cas, tout serait perdu.

Ce que je propose est d'utiliser un autre modèle ou un document.

Je pencherais même pour un doucment, certaines informations pourraient être inscrites dans le document pour être utilisées par le code, de cette manière, si les choses changent, une nouvelle entreprise, une qui diparaît, qui change de nom, ... Il ne serait pas utile de toucher au code.

Sur la base d'un document, on pourrait utiliser un tableau pour stocker les données et les utiliser pour remplir les listes de choix.

Partant sur deux colonnes, une pour le nom de l'entreprise et une seconde pour le répertoire qui contient les modèles de document.
Comme ce sera le premier tableau de notre document, dans le code, ce sera ActiveDocument.Tables(1).

On appelle un UserForm lors de l'ouverture du document sur base de l'évènement Open.

Code :

1
2
3
Sub Document_Open()
 
End Sub

C'est dans cette portion de code que nous allons appeler notre UserForm.
Ce UserForm, nous allons l'appeler ufAccueil, et lui donner Accueil comme titre (Catpion), c'est ce qui sera affiché dans la barre de titre du UserForm quand il sera affiché.

Ce UserForm contiendra deux zones de liste, l'une avec le nom des entreprises et le chemin des modèles (récupéré du tableau), la seconde liste sera remplie avec les modèles trouvés dans le répertoire après avoir fait un choix dans la première liste.

Nous allons ajouter deux zones de liste sur notre UserForm.

[VayLoe]

Coucou,

Oui, ça me semble très très bien. C'est vrai que j'ai déjà eu des soucis avec le normal.dotm et que si je pouvais éviter de tout recommencer à chaque fois ce serait pas une mauvaise chose

Très bonne idée de faire une sorte de base de données pour les entreprises et les modèles

Vraiment super, j'ai hâte de m'y mettre, ça devrait vraiment me simplifier la vie tout ça, merci

[Heureux-oli]

Salut,

T'as pas encore commencé sur base des indications que j'ai données ?

[VayLoe]

Coucou,

Et non j'avais pas commencé, week-end plus chargé que je ne pensais
Mais bon là c'est fait.. du moins en partie voici ce que ça donne :





Par contre j'ai pas compris au niveau du tableau qu'il faut faire. Je dois créer un autre document (word ou exel ?) et faire 2 colonnes et entrer la liste des entreprise dans 1 et le nom des dossiers dans l'autre.. c'est bien ça ?

Et ce document que dois l'appeler : ActiveDocument.Tables(1), je dois l'enregistrer à une place bien distincte ou c'est égal ?

Navrée..

Merci

ps : encore une petite question, le projet, je dois bien l'enregistrer quelque part.. j'enregistre donc le document pour garder les infos ? Il faut l'enregistrer spécialement ou pas ?

[Heureux-oli]

Salut,

La table doit être dans le document qui va contenir les UserForms, ce document ne servira qu'à appeler les autres templates.

[VayLoe]

Ok, ça donne donc ça :







PS : j'ai été obligée de sauvegarder le document au format .docm.. sinon il ne gardait pas la macro c'est bon ?

[Heureux-oli]

Salut,

Pour remplir la table, on va faire autrement que le remplissage manuel.

Comme à chaque fois, on va aussi utiliser une petite fonction pour nettoyer le texte des cellules.
Si on récupère le texte contenu dans une cellule sans le traiter, il contient deux caractères supplémentaires qui ne nous intéressent pas.

Pour l'instant, j'ai le même résultat que toi au niveau du UserForm.

À notre UserForm, nous allons ajouter deux zones de textes pour l'édition des entrées de la table, la première zone de texte servira à alimenter l'entreprise et la seconde zone le chemin du répertoire.

Pour alimenter le répertoire, nous allons utiliser une méthode de l'objet application qui est le FileDialog

Code :

Application.FileDialog(msoFileDialogFilePicker)

C'est un texte qui est renvoyé.

Pour éviter d'aller dans trop de direction, je vais essayer d'avancer proprement sur mon appli.

[VayLoe]

Coucou ,

Alors, j'ai ajouter les deux zones de texte à ma UserForm, une au-dessus de la liste pour les entreprise et l'autre au-dessus de celle pour les modèles.

par contre j'ai pas pas compris ça :

Envoyé par Heureux-oli

Pour alimenter le répertoire, nous allons utiliser une méthode de l'objet application qui est le FileDialog

Code :

Application.FileDialog(msoFileDialogFilePicker)

C'est un texte qui est renvoyé.

Je sais pas du tout ou il faut inscrire le code

Sinon, pas de soucis, prend ton temps, je ne suis pas pressée, et de toute façon je serais absente pendant le week-end de Pâques (camping avec les enfants).

[Heureux-oli]

Salut,
ce code n'est pas complet, c'est juste un exemple que l'on va utiliser sur l'action d'un bouton.

[VayLoe]

Aïe, bon ben voilà quoi

[Heureux-oli]

Salut,

Je pense avoir fait le tour de la question.

Un UserForm avec deux listes de choix, trois zones de texte et cinq boutons.

Pour faire un peu plus joli, j'ai ajouté un cadre.

La première étape est la récupération des informations dans la table pour alimenter la prmière zone de texte.

Comme ces informations seront rechargées plusieurs fois, la récupération se fait via une procédure séparée.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
 
Sub MettreListeAJour()
'Procédure de récupération des données de la table du document
'Déclaration des variables
'Les données seront stockées dans un tableau VBA avant d'être
'injectées dans la zone de liste
Dim oTbl As Table
Dim entreeTable() As String
Dim intR As Integer, intCR As Integer
 
'Affectation des données
Set oTbl = ActiveDocument.Tables(1)
intR = oTbl.Rows.Count
ReDim entreeTable(intR, 2)
 
'Boucle sur les lignes de la table
For intCR = 1 To intR
entreeTable(intCR - 1, 0) = intCR
entreeTable(intCR - 1, 1) = NetText(oTbl.Rows(intCR).Cells(1).Range.Text)
entreeTable(intCR - 1, 2) = NetText(oTbl.Rows(intCR).Cells(2).Range.Text)
 
 
Next intCR
'Affectation des données à la liste
Me.ListBox1.List() = entreeTable
 
 
End Sub

Dans cette procédure, on fait appel à une fonction de nettoyage, comme je l'ai souvent mentionné, une cellule en Word comporte deux caractère supplémentaires, si l'on souhaite traiter le contenu d'une cellule, il faut éliminer ces deux caractères.
je place généralement cette fonction dans un module que j'appelle Utilitaire. C'est une fonction puisqu'elle renvoie une chaîne.

Code :

1
2
3
4
5
6
7
 
Public Function NetText(stTemp As String) As String
'Nettoyage des données contenues dans les cellules des tables
NetText = Left(stTemp, Len(stTemp) - 2)
 
 
End Function

Nous allons appeler la procédure " MettreListeAJour " sur lévènement "Initialize" du UserForm

Code :

1
2
3
4
5
6
Private Sub UserForm_Initialize()
 
MettreListeAJour
Me.ListBox1.SetFocus
 
End Sub

Et par la même accasion, nous allons donner le Focus à la Zone de Liste.

Au chargement du UserForm, la zone de liste sera remplie avec le contenu de la table.

La procédure de remplissage remplit trois colonnes alors que notre table n'en contient que deux, la colonne supplémentaire va recevoir l'index de la ligne, ce sera plus facile pour faire nos traitements par la suite.

L'étape suivante sera le passage des données de la zone de liste vers les zones de texte pour une éventuelle modification.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Private Sub ListBox1_Click()
'Activation des boutons d'édition
Me.cmdModifier.Enabled = True
Me.cmdValider.Enabled = True
'Affectation des valeurs de la liste aux contrôles
'texte du formulaire
Me.txtItem = Me.ListBox1.Column(0)
Me.txtEntreprise = Me.ListBox1.Column(1)
Me.txtChemin = Me.ListBox1.Column(2)
'Appel de la fonction de remplissage de la
'seconde zone de liste
MettreListeModelAJour
 
End Sub

Le bouton d'édition Modifier et Valider ne doivent devenir Actif que si une valeur se trouve dans les zones de texte. Par la suite, ces boutons seront désactivés pour éviter certaines manipulations erronnées.

Lorsque l'on clique sur le bouton édition, on active les zones de textes.

Code :

1
2
3
4
5
6
7
8
Private Sub cmdModifier_Click()
'Activation des zones de texte
Me.txtChemin.Enabled = True
Me.txtEntreprise.Enabled = True
'Activation du bouton pour le chemin
Me.cmdDefinePath.Enabled = True
 
End Sub

Le bouton du chemin va faire appel à un objet FileDialog qui appartient à l'Objet Application.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
Private Sub cmdDefinePath_Click()
'Mise à jour du chemin du répertoire
'Déclaration d'un Objet FileDialog pour réupérer un
'répertoire
Dim oDlg As FileDialog
 
'Affectation et affichage de la boîte de dialogue
Set oDlg = Application.FileDialog(msoFileDialogFolderPicker)
oDlg.Show
'Récupération de la chaîne de caractère
'pour l'affecter à la zone de texte txtchemin
Me.txtChemin = oDlg.SelectedItems(1)
 
Set oDlg = Nothing
 
 
End Sub

Le résultat sera directement envoyé dans la zone de texte.

Lorsque les données ont été modifiées, il faut les écrire dans la table, j'utilise un bouton valider.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Private Sub cmdValider_Click()
'Déclaration des variables
Dim oTbl As Table
'Affectation des Objets
Set oTbl = ActiveDocument.Tables(1)
'Écriture dans la table, c'est ici que l'index de
'la ligne est utilisé.
With oTbl.Rows(Me.txtItem)
    .Cells(1).Range.Text = Me.txtEntreprise
    .Cells(2).Range.Text = Me.txtChemin
End With
'Appel de la procédure de mise à jour de la liste
MettreListeAJour
'Désactivation des contrôles
Me.txtChemin.Enabled = False
Me.txtEntreprise.Enabled = False
Me.txtItem.Enabled = False
Me.cmdDefinePath.Enabled = False
Me.cmdModifier.Enabled = False
Me.cmdValider.Enabled = False
 
Set oTbl = Nothing
 
End Sub

Cette procédure fait à nouveau appel à la liste pour qu'elle soit mise à jour avec les modifications.

La mise à jour de la liste des modèles fait appel à la bibliothèque Microsoft Scripting RunTime. cette bibliothèque permet de travailler avec et sur le système de fichier de Windows.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
 
Sub MettreListeModelAJour()
'Utilistation de la bibliothèque
'Microsoft Scripting RunTime (FileSystemObject)
Dim oFSO As FileSystemObject
Dim oFol As Folder
Dim oFil As File
 
Set oFSO = New FileSystemObject
Set oFol = oFSO.GetFolder(Me.ListBox1.Column(2))
'On vide la liste avant de la remplir
Me.ListBox2.Clear
 
'Boucle sur les fichiers du répertoire
For Each oFil In oFol.Files
'Tri des fichiers pour ne pas tous les afficher
Select Case Right(oFil.Name, 3)
'Pour les Dotx
Case "otx"
 
Me.ListBox2.AddItem oFil.Name
'Pour les Dotm
Case "otm"
 
Me.ListBox2.AddItem oFil.Name
'Pour les Dot
Case "dot"
 
Me.ListBox2.AddItem oFil.Name
End Select
Next oFil
 
Set oFol = Nothing
Set oFSO = Nothing
 
End Sub

J'ai aussi prévu d'ajouter une entreprise par le code.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
Private Sub cmdAddEntreprise_Click()
'Ajout d'un nouvelle ligne
Me.txtChemin.Enabled = True
Me.txtEntreprise.Enabled = True
Me.txtItem.Enabled = True
Me.cmdDefinePath.Enabled = True
Me.cmdModifier.Enabled = True
Me.cmdValider.Enabled = True
'Ajout d'une ligne
ActiveDocument.Tables(1).Rows.Add
'Récupération du nombre de lignes
Me.txtItem = ActiveDocument.Tables(1).Rows.Count
Me.txtChemin = ""
Me.txtEntreprise = ""
Me.txtChemin.SetFocus
 
End Sub

Et la création d'un document sur base du contenu de la seconde liste

Code :

1
2
3
4
5
6
7
8
9
10
 
Private Sub cmdCreateDoc_Click()
Dim oDoc1 As Document
Dim oDoc2 As Document
 
Set oDoc1 = ActiveDocument
 
MsgBox Me.txtChemin & "\" & Me.ListBox2
 
End Sub

Dans ce code, le document n'est pas crée, mais j'affiche le chemin complet.

Pour la création du document, c'est

Code :

Documents.Add (LecheminDuModèle)

Voilà, j'espère ne rien avoir oublié.
Je met mon exemple sur le forum.

[VayLoe]

Coucou,

J'espère que tu as passé de bonnes fêtes de Pâques

Merci pour tout ce travail

Tout me semble très bien, c'est tout à fait dans l'esprit de ce que je pensais.

Je teste tout ça.. du moins j'essaie de tester tout ça et je te redonne des nouvelles, mais comme c'est la fin du mois, j'ai passablement de boulot

Donc je vais tester tout ça début de la semaine prochaine

Encore merci