Export de plusieurs variables avec PROC UNIVARIATE [Résolu]

[Mark531]

Bonjour,

J'essaie désespérément d'exporter les stats de plusieurs variables dans une table. Je me suis aperçu que PROC MEANS exportait les stats en ligne, or je préfère les avoir en colonne. Je me suis donc tourné vers PROC UNIVARIATE mais elle ne semble pas gérer l'export de plusieurs variables.

Par exemple, le code suivant :

Code :

1
2
3
4
PROC UNIVARIATE NOPRINT DATA=matable;
VAR x y;
OUTPUT OUT=temp MEAN=moyenne;
RUN;

n'exporte que la moyenne de la variable x dans la table matable. Comment faire ?

Merci d'avance,
Mark

[MEGAMIND2]

Bonjour,
La proc means est pas mal aussi pour faire ça, puis tu transposes

Code :

1
2
3
4
5
6
7
8
proc means DATA=sashelp.class;
var  Weight Height;
OUTPUT OUT=temp(DROP=_TYPE_ _FREQ_) MEAN=;
RUN;
 
proc transpose DATA=temp out=transpose name=variable prefix=moyenne;
var Weight Height;
run;

Bon courage!

[Manoutz]

pour la proc univariate il faut mettre autant de statistiques que de variables sinon sas ne peut pas comprendre!

Code :

1
2
3
4
PROC UNIVARIATE NOPRINT DATA=sashelp.bweight;
VAR weight m_wtgain;
OUTPUT OUT=temp MEAN=moyenne1 moyenne2;
RUN;

[Mark531]

Ah ok, c'était un problème de syntaxe ! Si seulement l'aide de SAS donnait des exemples...

Le problème, c'est que le tableau n'a pas la forme que je souhaite :

Code :

1
2
3
4
PROC UNIVARIATE NOPRINT DATA=matable;
VAR x y;
OUTPUT OUT=temp MEAN=moy1 moy2 STD=std1 std2;
RUN;

Je me retrouve avec un tableau de la forme :

moyX moyY stdX stdY
1

Or, je souhaiterais avoir un tableau de la forme :

moy std
x
y

Un tableau de stats classique quoi ! Malheureusement, ça ne semble pas transposable facilement avec PROC TRANSPOSE... Vous avez une idée ?

[Manoutz]

c'est surement jouable avec la transpose, voici en tout cas une solution avec une étape data (qui présente l'avantage contrairement à la transpose de pouvoir effectuer des manipulations complémentaires).

J'ai rajouté une variable "var_orig" pour être sur de ne pas se mélanger les pinceaux...

Code :

1
2
3
4
5
6
7
8
9
10
11
12
PROC UNIVARIATE NOPRINT DATA=sashelp.bweight;
VAR weight m_wtgain;
OUTPUT OUT=temp MEAN=moyenne1 moyenne2 std=std1 std2;
RUN;
 
DATA Tablefinale; 
length var_orig$50.;
SET temp(keep=moyenne1 std1 IN=A)
	temp(keep=moyenne2 std2 RENAME=(moyenne2=moyenne1 std2=std1) IN=B);
	IF A then var_orig=	"weight";
	IF B then var_orig=	"m_wtgain";
run;

[olivier.decourt]

Si tu veux récupérer des statistiques comme une moyenne, un écart-type, un min et un max et le nombre d'observations renseignées, tu peux utiliser la proc CORR (à contre-emploi mais directement avec la mise en forme voulue).
L'avantage c'est que ça fonctionne pareil avec 250 variables numériques, et s'il y a des calculs par blocs de variables quali, on ajoute un BY.

Code :

1
2
3
4
5
6
ODS EXCLUDE ALL ;
ODS OUTPUT simpleStats=work.stats ;
PROC CORR DATA=sashelp.class ;
  VAR weight height ;
RUN ;
ODS SELECT ALL ;

Olivier

[Mark531]

Oui, la PROC CORR exporte en effet des stats descriptives comme je le veux !

C'est fou qu'on ne puisse pas le faire simplement, la solution de Manoutz est quand même très compliquée et demande déjà une sacrée maitrise...

Merci à vous !