ODS et COMPUTE [Résolu]

[Bonjovi51]

Bonjour à tous,
Je me permets de poster ce message parce que je n'ai pas trouvé mon bonheur en faisant une recherche rapide sur "compute".

Mon problème est tout simple (je pense) mais je n'ai pas encore assez d'expérience pour en arriver à bout.

Je vous expose mon problème.

Voilà, à partir de données d'une base ORACLE, je dois formatter mon tableau en fonction des données sorties.
Pour cela j'utilise la fonction compute. Là je me dis pas de problème, ça devrait passer sans problème. Eh bien, shame on me, ce la ne fonctionne pas.

En gros, ma colonne doit se mettre en gras lorsque ma colonne incontournale est à 'Y'. Mais rien ne se passe. J'ai bien mis mon Y entre quote et doublequote mais rien n'y fait le problème persiste.

Code :

1
2
3
4
5
6
7
8
9
proc report DATA=mes_data nowd  style(report)={just=LEFT BORDERwidth=1pt frame=box rules=groups}
							 style(header)={CELLWIDTH=7cm BACKGROUND=#FFE89F};
    COLUMN ("Colonne 1" colonne) incontournable;
	define colonne / "" display  style(COLUMN) = {CELLWIDTH=19cm JUST=LEFT vjust=center};
	define incontournable / display noprint;
	compute colonne;
		IF incontournable = 'Y' then call define(_COL_,'STYLE','STYLE=[FONT_WEIGHT=bold]');
	endcomp;
run;

Quelqu'un aurait-il une idée à me soumettre?

Je vous remercie d'avance

[sasadm]

Salut,
2 modifications de ton code pour aboutir à ce que tu recherches :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
DATA mes_data;
input incontournable $ colonne $;
cards;
Y ligne1
N ligne2
Y ligne3
;
run;
 
proc report DATA=mes_data nowd  style(report)={just=LEFT BORDERwidth=1pt frame=box rules=groups}
							 style(header)={CELLWIDTH=7cm BACKGROUND=#FFE89F};
    COLUMN ("Colonne 1" colonne) incontournable;
	define colonne / "" display  style(COLUMN) = {CELLWIDTH=19cm JUST=LEFT vjust=center};
	define incontournable / display noprint;
 
	/* compute de incontournable plutot que colonne + define de colonne */
	compute incontournable;
		IF incontournable = 'Y' then call define('colonne','STYLE','STYLE=[FONT_WEIGHT=bold]');
	endcomp;
run;

[Bonjovi51]

Merci beaucoup sasadm.
Réponse rapide pour une solution efficace

A bientôt

[olivier.decourt]

Et le pourquoi de la solution proposée par SASADM : dans un bloc COMPUTE, on ne connaît que les colonnes situées physiquement plus à GAUCHE (selon l'ordre défini dans COLUMNS) que celle que l'on compute.
Donc COMPUTE colonne et un test sur une variable qui se trouve à sa droite ne peut pas fonctionner correctement (SAS évalue les colonnes plus à droite à une valeur manquante).

[Bonjovi51]

Merci pour la petite précision Olivier

[sasadm]

Merci Olivier.
J'apprends quelque chose.

[sasadm]

Donc en application de ce principe, il suffisait de faire commencer la liste des colonnes par la variable incontournable :

Code :

1
2
3
4
5
6
7
8
9
10
 
proc report DATA=mes_data nowd  style(report)={just=LEFT BORDERwidth=1pt frame=box rules=groups}
							 style(header)={CELLWIDTH=7cm BACKGROUND=#FFE89F};
    COLUMN incontournable ("Colonne 1" colonne) ;
	define colonne / "" display  style(COLUMN) = {CELLWIDTH=19cm JUST=LEFT vjust=center};
	define incontournable / display noprint;
	compute colonne;
		IF incontournable = 'Y' then call define(_COL_,'STYLE','STYLE=[FONT_WEIGHT=bold]');
	endcomp;
run;

[Bonjovi51]

C'est bien sasadm.
J'ai utilisé la dernière solution et ça marche tout aussi bien.

Merci encore !