Cherche informat pour DATETIME [Résolu]

[hoccha]

Bonjour ,
Je suis nouveau dans SAS et je suis un peux perdu là... j’ai quelque problèmes avec un informat.
Je cherche à lire des dates de ce type :

2010-03-13 16:37:56
2010-03-18
2010-03-14 18:19:05
2010-03-08 12:00:00
2010-03-17

Donc parfois j’ai le time mais pas toujours. Pourriez-vous svp m’aider à trouver le bon informat ?
Un grand merci d'avance!

[bahraoui]

bonjour,

Je pense qu'il faut créer une variable date et une variable time, après tu peux recréer une variable de type datetime à partir des deux variables créées avant.

[s_a_m]

ANYDTDTMw.

[s_a_m]

sorry

utilises plutôt substr pour extraire la date sans les time ;

[MEGAMIND2]

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
DATA TEST;
	INPUT date  $1-11 time $12-20;
	date2=MDY
	( INPUT(substr(date,6,2),BEST.),
	  INPUT(substr(date,9,2),BEST.),
	  INPUT(substr(date,1,4),BEST.));
	FORMAT date2 date.;
	IF time='' THEN time='00:00:00';
	datetime=INPUT(PUT(date2,date.)!!":"!!time,DATETIME.);
	FORMAT datetime DATETIME.;	
DATALINES;
2010-03-13 16:37:56
2010-03-18
2010-03-14 18:19:05
2010-03-08 12:00:00
2010-03-17 
;
RUN;

[olivier.decourt]

Envoyé par s_a_m

ANYDTDTMw.

Pourquoi te rétracter Sam ? Ca fonctionne très bien avec cet informat, en le faisant précéder des : pour dire que c'est sur 20 caractères au maximum...

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
OPTION DATESTYLE=YMD ;
DATA work.test ;
  INFILE DATALINES DLM="," ;
  INPUT dt :ANYDTDTM20. ;
  FORMAT dt DATETIME. ;
DATALINES ;
2010-03-13 16:37:56
2010-03-18
2010-03-14 18:19:05
2010-03-08 12:00:00
2010-03-17 
;
RUN ;
PROC PRINT ;
RUN ;

Et sinon Brice, pour ta solution, on peut quand même faire un poil plus simple avec des fonctions INPUT. (Et comme ça, partir en week-end plus vite.)

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
DATA TEST;
input date  $1-11 time $12-20 ;
datetime = INPUT(date,YYMMDD10.) * 24 * 60 * 60 ;
IF time NE "" THEN datetime = datetime + INPUT(time,TIME8.) ;
FORMAT datetime DATETIME. ;
cards;
2010-03-13 16:37:56
2010-03-18
2010-03-14 18:19:05
2010-03-08 12:00:00
2010-03-17 
;
run;
PROC PRINT ;
RUN ;

[MEGAMIND2]

[s_a_m]

Envoyé par olivier.decourt

Pourquoi te rétracter Sam ? Ca fonctionne très bien avec cet informat, en le faisant précéder des : pour dire que c'est sur 20 caractères au maximum...

Code :

Bonjour Olivier;
DLM="," le CODE ne marche pas et avec un DLM= " ", l'heure est : 00:00:00, d'où le subsrt pour extraire les dates et l'geure et concatiner par la suite et j'opte pour ta deuxième solution.

[MEGAMIND2]

Envoyé par s_a_m

Bonjour Olivier;
DLM="," le CODE ne marche pas et avec un DLM= " ", l'heure est : 00:00:00, d'où le subsrt pour extraire les dates et l'geure et concatiner par la suite et j'opte pour ta deuxième solution.

J'ai testé sur la V9.2 ça marche et non sur V9.1, faut vivre avec son temps Sam

[s_a_m]

Dans pas longtemps.

par contre reste à savoir quelle version hoccha utilise, d'où le substr qui fonctione de la 6.2 ----> 9.2

[hoccha]

Merci!!!

[MEGAMIND2]

Envoyé par s_a_m

Dans pas longtemps.

par contre reste à savoir quelle version hoccha utilise, d'où le substr qui fonctione de la 6.2 ----> 9.2

Qu'il fasse son choix en fonction de sa version et de la complexité du code (je raconte n'importe quoi, quelle complexité )