[Proc Tabulate] répéter occurences identiques d'une ligne [Résolu]

[Filippo]

Bonjour,
J'utilise une proc tabulate pour éditer un tableau avec un croisement de variables.

Code :

1
2
3
4
proc tabulate DATA=query;
		class Metier EmploiEnClair Niveau;
		TABLE Metier*EmploiEnClair ALL='TOTAL', Niveau*n='' ALL='TOTAL';
run;

Est-il possible de répéter les occurences de la première colonne (de métier) même quand elle sont identiques pour plusieurs EmploiEnClair ?

Merci.

[datametric]

je ne pense pas.

[Filippo]

Ok,
merci Stéphane.

[olivier.decourt]

Il faudrait plutôt chercher dans la procédure REPORT, avec un bloc COMPUTE pour répéter les valeurs sous-entendues de METIER, et un rôle ACROSS pour avoir ton tableau croisé.

[Filippo]

Merci Olivier,
je vais regarder la proc report

[olivier.decourt]

Hello !
Voici une petite ébauche pour que ta proc Report ressemble à Tabulate...

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
OPTION ORIENTATION=LANDSCAPE ;
PROC TABULATE DATA=sashelp.shoes ;
  CLASS product region subsidiary ;
  TABLE region*subsidiary ALL="TOTAL", product*N="" ALL="Total";
RUN ;
PROC REPORT DATA=sashelp.shoes NOWD ;
  COLUMNS region subsidiary product N ;
  DEFINE region / GROUP ;
  DEFINE subsidiary / GROUP ;
  DEFINE product / ACROSS ;
  DEFINE N / "Total" ;
  RBREAK AFTER / SUMMARIZE ;
  COMPUTE BEFORE region ; /* 1e ligne de chaque région */
    memoire_region = region ; /* RETAIN implicite */
  ENDCOMP ;
  COMPUTE region ;
    IF MISSING(region) THEN region = memoire_region ;
	IF _break_="_RBREAK_" THEN region = "TOTAL" ;
  ENDCOMP ;
RUN ;

Jusqu'au RBREAK, ça reste encore compréhensible (enfin si tu es familier de la proc Report). Ensuite, les blocs COMPUTE interviennent une fois que le tableau est constitué, avant de l'afficher. C'est une espèce d'étape DATA sur le tableau. Le COMPUTE BEFORE est l'équivalent d'un IF FIRST dans une étape DATA ; le COMPUTE tout court s'exécute à toutes les observations.
Bon courage.
Olivier

[Filippo]

Merci beaucoup Olivier,
je n'en demandais pas autant, je vais me documenter plus sur la proc report.

Bonne journée.