Formulaire et Mot de passe

[bibi28]

Bonjour à tous,

j'ai une base de données avec access 2003 et un formulaire d'accueil. Je voudrais créer un mot de passe sur ce formulaire afin d'autoriser que les personnes ayant ce mot de passe a consulter la base.

Merci de vos réponses.

A +

[Philippe JOCHMANS]

Bonjour

Merci de faire des recherches :

Les sécurités avec Microsoft ACCESS.
Formulaire Login/mot de passe

Philippe

[PapouDomi]

Bonjour.
Créer une table Utilisateurs contenant un identifiant unique par utilisateur, son mot de passe et éventuellement ses nom et prénom
Au démarrage de l'application, ouvrir le formulaire d'accueil contenant une liste déroulante basée sur la table Utilisateurs (colonne 0: Identifiant, colonne 1: Mot de passe) et une zone de texte pour saisir le mot de passe.
Sur l'évènement "Après mise à jour" du mot de passe, comparer le mot de passe saisi avec la colonne 1 de l'utilisateur choisi dans la liste déroulante.
Si tu ne veux pas de liste déroulante,remplace la liste déroulante par une zone de texte et utilise une fonction vérifiant le mot de passe à l'aide d'une requête lancée par l'évènement "Après mise à jour" du mot de passe.
Le code ci-dessous contient les 2 solutions.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
Option Compare Database
Option Explicit
 
Private Function TestPassword(ByVal strIdUser As String, ByVal strPw) As Boolean
'Cette fonction vérifie le mot de passe de l'utilisateur
'Elle retourne vrai si le mot de passe est correct
 
'Entrées: strIdUser:  Identifiant utilisateur
'         strPW:      Mot de passe saisi
 
  Dim oMyDtb As Database    'Base de données courante
  Dim oMyQry As QueryDef    'Requête de recherche du mot de passe
  Dim oRst As Recordset     'Résultat de la requête
 
  'Initialisation
  TestPassword = False
 
  Set oMyDtb = CurrentDb
 
  'Créer la requête
  Set oMyQry = oMyDtb.CreateQueryDef("")
  oMyQry.SQL = "SELECT id, Password " & _
               "FROM tblUsers " & _
               "WHERE Id=""" & strIdUser & """ AND Password=""" & strPw & """;"
  'Exécuter la requête
  Set oRst = oMyQry.OpenRecordset()
 
  If Not (oRst.EOF) Then
    TestPassword = True
  End If
 
  Set oRst = Nothing
  Set oMyQry = Nothing
  Set oMyDtb = Nothing
 
End Function
 
 
Private Sub cboUser_AfterUpdate()
'Liste déroulante de saisie utilisateur
  txtPassword = ""
End Sub
 
Private Sub Form_Open(Cancel As Integer)
  cboUser = ""
  txtPassword = ""
End Sub
 
Private Sub txtPassword_AfterUpdate()
'Zone de texte de saisie utilisateur
 
'1ère solution avec liste déroulante
'  If txtPassword = cboUser.Column(1) Then
'  'Ouvrir le formulaire principal
'  'Fermer le formulaire d'accueil
'  Else
'    MsgBox "Mauvais mot de passe"
'    DoCmd.Quit
'  End If
 
'2ème solution avec requête
  If TestPassword(txtUser, txtPassword) Then
  Else
    MsgBox "Mauvais mot de passe"
    DoCmd.Quit
  End If
 
End Sub
 
 
Private Sub txtUser_Click()
'Lone de texte de saisie utilisateur
  txtPassword = ""
End Sub

Ne pas oublier de neutraliser la touche "Shift" qui neutralise tous les paramètres de démarrage.
Cordialement, Dominique.

[bibi28]

bonjour

je teste et te tiens informé

merci

a +