[XL-2007] Calcul des droits par tranche et suivant montant de la transaction.

[Abdelinho]

Bonjour.
J’en ai déjà posté cette question et je n’ai pu avoir la réponse qu’il faut, peut cela est du à ma façon de s’exprimer. Au je répète en étant plus circoncis. Exemple d’un agent immobilier qui touche ses droits suivant le montant de la transaction : pour la tranche allant de 1 à
500 000,00 Euros il a doit a 3%, pour la tranche allant de 500 000,00 à 1 000 000,00 il touche 2%, pour plus de 1 000 000,00 il touche 1%. Quelle formule appliquée.
Exemple :
Pour une transation de 650 000,00 il touche 18 000,00 (15 000 + 3000)
Pour une transaction de 900 000,00 il touche 23 000,00 (15 000+8 000)
Pour une transaction de 1 200 000,00 il touche 27 000,00 (15 000+ 10 000+2 000)
Pour une transaction de 2 450 000,00 il touche 39 500,00 (15 000+10 000+ 14 5000)
A conclure que pour les premiers 500 000,00 il touche 15 000,00, pour les seconds 500 000,00 il touche 10 000,00 ce qui fait 25 000,00 pour le 1 000 000,00 d’euros, pour ce qui est plus de 1 000 000,00 il touche 1%.
Merci d’avance

[spepok]

Bonsoir a tous ,

Peux tu essayer avec :

=SI(A1="";"";MIN(5*10^5;A1)*0,03+(MIN(5*10^5;MAX(0;A1-5*10^5))*0,02)+(MAX(0;A1-10^6)*0,01))

la somme de la transaction étant bien sur en A1.

Amicalement

[spepok]

Bonsoir forum ,

Suite au message privé de notre ami ,voici une solution pour un problème similaire.
Question:

1ere formule concernant: pour moins de 50000 c'est 2% et pour plus c'est 1%;
2ème formule:
mois cde 20 000 = 5 %
entre 20000 et 30000 = 1%
entre 30 000 et 40 000 =0,70 %
entre 40 000 et 50 000=0,60%
plus de 50 000= 0,50 .

Solution proposée:

=SI(A1="";"";PRODUITMAT({0,02.-0,01};(A1-{0;50000})*(A1>{0;50000})))

pour la 1°formule
et

=SI(A1="";"";PRODUITMAT({0,05.-0,04.-0,003.-0,001.-0,001};(A1-{0;20000;30000;40000;50000})*(A1>{0;20000;30000;40000;50000})))

pour la 2°

Suivant les versions excel , il faudra peut-être remplacer les "." par "\".
Je dois reconnaitre que j'ai seulement adapté une formule trouvée sur un site ami que j'avais gardé en copie.
Merci à l'auteur (dont je ne me souviens plus le nom) s'il passe par là.

Amicalement

[hben1961]

Bonjour à tous,

Essayes avec la formule suivante (en supposant le montant de la transaction en A1) :

Code :

=SI(A1>1000000;25000+(A1-1000000)*1%;SI(A1>500000;15000+(A1-500000)*2%;A1*3%))

Cordialement

[Abdelinho]

Bonjour.
Merci de votre assistance. Y'a que lors de l'application de la 1ère formule avec des taux différents ça n'a pas marché:
La formule dont il s'agissait: pour moins de 50000 c'est 2% et pour plus c'est 1%;
J'ai voulu l'appliquer pour des calculs tel : pour moins de 50000 c'est 1% et pour plus c'est 0,75.
Mois j'ai mis
=SI(A1="";"";PRODUITMAT({0,01.-0,0075};(A1-{0;500000})*(A1>{0;500000}))).
Manière de remplacer les taux. Mais ça n'a pas marcher. pourriez vous m'aider ?
Merci d'avance.

[GerardCalc]

Bonjour,

Dans la première constante de matrice, le premier chiffre est le taux de la première tranche. Les taux suivants ne sont pas les taux des tranches suivantes mais les différences de taux :

=SI(A1="";"";PRODUITMAT({0,01.-0,0025};(A1-{0;500000})*(A1>{0;500000})))

Si tu avais 3 taux successifs pour 3 tranches, par exemple 1% 0,8% et 0,5% la matrice serait 1% 0,8%-1% et 0,5%-0,8% soit {0,01.-0,002.-0,003}

A+

Edit : Mais le plus simple est d'utiliser SOMMEPROD avec un tableau récap.
C'est + facile si tu doit modifier les taux de les modifier dans les cellules plutôt que dans une formule.
Ci-joint un exemple avec les taux d'imposition.

J'oubliais que j'étais sur le forum Excel (j'utilise LibreOffice).
Remplaces

Code :

=SOMMEPROD(C11>A2:A6;C11-A2:A6;B2:B6-B1:B5)

Code :

=SOMMEPROD((C11>A2:A6)*(C11-A2:A6);B2:B6-B1:B5)