Faire l'inverse d'un transpose [Résolu]

[ChrisMaire]

Bonjour à tous.

J'ai un dataset D1 qui a cette forme :
Num_Rec (numériq) Nom_Banq (alpha) Nom1 (alpha) Nom_long1 (alpha) Nom2 (alpha) Nom_long2 (alpha) Nom3 (alpha) Nom_Long3 (alpha).

et je voudrais le transformer en un dataset D2 qui aurait cette forme
Num_Rec Num_Banq Nom Nom_long

Donc chaque ligne de D1 deviendrait 3 lignes dans D2.

Est ce que quelqu'un a une idée ?

[MEGAMIND2]

Salut,
Je pense qu'il y a plus simple que ça, mais si ça peut t'aider:

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
DATA TEST;
INPUT Num_Rec Nom_Banq $ Nom1 $ Nom_long1 $ Nom2 $ Nom_long2 $ Nom3 $ Nom_Long3 $;
CARDS;
01 4 A1 A2 B1 B2 C1 C2
;
RUN;
 
DATA A ;
SET TEST;
KEEP Num_Rec Nom_Banq  Nom1 Nom_long1 ;
RENAME NOM1=NOM Nom_long1=Nom_long;
RUN;
 
DATA B ;
SET TEST;
KEEP Num_Rec Nom_Banq  Nom2 Nom_long2 ;
RENAME NOM2=NOM Nom_long2=Nom_long;
 
RUN;
 
DATA C ;
SET TEST;
KEEP Num_Rec Nom_Banq  Nom3 Nom_long3 ;
RENAME NOM3=NOM Nom_long3=Nom_long;
 
RUN;
 
DATA FIN;
SET  A B C;
RUN;

[olivier.decourt]

Bonjour.
Outre la solution de Brice, un autre moyen de faire l'inverse d'une proc Transpose est de faire... une proc Transpose.
Mais comme il en faut 1 par série de variables, dans ton cas il faudra 2 proc Transpose + 1 merge.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
DATA TEST;
INPUT Num_Rec Nom_Banq $ Nom1 $ Nom_long1 $ Nom2 $ Nom_long2 $ Nom3 $ Nom_Long3 $;
CARDS;
01 4 A1 A2 B1 B2 C1 C2
;
RUN;
PROC TRANSPOSE DATA=work.test OUT=work.test1a (RENAME=(col1=nom)) ;
  BY num_rec nom_banq ;
  VAR nom_long1-nom_long3 ;
RUN ;
PROC TRANSPOSE DATA=work.test OUT=work.test1b (RENAME=(col1=nom_long)) ;
  BY num_rec nom_banq ;
  VAR nom_long1-nom_long3 ;
RUN ;
DATA work.test2 (DROP=_name_) ;
  MERGE work.test1a work.test1b ;
  BY num_rec nom_banq ;
RUN ;

Je pense qu'il est plus efficace d'utiliser des arrays.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
DATA TEST;
INPUT Num_Rec Nom_Banq $ Nom1 $ Nom_long1 $ Nom2 $ Nom_long2 $ Nom3 $ Nom_Long3 $;
CARDS;
01 4 A1 A2 B1 B2 C1 C2
;
RUN;
DATA work.test2 (DROP=i nom_long1-nom_long3 nom1-nom3) ;
  SET work.test ;
  ARRAY long $ nom_long1-nom_long3 ;
  ARRAY court $ nom1-nom3 ;
  DO i=1 TO DIM(court) ;
    nom = court(i) ;
	nom_long = long(i) ;
	OUTPUT ;
  END ;
RUN ;

Dans la boucle, l'instruction OUTPUT permet de créer une nouvelle observation.
Bon courage.
Olivier

[MEGAMIND2]

créé autant de tables que de variables est fastidieux surtout s'il y avait vingtaine de variable à remettre en ligne. J'ai pensé à l'array mais j'étais bloqué

[olivier.decourt]

En fait j'ai repensé à la solution avec Transpose et il n'est pas utile d'en faire plusieurs, sauf si toutes les variables à transposer ne sont pas toutes de même type (--> dans ce cas, il faudra une Transpose pour les variables numériques et une pour les variables de type caractère).

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
DATA TEST;
INPUT Num_Rec Nom_Banq $ Nom1 $ Nom_long1 $ Nom2 $ Nom_long2 $ Nom3 $ Nom_Long3 $;
CARDS;
01 4 A1 A2 B1 B2 C1 C2
;
RUN;
PROC TRANSPOSE DATA=work.test OUT=work.test1 ;
  BY num_rec nom_banq ;
  VAR nom_1-nom_3 nom_long1-nom_long3 ;
RUN ;
DATA work.test2 (DROP=_name_) ;
  MERGE work.test1 (RENAME=(col1=nom_long) WHERE=(UPCASE(_name_) BETWEEN "NOM_LONG1" AND "NOM_LONG999"))
            work.test1 (RENAME=(col1=nom) WHERE=(UPCASE(_name_) BETWEEN "NOM" AND "NOM999"))
  ;
  BY num_rec nom_banq ;
RUN ;

Mais bon, le plus simple et le plus efficace, c'est la solution avec une étape Data et autant d'arrays que de séries de variables.

[MEGAMIND2]

Salut,
Je ne savais pas qu'on pouvait fusionner une table avec elle même, mais la solution avec les arrays est optimal sauf que l'intéressé (ChrisMaire) a l'air de s'en foutre

[ChrisMaire]

Euhh non je ne vois pas pourquoi tu dis que je m'en fous, je ne fais juste pas de la programmation 100% de mon temps, j'ai des réunions qui m'occupent pas mal et les 6h de décalage horaire n'aide pas non plus. En tout cas, merci beaucoup, je vais essayer la méthode du transpose de ce pas !

[MEGAMIND2]

Au temps pour moi!
La solution proposée par Olivier avec les vecteurs (array) est la plus simplifiée et optimale.
Pour rappel:

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
DATA TEST;
INPUT Num_Rec Nom_Banq $ Nom1 $ Nom_long1 $ Nom2 $ Nom_long2 $ Nom3 $ Nom_Long3 $;
CARDS;
01 4 A1 A2 B1 B2 C1 C2
;
RUN;
DATA work.test2 (DROP=i nom_long1-nom_long3 nom1-nom3) ;
  SET work.test ;
  ARRAY long $ nom_long1-nom_long3 ;
  ARRAY court $ nom1-nom3 ;
  DO i=1 TO DIM(court) ;
    nom = court(i) ;
	nom_long = long(i) ;
	OUTPUT ;
  END ;
RUN ;

Bon courage!

[ChrisMaire]

Impressionnant !
ça marche #1 ! Merci et bonne fin de semaine !

[MEGAMIND2]

Bon week-end à toi également!