Verifier droit utilisateur sur un objet de la base [Résolu]

[acama]

Bonjour,
J'ai sécurisé ma base de données.
Maitenant je voudrais tester si l'utilisateur qui ouvre un formulaire à le droit sur le sous-formulaire.
J'ai vu des discussion pour savoir a quels groupes appartient l'utilisateur.
Mais je vois pas comment récupérer les groupes ayant accès à un objet et quel type de droit ils ont.
Peut être existe t'il une façon plus directe.
Pouvez vous m'aiguiller ?
Alex

[LedZeppII]

Bonjour,

Essaie avec ce bout de code.

Code :

1
2
3
4
5
6
' Constantes sécurité Access sur les formulaires et états
Enum acPermFormReport
    Ouvrir = Access.acSecFrmRptExecute
    VoirDesign = Access.acSecFrmRptReadDef
    ModifierDesign = Access.acSecFrmRptWriteDef
End Enum

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Function ChkFmRptPerm(sUsr As String, sForm As String, Permission As acPermFormReport) As Boolean
Dim db As DAO.Database, oDoc As DAO.Document
On Error GoTo ErrH:
 
Set db = CurrentDb
Set oDoc = db.Containers("Forms").Documents(sForm)
oDoc.UserName = sUsr
If (oDoc.AllPermissions And Permission) <> 0 Then
   ChkFmRptPerm = True
Else
   ChkFmRptPerm = False
End If
 
Set oDoc = Nothing
Set db = Nothing
Exit Function
 
ErrH:
MsgBox "Erreur No. " & Err.Number & " : " & Err.Description, , Err.Source
End Function

Le membre AllPermissions permet de vérifier les autorisations effectives.
C'est à dire celles de l'utilisateur lui-même, et celles des groupes dont il est membre.

A+

[acama]

Impec.
Merci (encore) LedZepp

Un petit lien également pour les autres codes de droit :
ftp://ftp-developpez.com/dolphy35/fi.../SECFAQ_FR.doc

Alex