Automatiser l'ouverture de sessions locales à partir d'une machine distante [Résolu]

[BigLou]

Bonjour,
je travaille dans un centre de formation comprenant un LAN avec une petite centaine de postes clients ; Il nous arrive très fréquemment de recevoir des visites d'autres organismes et de devoir mettre en configuration toutes les salles de cours (Allumage PC et ouverture des sessions).

Un compte utilisateur dédié à cette manip est déjà configuré sur chaque poste et je voudrais savoir si il est possible d'ouvrir cette session à distance sur chacun des ordi.

La solution de faire une ouverture de session automatiquement ne me plaît pas trop car quand les stagiaires vont allumer ou redémarrer le poste, ils vont se planter et ne pas bosser sur leur compte.
J'ai déjà un peu cherché au niveau de VNC et du processus winlogon.exe mais sans vraiment trouver ce que je veux.
Je n'ai pas énormément de contraintes de sécurité sur ce réseau (c'est pas la fête à mémé quand même... ) et je suis plus ou moins libre de faire ce que je veux tant qu'il fonctionne.

Pour les p'tites infos, on a du serveur Win2003/Active Directory/Exchange, des clients en WinXP Pro SP3 et j'utilise WakeOnLan pour réveiller les machines.

Si quelqu'un a ne serait-ce qu'une idée, mes petits doigts qui doivent authentifier tous les comptes lui diront merci.

[Viduc]

Salut,

tu pourrais faire simple en modifiant à distance le registre, en mettant l'autologon à 1 + login et mdp quand tu as besoins d'une session particulière, et en désactivant le tout quand tu veux que ta salle fonctionne normalement.

Tu peux te faire un script (vbs ou batch) avec arguments et si tes sessions sont toujours aux mêmes heures le faire lancer par un planificateur de tache...

SI tu as un serveur ghost tu peux gérer aussi avec si tu ne te sens pas de scripter le truc...

[BigLou]

Ok je vais travailler là dessus mais ça implique un redémarrage des machines après modification du registre, non ?

[Viduc]

oui en effet, mais tu peux rajouter ça aussi dans la fin de ton script ça se fait bien...

[BigLou]

J'ai trouvé une soluce.

Donc j'ai deux scripts :
- Un qui modifie les trois valeurs du registre et redémarre la bécane avec ouverture de la session "visite".
- Un autre qui remet le registre dans sa configuration initiale.

Plutôt que de faire des batchs utilisant une liste des machines avec leurs @Mac et @IP, j'utilise une application qui s'appelle WakeOnLan.
Elle permet non seulement de gérer l'allumage/extinction des pc à distances mais en plus on peut y ajouter des scripts qui pourront être appliqués sur une ou plusieurs machines. Pour ça il faut aller voir dans Option/Configuration puis dans l'onglet Commands et ajouter, pour chacun des scripts, le nom complet du script avec le paramètre %ip% (pour le passage de paramètre).

Donc pour le script de lancement de la visite, on a :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
LanceSessionVisite.bat
@echo off
REM Ce script permet d'allumer un ordinateur distant et d'automatiser l'ouverture de la session qu'on appellera "visite"
REM Dans les grandes lignes :
REM – Il modifie les valeurs du registre
REM – Il redemarre le PC pour qu'il lance la session visite
REM Il est concu pour fonctionner avec l'application WakeOnLan avec un passage de parametre.
REM ########################################Definition des variables##################################
REM Definit le chemin de la cle dans le registre
REM ATTENTION : Les " situés à la fin de la chaine ferme le parametre de la commande reg plus bas
set CLEREG=HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\winlogon"
REM Definit le compte a utiliser
set CPTE=visite
REM Definit le MDP a utiliser
set MDP=<mot de passe>
REM Extraction du premier parametre qui doit etre l'@ IP
set IP=%1
REM #############################################Modif Registre distant###############################
REM Modif de la valeur DefaultUserName pour forcer le demarrage de la session Visite
REM On retrouve les " qui ouvrent le parametre de la commande reg
echo Modification de la clé \\%IP%\%CLEREG%
reg add "\\%IP%\%CLEREG% /v DefaultUserName /t REG_SZ /d %CPTE% /f
REM Enregistre le mot de passe en clair (oups...)
reg add "\\%IP%\%CLEREG% /v DefaultPassword /t REG_SZ /d %MDP% /f
REM Modif de la valeur AutoAdminLogin pour le demarrage automatique de la session
reg add "\\%IP%\%CLEREG% /v AutoAdminLogon /t REG_SZ /d 1 /f
REM #############################################Redemarrage##########################################
shutdown -r -t 10 -f -m \\%IP%

Et pour remettre les machines en configuration initiale :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
@echo off
REM Ce script permet d'automatiser la reinitialisation des parametres modifiés par LanceSesionVisite.bat.
REM Dans les grandes lignes :
REM - Il modifie Les valeurs du registre
REM - Il eteind le PC.
REM Il est parametre pour etre lance a partir de l application WakeOnLan
REM ########################################Definition des variables##################################
REM Definit le chemin de la clé dans le registre
REM NOTE : Les " situés à la fin de la chaine ferme le parametre de la commande reg plus bas
set CLEREG=HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\winlogon"
REM Extraction du premier parametre qui doit etre l'@ IP
set IP=%1
REM #############################################Modif Registre distant###############################
REM Modif de la valeur DefaultUserName pour retirer le nom au demarrage.
REM NOTE : On retrouve les " qui ouvrent le parametre de la commande reg
echo Modification de la clé \\%IP%\%CLEREG%
reg add "\\%IP%\%CLEREG% /v DefaultUserName /t REG_SZ /d "" /f
REM Supprime le mot de passe
reg add "\\%IP%\%CLEREG% /v DefaultPassword /t REG_SZ /d "" /f
REM Modif de la valeur AutoAdminLogin pour arreter le demarrage automatique de la session
reg add "\\%IP%\%CLEREG% /v AutoAdminLogon /t REG_SZ /d 0 /f
REM #############################################Arret##########################################
shutdown -s -t 10 -f -m \\%IP%

Je ne pense pas que ce soit la méthode la plus "propre" qu'il existe et le mot de passe du compte circule en clair mais en tout cas ça fonctionne bien pour mon cas.

Voilà, voilà, à plus.

[Viduc]

oui c'est une solution, tu peux aussi envisager la possibilité de mettre tes scripts en local sur les machines dans un endroit sécurisé (accessible seulement par les comptes admins et système) et faire que ton système n'ai plus qu'a lancer ces scripts. comme ça tes mdp ne circulent pas en claire...