Problème : Compile error : Method or data member not found [Résolu]

[Nitromard]

Bonjour à tous,

Je suis débutant en programmation VBA et j'ai un petit problème avec un programme.
En fait j'ai testé ce probgramme sur Excel et il fonctionne très bien (il faut juste mettre la référence Microsoft Outlook library.
Mais il faudrait que je puisse le faire fonctionner avec VBA mais sous Access, le porblème est que j'ai l'erreur : "Compile error : Method or data member not found" qui apparait sur une ligne de code indiquée en rouge dans le programme suivant :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
Sub Test()
'Arg 1 = Folder name in your Inbox
'Arg 2 = File extension, "" is every file
'Arg 3 = Save folder, "C:\Users\Ron\test" or ""
'If you use "" it will create a date/time stamped
'folder for you in the "My Documents" folder.
'Note: If you use this "C:\Users\Ron\test" the folder must exist

    SaveEmailAttachmentsToFolder "MyFolder", "xls", ""

End Sub



Sub SaveEmailAttachmentsToFolder(OutlookFolderInInbox As String, _
                                 ExtString As String, DestFolder As String)
    Dim ns As Namespace
    Dim Inbox As MAPIFolder
    Dim SubFolder As MAPIFolder
    Dim Item As Object
    Dim Atmt As Attachment
    Dim FileName As String
    Dim MyDocPath As String
    Dim I As Integer
    Dim wsh As Object
    Dim fs As Object

    On Error GoTo ThisMacro_err

    Set ns = GetNamespace("MAPI")
    Set Inbox = ns.GetDefaultFolder(olFolderInbox)
    Set SubFolder = Inbox.Folders(OutlookFolderInInbox)

    I = 0
    ' Check subfolder for messages and exit of none found
    If SubFolder.Items.Count = 0 Then
        MsgBox "There are no messages in this folder : " & OutlookFolderInInbox, _
               vbInformation, "Nothing Found"
        Set SubFolder = Nothing
        Set Inbox = Nothing
        Set ns = Nothing
        Exit Sub
    End If

    'Create DestFolder if DestFolder = ""
    If DestFolder = "" Then
        Set wsh = CreateObject("WScript.Shell")
        Set fs = CreateObject("Scripting.FileSystemObject")
        MyDocPath = wsh.SpecialFolders.Item("mydocuments")
        DestFolder = MyDocPath & "\" & Format(Now, "dd-mmm-yyyy hh-mm-ss")
        If Not fs.FolderExists(DestFolder) Then
            fs.CreateFolder DestFolder
        End If
    End If

    If Right(DestFolder, 1) <> "\" Then
        DestFolder = DestFolder & "\"
    End If

    ' Check each message for attachments and extensions
    For Each Item In SubFolder.Items
        For Each Atmt In Item.Attachments
            If LCase(Right(Atmt.FileName, Len(ExtString))) = LCase(ExtString) Then
                FileName = DestFolder & Item.SenderName & " " & Atmt.FileName
                Atmt.SaveAsFile FileName
                I = I + 1
            End If
        Next Atmt
    Next Item

    ' Show this message when Finished
    If I > 0 Then
        MsgBox "You can find the files here : " _
             & DestFolder, vbInformation, "Finished!"
    Else
        MsgBox "No attached files in your mail.", vbInformation, "Finished!"
    End If

    ' Clear memory
ThisMacro_exit:
    Set SubFolder = Nothing
    Set Inbox = Nothing
    Set ns = Nothing
    Set fs = Nothing
    Set wsh = Nothing
    Exit Sub

    ' Error information
ThisMacro_err:
    MsgBox "An unexpected error has occurred." _
         & vbCrLf & "Please note and report the following information." _
         & vbCrLf & "Macro Name: SaveEmailAttachmentsToFolder" _
         & vbCrLf & "Error Number: " & Err.Number _
         & vbCrLf & "Error Description: " & Err.Description _
         , vbCritical, "Error!"
    Resume ThisMacro_exit

End Sub

Ce programme permet d'enregistrer des pièces jointes d'un email d'un folder automatiquement.

Quelqu'un aurait une idée de comment résoudre mon problème?

[marot_r]

As-tu mis une référence sur Outlook (et si oui la même qu'en Excel) dans Access ?

A+

[Nitromard]

Oui, j'ai mis la même référence que dans excel : Microsoft Outlook 12.0 Object Library.
N'importe qui peut l'essayer je pense, elle fera la même erreur.

[marot_r]

Essaye de mettre la ligne en commentaire et de recompiler le code. Dés fois l'erreur signalée n'est la source réelle du problème.

A+

[Nitromard]

Hey,

J'ai mis la ligne en commentaire comme tu me l'as demandé j'obtiens une erreur du type :

An unexpected error has occured
Please note and report the following information.
Macro Name : SaveEmailAttachmentsToFolder
Error Number : 13
Error description : Type mismatch

[marot_r]

Attention, il ne faut pas exécuter le code mais il faut simplement le compliler (menu debogage/complier) pour voir si une autre erreur ne serait pas la cause du problème. .

Si le compliateur ne dit rien alors c'est que c'est bien cette ligne qui est en erreur et je n'en vois pas la cause.

A+

[Nitromard]

Bonjour,

Bon malheureusement j'ai compilé le code avec la ligne, il me donnait la mm erreur que précédemment ensuite j'ai essayé avec la ligne en commentaire et il ne me dit effectivement rien.
Donc c'est bien cette ligne qui a un problème...

[pgz]

Bonjour.

Il y a peut-être confusion entre la classe Attachment d'access et celle d'outlook. Dans tes déclarations, précise

Code :

Dim Atmt as Outlook.Attachment

Pour voir.

Cordialement,

PGZ

[Nitromard]

Super ça fonctionne!

Merci bcp ^^
(comment je fais pour mettre la discussion en résolue?)

Cordialement,

Nitromard