Afficher une fenêtre de téléchargement: ouvrir/enregistrer [Résolu]

[amAtunisian]

Bonjour,

je voudrais afficher une fenêtre comme celle jointe : image
et j'ai ce code pour faire cela :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
 response.clear() ' Vide le buffer'
 
   ' Dialogue de téléchargement'
   response.contentType = "application/pdf"
 
   response.addHeader "Content-Disposition","attachment; filename=asp.pdf"
   response.flush() ' Envoie le buffer'
   Response.End() 
   ' Lecture du fichier'
   set FSO = Server.CreateObject("Scripting.FileSystemObject")
   set inF = FSO.OpenTextFile("asp.pdf",1,false)
   t = inF.readAll
   inf.close
 
   response.write(t) ' Envoie le contenu du fichier'

le document pdf téléchargé est vide et voici l'erreur qui s'affiche :
adobe reader could not open because it is either not a supported file type or because the file has been damaged (for example, it was sent as an email attachement and wasn't correctly decoded)

[eclisse]

Tiens, si ça peut répondre à ton problème...

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
response.Clear
Response.AddHeader "Content-Disposition","attachment; filename=asp.pdf"
fn = "asp.pdf" 
FPath = server.MapPath(fn)
Response.AddHeader "Content-Disposition", "attachment; filename=" & fn 
 
Set adoStream = CreateObject("ADODB.Stream") 
chunk = 2048 
adoStream.Open() 
adoStream.Type = 1 
adoStream.LoadFromFile(FPath) 
iSz = adoStream.Size 
Response.AddHeader "Content-Length", iSz 
For i = 1 To iSz \ chunk 
	If Not Response.IsClientConnected Then Exit For 
	Response.BinaryWrite adoStream.Read(chunk) 
Next 
 
If iSz Mod chunk > 0 Then 
	If Response.IsClientConnected Then 
		Response.BinaryWrite adoStream.Read(iSz Mod chunk) 
	End If 
End If 
 
adoStream.Close 
Set adoStream = Nothing 
Response.End

[amAtunisian]

Je vous remercie