Somme d'une variable par modalités d'une autre [Résolu]

[ludo35]

Bonjour,

Les individus sont des communes, j'ai une variable région et une variable numérique.
Comment faire la somme par région?

merci de votre aide

[MEGAMIND2]

Bonjour,

Code :

1
2
3
4
5
6
7
8
9
PROC SORT DATA=MATABLE;
BY REGION;
RUN;
 
PROC MEANS DATA=MATABLE;
BY REGION;
VAR mavariable_num;
OUTPUT OUT=SORTIE(DROP=_TYPE_ FREQ_) SUM=;
RUN;

Sinon tu passes par un proc SQL;

Code :

1
2
3
4
PROC SQL;
CREATE TABLE SORTIE AS SELECT REGION,SUM(mavariable_num) AS SUM 
FROM MATABLE GROUP BY REGION;
QUIT;

Bon courage

[suistrop]

Hello,

avant aussi j'utilisais les "BY" mais avec class, pas besoin de trier !

Code :

1
2
3
4
5
PROC MEANS DATA=MATABLE nway sum noprint missing;
class REGION;
VAR mavariable_num;
OUTPUT OUT=SORTIE(DROP=_TYPE_ FREQ_) SUM=;
RUN;

je n'ai pas encore vu de probleme à utiliser class.

Suistrop

[MEGAMIND2]

[olivier.decourt]

Envoyé par suistrop

avant aussi j'utilisais les "BY" mais avec class, pas besoin de trier !
je n'ai pas encore vu de probleme à utiliser class.

Il y a quand même quelques différences pas si mineures entre CLASS et BY.
1) CLASS lit toute la table d'un seul bloc, alors que BY lit la table par morceaux. Sur une énorme volumétrie, ça fait une vraie différence, car CLASS peut générer des OUT OF MEMORY alors que BY passe impeccablement bien.
2) CLASS oblige à ajouter l'option NWAY ou une instruction WAYS à la proc MEANS pour récupérer une table (via l'instruction OUTPUT OUT, pas via l'ODS) qui ne contienne pas des agrégats intermédiaires. Par exemple, par défaut, avec BY region, j'obtiens une ligne par région dans une table SAS. Avec CLASS region, j'ai une ligne par région... plus une ligne "France entière". Bien pratique parfois, mais à filtrer dans 90% des cas.
3) visuellement, CLASS édite un seul tableau et BY en édite plusieurs. Ca dépend de l'aspect qu'on veut (et par exemple, dans ODS TAGSETS.EXCELXP on peut faire un onglet par "bloc BY" mais pas un onglet par valeur des variables de CLASS).

Et accessoirement : pas forcément besoin de trier en présence d'un BY (mais bon, chut !). Il suffit d'un index ou d'une table ordonnée par blocs.
Dans ce dernier cas, si on a d'abord toutes les observations avec la valeur 1, puis toutes celles avec 3, puis toutes celles avec 2, on dira BY maVariable NOTSORTED ; et on n'aurait pas besoin de reconstruire l'ordre correct 1 puis 2 puis 3 (ou 3 puis 2 puis 1).

Enfin, ça peut être pratique d'utiliser les 2, justement pour obtenir certaines ruptures (changement de tableau) avec cependant des stats groupées par certaines variables.

A titre perso, je fais surtout des CLASS, surtout depuis que la version 8 nous a offert les instructions WAYS et TYPES qui permettent d'être fainéant et de faire plusieurs proc Means en une seule.

Olivier

[MEGAMIND2]

Envoyé par olivier.decourt

A titre perso, je fais surtout des CLASS, surtout depuis que la version 8 nous a offert les instructions WAYS et TYPES qui permettent d'être fainéant et de faire plusieurs proc Means en une seule.

Olivier

Bonjour Olivier,
Tu pourrais m'expliquer comment tu peux faire plusieurs proc Means en une seule? j'avais pas tilté sur le coups.
Merci!
ps: avec ton explication je prône pour l'utilisation de Class, si on peut se passer d'un tri, alors pourquoi s'en priver!

[olivier.decourt]

Disons que CLASS sera très bien dans 90% des cas. Et que sinon, il faudra se souvenir que BY existe.
Pour ce que je voulais dire par "plusieurs proc Means en une seule", voilà :

Code :

