[SQL] jointure et PassTrough [Résolu]

[valery95]

Bonjour à tous,
Je cherche à optimiser un traitement qui prend environ 2h (libname + SQL) par une solution passtrough, cependant j'ai une erreur de code car je fais une jointure avec un table en local hors je ne vois pas trop comment faire ma jointure.

Ci-joint le code

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
libname LOC "G:\local";
libname SERV db2 user="XXX" password="YY" DATABASE='BMP1G' schema='GU_AGRC' READBUFF=1000;
 
/* Ajout des coordonnées*/
PROC SQL;
      CREATE TABLE LOC.Point2 AS
          SELECT  A.* ,
                  B.IDLOC ,
                  C.ADR_IDADR,
                  D.ADR_NUMRUE,
                  D.ADR_NOMRUE,
                  D.ADR_COMMUNE,
                  D.ADR_POSTAL,
          FROM LOC.POINT A /*table local*/
 
          LEFT JOIN serv.DWH_POINT B
                  ON A.POINT_ID=B.POINT_ID
 
          LEFT JOIN serv.DWH_LOCAL C
                  ON B.IDLOC=C.IDLOC
 
          LEFT JOIN serv.DWH_ADRESSE D
                  ON C.ADR_IDADR=D.ADR_IDADR
;
quit;
 
/*solution passtrough*/
proc sql ;
    connect TO DB2 (user="XXX" password="YY" DATABASE='BMP1G' schema='GU_AGRC' READBUFF=1000);
    CREATE TABLE LOC.Point2 AS 
		SELECT * FROM connection TO DB2 	(
 
		SELECT 	A.* , 
                  B.IDLOC ,
                  C.ADR_IDADR,
                  D.ADR_NUMRUE,
                  D.ADR_NOMRUE,
                  D.ADR_COMMUNE,
                  D.ADR_POSTAL,
 
 
		FROM LOC.POINT A /*erreur*/
 
		LEFT JOIN DWH_POINT B
				ON A.POINT_ID=B.POINT_ID
		LEFT JOIN DWH_LOCAL C
				ON B.LOC_IDLOC=C.LOC_IDLOC
		LEFT JOIN DWH_ADRESSE D
				ON C.ADR_IDADR=D.ADR_IDADR
											);
 disconnect FROM db2;
QUIT;

le msg d'erreur :

Code :

1
2
CLI DESCRIBE error: [IBM][CLI Driver][DB2/AIX64] SQL0204N Le nom "LOC.POINT" n'est pas défini.
        SQLSTATE=42704

Merci.

[MEGAMIND2]

Bonjour,
J'ai balayé ton code en diagonale, et je pense que ya une coquille
la virgule juste avant ton "FROM LOC.POINT" ne devait pas y être.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
proc sql ;
connect to DB2 (user="XXX" password="YY" database='BMP1G' schema='GU_AGRC' READBUFF=1000);
create table LOC.Point2 as 
select * from connection to DB2 (

SELECT A.* , 
B.IDLOC ,
C.ADR_IDADR,
D.ADR_NUMRUE,
D.ADR_NOMRUE,
D.ADR_COMMUNE,
D.ADR_POSTAL,

FROM LOC.POINT A /*erreur*/LEFT JOIN DWH_POINT B
ON A.POINT_ID=B.POINT_ID
LEFT JOIN DWH_LOCAL C
ON B.LOC_IDLOC=C.LOC_IDLOC
LEFT JOIN DWH_ADRESSE D
ON C.ADR_IDADR=D.ADR_IDADR
);
disconnect from db2;
QUIT;

[olivier.decourt]

Effectivement, comme le signale Brice, il y a une virgule en trop.
Mais le fond du souci, c'est que DB2 ne connaît pas ta table locale, effectivement. Ce qui veut dire que 1) tu connais suffisamment bien ton DBA pour obtenir d'avoir un espace où copier ta table locale dans la base DB2, et ensuite tu pourras faire ta jointure en pass-thru ; ou 2) tu fais toutes les jointures possibles en pass-thru et tu finis sous SAS :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
proc sql ;
    connect TO DB2 (user="XXX" password="YY" DATABASE='BMP1G' schema='GU_AGRC' READBUFF=1000);
    CREATE TABLE LOC.Point2 AS 
		SELECT * FROM 
LOC.POINT AS A
LEFT JOIN
connection TO DB2 	(
 
		SELECT  
                  B.IDLOC ,
                  C.ADR_IDADR,
                  D.ADR_NUMRUE,
                  D.ADR_NOMRUE,
                  D.ADR_COMMUNE,
                  D.ADR_POSTAL
 
 
		FROM  
                   DWH_POINT B
 
		LEFT JOIN DWH_LOCAL C
				ON B.LOC_IDLOC=C.LOC_IDLOC
		LEFT JOIN DWH_ADRESSE D
				ON C.ADR_IDADR=D.ADR_IDADR
) AS B
ON A.POINT_ID=B.POINT_ID ;
 disconnect FROM db2;
QUIT;

Bon courage.
Olivier

Olivier a raison , ta base ne reconnait pas la table SAS, pour te convaincre,
ajoute sa à ta requêtte SQL;

Code :

1
2
3
 
 
%put &sqlxmsg;

[valery95]

Merci pour vos réponses ,

effectivement la 2ème solution d'Olivier fonctionne j'arrive a gagné 1h de traitement ! Juste une petite correction dans le code il manquait le schéma a indiqué pour les tables db2.

voici le code corrigé :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
 
proc sql ;
    connect TO DB2 (user="XXX" password="YY" DATABASE='BMP1G' schema='GU_AGRC' READBUFF=1000);
    CREATE TABLE LOC.Point2 AS 
		SELECT * FROM 
LOC.POINT AS A
LEFT JOIN
connection TO DB2 	(
 
		SELECT  
                  B.IDLOC ,
                  C.ADR_IDADR,
                  D.ADR_NUMRUE,
                  D.ADR_NOMRUE,
                  D.ADR_COMMUNE,
                  D.ADR_POSTAL
 
 
		FROM  
                   GU_AGRC.DWH_POINT B
 
		LEFT JOIN GU_AGRC.DWH_LOCAL C
				ON B.LOC_IDLOC=C.LOC_IDLOC
		LEFT JOIN GU_AGRC.DWH_ADRESSE D
				ON C.ADR_IDADR=D.ADR_IDADR
) AS B
ON A.POINT_ID=B.POINT_ID ;
 disconnect FROM db2;
QUIT;

Valéry