format conditionnel pour colonne jours fériés [Résolu]

[abdel792]

Bonjour,

Voilà, dans un classeur créé avec Excel 2007, j'ai une feuille dont la première ligne comporte de B1 jusqu'à XFD1, des dates allant du premier janvier 2010 jusqu'au 8 novembre 2054.

Ces dates sont au format mercredi 14 mars 2001.

Je souhaiterais appliquer une mise en forme conditionnelle à toutes les colonnes dont la date d'entête est soit samedi soi dimanche.

J'ai essayé plusieurs choses, mais en vain.

Quelqu'un pourrais t-il me renseigner sur la démarche à suivre?

Si le format conditionnel pourrais s'appliquer à tous les jours fériés même ceux qui ne tombent pas un samedi ou dimanche, ce serait encore mieux.

Je vous remercie d'avance.

[wilfried_42]

Bonjour

Formule à appliquer dans la mise ne forme conditionnelle :

Code :

=joursem(B$1;2)>5

definir le format

salutations

[abdel792]

Merci, ca marche.

Autre question, y aurait t-il une formule ou une fonction qui reconnaîsse le jour férié même si il ne tombe par un samedi ou un dimanche?

Merci d'avance.

[wilfried_42]

re:

des jours feriés ceratins sont figés comme le 1er mai, le 14 juillet ...mais d'autres sont calculés selon le calendrier lunaire comme le lundi de paques et 2 autres.

Le mieux pour toi est de gerer une base de donnée (2eme feuille) contenant le calendrier des jours féries et ensuite la nouvelle formule pour la MFC sera simple.

Tu trouveras sur le forum, les formules nécessaires avec les mots cles : jours fériés

[abdel792]

Merci beaucoup, je vais faire une recherche sur le forum...

[BOYVES]

Bonjour,
je crois pouvoir te renseigner, il faut rentre la formule est dans MFC

pour les WE =JOURSEM(I$4;2)>5 choisir la mise en forme

pour les jours fériés d'abord il faut nommé toutes les cellules jours fériés
puis dans la MFC la formule est : ET(I$4<>"";NB.SI(FERIE;I$4)>0)

il faut juste modifier la cellule qui en l'occurence dans ce cas I4

[BOYVES]

Bonjour,

pour les jours fériés :

Premier de l'An :
Lundi de Pâques : =DATE(AN;3;29,56+0,979*MOD(204-11*MOD(AN;19);30)-JOURSEM(DATE(AN;3;28,56+0,979*MOD(204-11*MOD(AN;19);30))))+1
Fête du Travail
Victoire 1945
Ascension : lundi de Pâcques + 38
Lundi de Pentecôte : lund de Pâcques + 49
Fête Nationale
Assomption
Toussaint
Armistice

La formule pour trouver Pâcques fonctionne mais je ne pourrais pas te l'expliquer !?
Amuses toi bien .

[berapard]

Bonsoir,

La formule suivante indiquée dans la MFC fonctionne pas trop mal :
=NON(NB.JOURS.OUVRES(LC1;LC1;Jours_Fériés))

Avec :
- Jours_Fériés : Zone où sont listés les jours fériés
- LC1 : référence à adapter en fonction du tableau (je sais, j'ai été traumatisé par Multiplan !)

Année : 2010

Jour de l'an =DATE(Année;1;1)
Dim. de Pâques =DATE(Année;3;29,56+0,979*MOD(204-11*MOD(Année;19);30)-
JOURSEM(DATE(Année;3;28,56+0,979*MOD(204-11*MOD(Année;19);30))))
Lundi de Pâques =Paques+1
Fête du Travail =DATE(Année;5;1)
Victoire 39/45 =DATE(Année;5;8)
Ascension =Paques+39
Dim. de Pentecôte =Paques+49
Lundi de Pentecôte=Paques+50
Fête Nationale =DATE(Année;7;14)
Assomption =DATE(Année;8;15)
Toussaint =DATE(Année;11;1)
Armistice 14/18 =DATE(Année;11;11)
Noël =DATE(Année;12;25)

[corona]

Bonsoir,
A ce jour, j'ai relevé 3 fonctions permettant de calculer le jour de Pâques.

Code :

1
2
3
=FRANC((JOUR(MINUTE(A2/38)/2 + 55) & "/4/" & A2 ) / 7;) * 7-6
=PLANCHER(DATE(A2;5;JOUR(MINUTE(A2/38)/2+56));7)-34
=DATE(A2;3;29,56+0,979*MOD(204-11*MOD(A2;19);30)-JOURSEM(DATE(A2;3;28,56+0,979*MOD(204-11*MOD(A2;19);30))))

Entre l'année 1900 et 2899, elles donnent toutes les 3 le même résultat. A l'exception des années 2079 et 2744 où les 2 premières donnent ensembles le dim 16/04/2079 et dim 16/04/2744 alors que la 3ème donne le dim 23/04/2079 et dim 23/04/2744.
J'avoue ne pas savoir qui a raison, n'ayant pas eu encore l'occasion d'aller vérifier.
Je doute d'ailleurs d'avoir à rencontrer des problèmes avec un client à cette époque là.
Pour ma part, j'utilise depuis plusieurs années la première fonction, trouvé sur le site de Laurent Longre.