[VBA] Body contenant du Html ? [Résolu]

[Monkey_D.Luffy]

Bonjour

Je développe en VBA une macro d'envoi automatique de mail.
Dans le corps du mail, je voudrais inclure un lien Html.

Voici le code que j'utilise

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Private Sub SendLotus(ByVal vSubject As String, ByVal vDest As Variant, ByVal vBody As String)

    Dim oWorkspace As Object
    Dim oSess As Object
    Dim oDB As Object
    Dim oDoc As Object
    Dim oItem As Object
    Dim oEditDoc As Object
    
    Set oSess = CreateObject("Notes.NotesSession")
    
    Set oDB = oSess.GETDATABASE("", "")
    Call oDB.OPENMAIL

    Set oDoc = oDB.CREATEDOCUMENT
    
    Set oWorkspace = CreateObject("Notes.NotesUIWorkspace")
    
    Set oItem = oDoc.CREATERICHTEXTITEM("BODY")
    
    oDoc.Form = "Memo"
    oDoc.Subject = vSubject
    oDoc.SendTo = vDest
    oDoc.Body = vBody
    oDoc.postdate = Date
    
    Call oDoc.Save(True, True)
    
    On Error Resume Next
    Set oEditDoc = oWorkspace.EditDocument(True, oDoc, True, , False, True)
    On Error GoTo 0
    
    Call oEditDoc.gotofield("Body")
    
    oDoc.visable = True
    
    MsgBox "Mail prepared !", vbInformation

End Sub

J'ai essayé avec

Code :

1
2
oDoc.HtmlBody = "Texte en Html"

mais sans succès.

Auriez-vous un simple exemple de fonction d'envoi de body contenant du Html svp ?

Merci d'avance.

[Zabriskir]

Bonjour,

Une réponse à votre question ici.

@+

[Monkey_D.Luffy]

Merci pour votre réponse. Finalement entre temps j'avais trouvé une autre solution permettant de passer en argument le code Html

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

Private Sub SendViaLotus(ByVal vSubject As String, ByVal vDest As Variant, ByVal vBody As String)

    Dim oSess As Object
    Set oSess = CreateObject("Notes.NotesSession")
    
    Dim oDB As Object
    Set oDB = oSess.GetDatabase("", "")
    
    Call oDB.OPENMAIL

    Dim oDoc As Object
    Set oDoc = oDB.CreateDocument

    'Sujet du mail
    oDoc.Subject = vSubject
    'Liste de destinataire
    oDoc.SendTo = vDest
    
    oSess.ConvertMIME = False

    Dim oMime As Object
    Set oMime = oDoc.CreateMIMEEntity

    Dim oStream As Object
    Set oStream = oSess.CreateStream

    'vBody contient le texte au format Html
    Call oStream.WriteText(vBody)

    Dim oChild As Object
    Set oChild = oMime.CreateChildEntity
    Call oChild.SetContentFromText(oStream, "text/html;charset=iso-8859-1", ENC_NONE)

    Call oStream.Close

    oSess.ConvertMIME = True

    'Créé le Draft
    Call oDoc.Save(True, True)

End Sub

Encore merci et bonne journée.