Macro pour combinatoire [Résolu]

[joyeux_lapin13]

Bonjour, je voulais vous demander si vous connaissez une macro qui à partir d'une liste de variables, créé l'ensemble de toutes les combinaisons possibles et peut-être utilisée directement dans des procédures comme l'analyse discriminante par exemple?

L'idée est juste de pouvoir appliquer l'analyse discriminante (ou autre) sur toutes les combinaisons de variables disponibles dans ma table.

Merci d'avance.

[MEGAMIND2]

Encore toi Julien?
Tu peux donner un exemple de combinaisons à partir de 3 variables par exemple?

[joyeux_lapin13]

Lol! oui j'vous harcèle je sais lol!

ex: col1 = V1 col2 = V2 col3 = V3
Liste = V1 V2 V3
Combi = {V1} {V2} {V3} {V1 V2} {V1 V3} {V2 V3} {V1 V2 V3}

[MEGAMIND2]

Il faudrait programme qui prend en paramètre une macro variable, et lors de l'éxecution du lui donnes soit une variable où une liste de variable.s

Code :

1
2
3
4
5
6
7
8
9
10
11
12
%MACRO ANALYSE(var=);
 
PROC CORRESP DATA=LAPIN;
TABLES &var.;
RUN;
 
%MEND;
 
%ANALYS(var=V1);
%ANALYSE(var=V1 V2);
......
....

Par contre je ne sais pas comment définir automatiquement toutes les combinaisons possible.

Bon courage!

[joyeux_lapin13]

Merci pour ton conseil Megamind2!

[olivier.decourt]

Pour faire ça, j'utilise la proc PLAN (dans SAS/STAT). Il suffit de faire un petit format qui associe chaque variable à un nombre entier, car PLAN ne randomisera que des nombres de 1 à n.

En SAS 9.2 on peut aussi utiliser la fonction ALLCOMB. Ci-dessous un extrait d'une petite macro maison.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
	PROC CONTENTS DATA=&TABLE (KEEP=&quanti &quali)
				   OUT=work.dico NOPRINT ;
	RUN ;
	PROC TRANSPOSE DATA=work.dico (KEEP=name) 
					OUT=work.dico ;
		VAR name ;
	RUN ;
	DATA work.test ;
		SET work.dico ;
		ARRAY vars $ col: ;
		n = DIM(vars) ;
		DO k=1 TO n ;
			nbComb = COMB(n,k);
			DO i=1 TO nbComb ;
	      		rc=ALLCOMB(i, k, OF vars[*]);
				OUTPUT ;
			END ;
		END ;
	RUN ;

[joyeux_lapin13]

Merci Olivier! je vais regarder tout ça de suite!

[olivier.decourt]

Voilà une petite proc PLAN pour la route (--> ça fait une proc GPS. Oui, bon OK c'est nul comme blague).

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
%MACRO combinaisons (TABLE, exclues=) ;
PROC CONTENTS DATA=&TABLE 
					%IF %LENGTH(&exclues)>0 %THEN (DROP=&exclues) ;
               OUT=work.dico (KEEP=name varnum) NOPRINT ;
RUN ;
DATA work.format ;
  SET work.dico (RENAME=(name=label varnum=start))
     NOBS=nVar 
     END=fin ;
  type="N" ;
  fmtname="var" ;
  OUTPUT ;
  IF fin THEN DO ;
	CALL SYMPUTX("nbVar",nVar) ;
	start=. ;
	label="" ;
	OUTPUT ;
  END ;
RUN ;
PROC FORMAT CNTLIN=work.format ;
RUN ;
ODS OUTPUT plan=work.combinaisons (DROP=modeles) ;
PROC PLAN ;
      %DO i=1 %TO &nbVar ;
      FACTORS modeles=%SYSFUNC(COMB(&nbVar, 1)) ORDERED
              var = &i OF &nbVar COMB ;
	  %END ;
RUN ; QUIT ;
PROC PRINT DATA=work.combinaisons LABEL NOOBS ;
  FORMAT var: var. ;
RUN ;
%MEND combinaisons ;
%combinaisons (sashelp.prdsale) ;

Olivier

[joyeux_lapin13]

Bonjour Olivier, je viens tout juste de tester ton code et c'est exactement ce que je cherche! Merci à toi et Megamind2!