Concaténation selon critère [Résolu]

[JimJames23]

Bonjour à tous,

J'ai un problème en SAS ou plutot besoin d'aide!
J'ai un tableau du style :

Id N° Distance
1 a 10
1 b 15
1 c 23
2 b 11
2 d 0.5
...

Je veux obtenir une liste concaténé des numéros et distances, dans le style :

Id Liste_N° Liste_Dist
1 a,b,c 10,15,23
2 b,d 11,0.5

J'imagine qu'il faudrait un tableau et concaténer dans le cas où l'id est le meme mais je ne vois pas comment faire concrétement en terme de code.

Merci d'avance.

[MEGAMIND2]

Bonjour,
Une des solutions parmi tant d'autres...

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
DATA TEST;
INPUT
Id NUM $ Distance;
cards;
1 a 10
1 b 15
1 c 23
2 b 11
2 d 0.5
RUN;
 
PROC TRANSPOSE DATA=TEST OUT=distance(DROP=_NAME_) prefix=distance;
VAR  Distance;
BY Id;
RUN;
PROC TRANSPOSE DATA=TEST OUT=NUM(DROP=_NAME_) prefix=NUM;
VAR  NUM;
BY Id;
RUN;
DATA TRANSPOSE;
MERGE NUM distance;
BY ID;
RUN;

Bonne journée!

[JimJames23]

Tout d'abord merci pour ta réponse, elle me satisfait à 99% dans le sens où je voudrais juste une liste des "n" distances plutot que n colonnes des distances.

Du genre 10,12,13,14 plutot que 10 12 13 14
Est ce que c'est possible?

Merci

Edit : Plus exactement avec la table que je viens de créer grace à toi :
Id N°1 N°2 Dist1 Dist2
1 a b 10 15
2 c a 7 8

Je voudrais :
Id Dist
1 a(10), b(15)
2 c(7), a(8)

Je ne sais pas si c'est possible sous SAS.

[MEGAMIND2]

Envoyé par JimJames23

Tout d'abord merci pour ta réponse, elle me satisfait à 99% dans le sens où je voudrais juste une liste des "n" distances plutot que n colonnes des distances.

Du genre 10,12,13,14 plutot que 10 12 13 14
Est ce que c'est possible?

Merci

Les 1% pour te satisfaire

Code :

1
2
3
4
5
6
DATA TRANSPOSE;
MERGE NUM distance;
BY ID;
NUM=(compress(NUM1!!","!!NUM2!!","!!NUM3));
distrance=(compress(distance1!!","!!distance2!!","!!distance3));
RUN;

[olivier.decourt]

Voici une solution sans transposer.
Le RETAIN est indispensable pour mémoriser la valeur de l'observation précédente et l'augmenter. CATX existe à partir de SAS 9. Si tu as SAS 8, il faudra bricoler avec les fonctions LEFT et TRIM et des concaténations || ou !!.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
DATA TEST;
INPUT
Id NUM $ Dist ;
cards;
1 a 10
1 b 15
1 c 23
2 b 11
2 d 0.5
RUN;
DATA work.res (DROP=num dist) ;
  SET work.test ;
  BY id ; /* attention à trier au préalable ! */
  RETAIN liste_num liste_dist ;
  LENGTH liste_num liste_dist $ 1000 ;
  IF FIRST.id THEN DO ; /* initialisation */
    liste_num = "" ;
	liste_dist = "" ;
  END ;
  liste_num = CATX(",",liste_num,num) ;
  liste_dist = CATX(",",liste_dist,dist) ;
  IF LAST.id THEN OUTPUT ; /* on conserve 1 ligne */
RUN ;

Bon courage.
Olivier

[JimJames23]

Envoyé par MEGAMIND2

Les 1% pour te satisfaire

Code :

Ca me va mais le problème c'est que mon nombre de num et de distance est variable. Par exemple, pour l'id 1 je vais avoir 3 distances et pour l'id 5 , 10 distances...compress peut prendre un paramètre?

[MEGAMIND2]

Envoyé par JimJames23

Ca me va mais le problème c'est que mon nombre de num et de distance est variable. Par exemple, pour l'id 1 je vais avoir 3 distances et pour l'id 5 , 10 distances...compress peut prendre un paramètre?

Il faut passer par des macros pour récuprer le nombre de colonnes maximale (et donc ne pas taper distance1,...). Dans ce cas, tu peux envisager la solution proposée par Olivier (je n'ai pas testé mais je lui fais confiance)

[JimJames23]

Grace à vos idées à tous les 2, j'ai reussi ca marche.

Merci beaucoup et bravo pour la rapidité.