[Toutes versions] Sommes multi conditionnels [Résolu]

[nerixm]

Bonjour,
Voilà je suis en train de réaliser un petit fichier Excel pour gérer mon compte bancaire. Les données sont stockés sous cette forme :

N°..........Date..........Débit €..........Crédit €..........Controlé..........Type
10.........02/03/11.........10..........................................OK.............Nourriture
9..........11/12/10...............................20....................OK.............Frais
8..........02/12/10.........500.........................................OK.............Frais
7..........01/12/10...............................1000.................OK.............Frais
6..........01/12/10...............................1500.................OK.............Salaire
5..........25/11/10.........300.........................................OK.............Frais
...

Je souhaiterai créer dans une autre feuille, le budget alloué à chaque catégorie chaque mois (Ex ici pour frais en décembre 2010 = 1000+20-500 = 520).

J'arrive bien à faire le calcul pour les catégorie avec le code suivant

Code :

1
2
 
=(SOMME.SI(ColonneType;"Frais";ColonneCredit))-(SOMME.SI(ColonneType;"Frais";ColonneDebit))

Mais je n'arrive pas à l'adapter pour que la somme ne concerne que les données d'un mois de l'année en particulier.

Merci d'avance pour votre aide

[rvtoulon]

Salut,
Je suis pas sur mais essaye avec la fonction "SOMME.SI.ENS()", qui permet plusieurs critères.

[wilfried_42]

Bonjour

Toute version est demandée, je verais plutôt un sommeprod

Code :

=SommeProd((Colonnetype="Frais") * (texte(colonnedate;"mmaaaa")="032010") * colonnecredit) - =SommeProd((Colonnetype="Frais") * (texte(colonnedate;"mmaaaa")="032010") * colonnedebit)

formule non testée n'ayant pas d'exemples founis.

[hben1961]

Bonjour à tous,

On pourra aussi utiliser la fonction SOMMEPROD, par exemple, par la formule:

Code :

=SOMMEPROD((Année(ColonneDate)=CelluleAnnée)*(Mois(ColonneDate)=CelluleMois)*(ColonneType="Frais")*(ColonneCredit))-SOMMEPROD((Année(ColonneDate)=CelluleAnnée)*(Mois(ColonneDate)=CelluleMois)*(ColonneType="Frais")*(ColonneDebit))

où: CelluleAnnée est la cellule contenant l'Année, et CelluleMois est la cellule contenant le numéro du mois

On peut simplifier la formule précédente par la formule:

Code :

=SOMMEPROD((Année(ColonneDate)=CelluleAnnée)*(Mois(ColonneDate)=CelluleMois)*(ColonneType="Frais")*((ColonneCredit)-(ColonneDebit)))

Cordialement

[cb_60]

Bonjour
Voir si cela repond au probleme, des zones nommées et sommeprod.
les zones nommées:

Code :

1
2
3
4
credit	=DECALER(date;;2)
debit	=DECALER(date;;1)
ldate	=DECALER(Feuil1!$B$2;;;NB(Feuil1!$A:$A))
type	=DECALER(date;;4)

Le sommeprod:

Code :

=SOMMEPROD((MOIS(ldate)=MOIS($A2))*((credit)-(debit))*(type=B$1))

[nerixm]

MERCI.....

La je dois avouer que je suis bluffé par votre niveau en Excel. Pour info j'ai utilisé la solution de hben1961 (qui ressemble à celle de wilfried_42), car effectivement je n'ai pas acces à la fonction SOMME.SI.ENS() (Vieux excel oblige^^).
Merci à tous