Multiplication du nombre de lignes [Résolu]

[ycolpin]

Bonjour,
Petite question d'un débutant...
J'ai une table T1 dans laquelle j'ai 3 colonnes avec, mettons les données suivantes :
START_DATE | END_DATE | NB_WEEKS | WORKLOAD_PER_WEEK
14/03/2011 | 16/03/2011 | 1 | 1
14/03/2011 | 30/03/2011 | 3 | 4

Ceci corresponds à une list de tâches à réaliser avec la date de début de semaine de la tâche, la date de fin, le nombre de semaine entre ces deux dates, le nombre de jours à faire pour réaliser cette tâche.

Je souhaiterais transformer cette table de sorte que
1. chaque ligne soit dupliquées autant de fois qu'il y a de NB_WEEKS
2. si une ligne est dupliquée la start_date sera incrémentée de +7 jours à chaque duplication.

Pour notre exemple,
- la première ligne serait donc copiée telle quel, car NB_WEEK = 1
- la seconde ligne serait donc dupliquée 2 FOIS (car NB_WEEK = 3). La première duplication entraine START_DATE = START_DATE + 7 et la seconde duplication entraine START_DATE = START_DATE + (7x2)

La table cible serait donc la suivante :
START_DATE | END_DATE | WORKLOAD_PER_WEEK
14/03/2011 | 16/03/2011 | 1
14/03/2011 | 30/03/2011 | 4
21/03/2011 | 30/03/2011 | 4
28/03/2011 | 30/03/2011 | 4


C'est probablement un cas d'école pour les experts mais pour les débutants, y'a de quoi s'arracher les cheveux... (s'il nous en reste !)

Merci pour votre aide!!

[olivier.decourt]

Bonjour.
Une étape Data ferait ça très bien, à condition d'y inclure une boucle au sein de laquelle une instruction OUTPUT force l'écriture d'une nouvelle observation.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
DATA work.a_faire ;
  INFILE DATALINES DLM="|" MISSOVER DSD ;
  INPUT START_DATE :ddmmyy10.
        END_DATE   :ddmmyy10.
        NB_WEEKS 
        WORKLOAD_PER_WEEK ;
  FORMAT start_date end_date DDMMYY10. ;
DATALINES ;
14/03/2011 | 16/03/2011 | 1 | 1
14/03/2011 | 30/03/2011 | 3 | 4
;
RUN ;
DATA work.par_semaine ;
  SET work.a_faire ;
  end = start_date ;
  FORMAT end DDMMYY10. ;
  DO i=1 TO nb_weeks ;
    end = MIN(end+7, end_date) ;
	OUTPUT ;
  END ;
RUN ;

A ta disposition si tu souhaites des précisions.
Bon courage.
Olivier

[sasadm]

Bonjour,
Voici une solution:

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
DATA test;
informat START_DATE   END_DATE ddmmyy10.;
format START_DATE   END_DATE ddmmyy10.;
INFILE cards dlm="|";
input START_DATE   END_DATE   NB_WEEKS   WORKLOAD_PER_WEEK;
cards;
14/03/2011 | 16/03/2011 | 1 | 1
14/03/2011 | 30/03/2011 | 3 | 4
;
run;
 
DATA test2;
SET test;
output;
IF NB_WEEKS > 1 then do i=2 TO  NB_WEEKS;
	START_DATE = START_DATE + 7;
output;
end;
keep START_DATE END_DATE WORKLOAD_PER_WEEK;
run;

[MEGAMIND2]

Code :

1
2
3
4
5
6
7
8
9
data test2;
set test;
output;
if NB_WEEKS > 1 then do i=2 to  NB_WEEKS;
	START_DATE = START_DATE + 7;
output;
end;
keep START_DATE END_DATE WORKLOAD_PER_WEEK;
run;

Le premier Output sert à quoi Sasadm? juste pour comprendre!

[sasadm]

Bonjour Brice,

L'output est la commande qui provoque l'écriture du vecteur de travail (<=> ecriture d'une observation dans la table de sortie). Par défaut, l'output est implicite. Si on devait le placer dans une étape data classique, il faudrait le mettre juste avant le run:

Code :

1
2
3
4
5
 
DATA test;
SET test;
...
run;

équivaut à

Code :

1
2
3
4
5
6
 
DATA test;
SET test;
...
output;
run;

Donc j'emploie un output juste après le set pour dire à SAS d'écrire dans la table de sortie l'observation de la table d'entrée telle quelle (sans modification).
Ensuite si NB_WEEk est superieure ou égale à 2 il y a déclenchement d'une boucle do toujours à partir du même vecteur de travail, ce qui permet d'incrémenter date_start de 7 jours en 7 jours.
Pour que chaque iteration produise l'écriture d'une observation, je ré-emploie la commande output dans la boucle.

Si je ne suis pas clair, relance le code en enlevant/ajoutant/deplaçant des output. Tu verras quel est l'impact sur la sortie.

[MEGAMIND2]

Justement, j'ai testé et ça ne marche pas sans le premier output, c'est pour ça que je voulais comprendre le pourquoi. En tout cas tu as été assez clair.

[sasadm]

Petite précision:

Olivier fait nb_weeks iteration (i=1 to nb_weeks ). Sa premiere itération correspond à mon premier output.

Moi je fais un output d'entrée et s'il y a lieu, j'enchaine par nb_weeks-1 iterations puisque je commence par i=2.

[MEGAMIND2]

Yep!!

[ycolpin]

Franchement, merci! je ne m'attendais pas à des réponses aussi précises, rapides et efficaces!
A bientôt!