[XL-2007] Formule reférant à autre feuille du classeur

[samia08]

bonjour,

j'ai créé un tableau excel pour faire l'enregistrement de nombre de jours en présences et celles en absence du personnel dont je gères.

ainsi chaque feuille du classeur représente un mois ( Jan, Feb, Mar...etc)
je souhaite avoir une formule pour calculer automatiquent la présence de toute l'année ds une feuille du même classeur dont j'ai nommé Global

pour plus de clarifications, voici attaché un échantillon

Merci d'avance
samia

[U. Milité]

Bonjour,

Tester en B3 de la feuille "Global" (puis recopier jusqu'en I7) la formule suivante:

Code :

=INDIRECT("'"&GAUCHE(DECALER(B$1;0;1-EQUIV(B$2;$B$2:$C$2;0));3)&"-10'!"&CHOISIR(EQUIV(B$2;$B$2:$C$2;0);"B";"C")&LIGNE()-1)

... à noter qu'il aurait été plus facile de travailler avec le même texte en ligne 1 et dans les noms des feuilles (onglets)

[samia08]

bonjour,

j'ai essayé de recopier la formule mais je reçois toujours un méssage d'erreur

Merci de m'orienter
samia

[U. Milité]

re-bonjour,

Seule solution: ton fichier en retour.

[samia08]

Merci Infiniment
mais si j'ajoute une colonne Job( voir attachement ) , comment deviendras la formule

thanks in advance
Samia

[U. Milité]

Bonsoir,

Dans le dernier exemple transmis, la formule en B3 de la feuille "Global" deviendra:

Code :

=INDIRECT("'"&GAUCHE(DECALER(B$1;0;1-EQUIV(B$2;$B$2:$D$2;0));3)&"-10'!"&CHOISIR(EQUIV(B$2;$B$2:$D$2;0);"B";"C";"D")&LIGNE()-1)

... à recopier en bas et à droite.
Pour comprendre, fais des tests avec des parties de la formule, par exemple:

Code :

=GAUCHE(DECALER(B$1;0;1-EQUIV(B$2;$B$2:$D$2;0));3)

Code :

=GAUCHE(DECALER(B$1;0;1-EQUIV(B$2;$B$2:$D$2;0));3)&"-10'!"

Code :

=CHOISIR(EQUIV(B$2;$B$2:$D$2;0);"B";"C";"D")

Bon travail,

PS:je supprime ma précédente pièce jointe, pour "alléger"

[samia08]

la nouvelle formule a fonctionné
Merci beaucoup de votre aide

have a good day
Samia

[samia08]

rebonjour,

Dans la feuille Global du précedent fichier je voulais compter, pour chaque employé la somme de presence, du congé et du Job pour toute l'anné alors dans la cellule K3 pour la présence, j'ai inséré cette formule =SUMIF(B$2="present",=sum(B3:J3),0) mais je reçcois toujours un méssage d'erreur
pourriez vous me corriger cette formule

Thnks in Advance
Samia

[U. Milité]

Bonjour,

Si je ne m'abuse, SUMIF devrait correspondre à SOMME.SI On devrait donc pouvoir écrire:

Code :

=SUMIF($B$2:$I$2;"present";$B3:$I3)

... à tester

[samia08]

ça a fonctionné

Again thanks
Samia

[samia08]

Bonjour,

j'ai rencontré un autre problème c'est que mon tableau ne garde pas le même ordre des noms des employés pour chaque mois car il ya des partants et des nouveaux recrutés, donc la fomrule ne seras pas pratique, je souhaites avoir cette formule dépendants des Noms des employés pas des Numéros de cellules, est ce possible?

Merci d'avance
samia

[U. Milité]

Bonsoir,

Possible, sans aucun doute, mais un peu "ardu" au niveau de la formule. Par ailleurs, si cela devient lourd à gérer, la question à se poser (peut-être?) est: pourquoi "splitter" en différentes feuilles, pour tout rassembler ensuite?

Bref deux formules qui permettent de renseigner les "présent", "congé" et "job" ... En B3 de la feuille global:

Code :

=INDEX(INDIRECT("'"&GAUCHE(DECALER(B$1;0;1-EQUIV(B$2;$B$2:$D$2;0));3)&"-10'!$B$2:$D$20");EQUIV($A3;INDIRECT("'"&GAUCHE(DECALER(B$1;0;1-EQUIV(B$2;$B$2:$D$2;0));3)&"-10'!$A$2:$A$20");0);EQUIV(B$2;$B$2:$D$2;0))

... Ou (toujours en B3)

Code :

=INDIRECT("'"&GAUCHE(DECALER(B$1;0;1-EQUIV(B$2;$B$2:$D$2;0));3)&"-10'!"&CHOISIR(EQUIV(B$2;$B$2:$D$2;0);"B";"C";"D")&EQUIV($A3;INDIRECT("'"&GAUCHE(DECALER(B$1;0;1-EQUIV(B$2;$B$2:$D$2;0));3)&"-10'!$A$1:$A$20");0))

Attention: il te faut encore trouver un système qui liste en colonne A de la feuille Global, tous les prénoms repris dans (au moins) une des feuilles ... le tout, sans doublons

[samia08]

Merci de votre aide mais ça n'a pas fonctionné pour moi
je vais laisser tombé

Thanks
Samia