1
2
3
4
5
PROC MEANS DATA=sashelp.prdsale NONOBS MEAN MEDIAN ;
  VAR actual predict ;
  CLASS country product year ;
  WAYS 0 1 2 3 ;
RUN ;

Ca fait l'équivalent de 8 proc Means avec des BY différents.

[MEGAMIND2]

Thank you!

[ludo35]

Merci beaucoup pour votre aide.

J'ai une autre question: Les individus sont maintenant des régions et j'ai cinq variables numériques. Comment obtenir en sortie un seul individu par tableau (par sortie) ?

[MEGAMIND2]

Envoyé par ludo35

Merci beaucoup pour votre aide.

J'ai une autre question: Les individus sont maintenant des régions et j'ai cinq variables numériques. Comment obtenir en sortie un seul individu par tableau (par sortie) ?

Tu veux créer autant de tables que de variables?

[ludo35]

euh non, autant de tables que d'individus .

[MEGAMIND2]

Envoyé par ludo35

euh non, autant de tables que d'individus .

Ta variable région a combien de modalité? tu peux les lister si possible

[ludo35]

les 22 régions françaises plus une "DOM-TOM".

[MEGAMIND2]

Envoyé par ludo35

les 22 régions françaises plus une "DOM-TOM".

Adaptes ce programme à tes 22 fameuses régions (macro oblige)

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
%LET liste= Africa Asia Canada Pacific /* liste des régions*/;
 
%MACRO SUM_REGION;
%DO i=1 %TO 4 /* i=1 %to 22 dans ton cas*/;
	%LET liste&i=%SCAN(&liste.,&i,' ');
	PROC MEANS DATA=Sashelp.Shoes nway sum noprint missing;
	class Region;
	VAR Sales Inventory Returns;
	OUTPUT OUT=sortie_&&liste&i.(WHERE=( Region="&&liste&i") DROP=_TYPE_ _FREQ_ ) SUM=;
	RUN;
%END;
 
%MEND;
 
%SUM_REGION;

Bon courage

[Manoutz]

pourquoi ne passer par le by comme dans ton premier message megamind? ca crée autant de tables que d'individus

[MEGAMIND2]

Envoyé par Manoutz

pourquoi ne passer par le by comme dans ton premier message megamind? ca crée autant de tables que d'individus

Je ne sais pas du tout comment générer une table par région sans passer par des macros. Comment tu feras pour nommer ces tables? c'est peut être plus facile

[Manoutz]

Ses individus sont les régions.. donc pas de soucis de ce côté...

du coup tu vas éxécuter 22 proc means... pas évident que ce soit plus optimisé qu'un proc sort+proc means avec un by... En tout ta syntaxe est moins digeste (de mon point de vue en tout cas.. c'est un peu faire compliqué quand on peu faire simple )

[Manoutz]

c'est le principe du by

Code :

1
2
3
4
5
6
7
8
9
ods rtf file="c:\test.rtf";
proc sort DATA=sashelp.bweight out=weight;
BY married;
run;
PROC MEANS DATA=weight sum;
BY married;
VAR weight;
RUN;
ods rtf close;

A priori pas besoin de nommer les tables... de ce que je comprends de la question de ludo... mais pour le faire, suivant le besoin on peut utiliser le #byvar

http://www2.sas.com/proceedings/sugi23/Coders/p75.pdf

[MEGAMIND2]

Envoyé par Manoutz

c'est un peu faire compliqué quand on peu faire simple )

C'est justement ça, pourquoi faire simple qaud on peut faire plus compliqué?
En tout cas je refléchirai à ça demain, assez pour aujourd'hui!
Bonne soirée!

Désolé!

[olivier.decourt]

Mais oui, utilisons l'ODS. Et s'il faut produire plusieurs tables, pensons à ODS OUTPUT et à l'option MATCH_ALL très sous-employée (qui crée une table par bloc BY et stocke même les noms des tables dans une macro-variable).

Code :

1
2
3
4
5
6
7
8
9
10
PROC SORT DATA=sashelp.shoes OUT=work.shoes ;
  BY region ;
RUN ;
ODS OUTPUT summary (MATCH_ALL = liste_tables) = work.reg1 ;
PROC MEANS DATA=work.shoes SUM ;
  VAR sales ;
  BY region ;
RUN ;
 
%PUT liste_tables = &liste_tables ;