[VBA] BO5.1 export PDF [Résolu]

[antakini]

Bonjour,
J'ai une macro dans une requête qui me permet d'exporter mon rapport au format pdf. cette requête lorsque je la lance me demande de choisir le code d'un client et mon rapport exporté porte le nom :"code_client.pdf".
Mon problème est que je dois relancer ma requête et ma macro pour chacun de mes clients...
ma question est la suivante : Si je crée dans mon rapport une rupture sur le code client, est il possible en VBA de créer un pdf pour chacunes de mes ruptures ?
MERCI

[antakini]

Bonjour,
J'ai trouvé sur le net un code qui semble répondre à mes attentes, en jouant sur les sections à la place des ruptures :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
Option Explicit
Sub FilterAndExport()
  Dim mydoc As Document
  Dim myrpt As Report
  Dim myFilterVar As DocumentVariable
 
  Dim i, j, noOfReports, intNumChoices As Integer
  Dim myFilterChoices As Variant
  Dim strNextValue As String
 
  'Active Document
  Set mydoc = ActiveDocument
 
  ' Active (with focus) Report
  Set myrpt = ActiveReport

  ' Put your variable (or query object) here
  Set myFilterVar = mydoc.DocumentVariables("State")
 
  ' find out how many values there are for the variable
  intNumChoices = UBound(myFilterVar.Values(boUniqueValues))
  ' collect the number of choices in a variant variable
  myFilterChoices = myFilterVar.Values(boUniqueValues)
  For i = 1 To intNumChoices
   
    ' Get the variable value
    strNextValue = myFilterChoices(i)
   
    noOfReports = mydoc.Reports.Count
    For j = 1 To noOfReports
    Set myrpt = mydoc.Reports.Item(j)
   
    ' build filter
    myrpt.AddComplexFilter myFilterVar, "=<State> = " & """" & strNextValue & """"
   
    ' recompute the report
    myrpt.ForceCompute
   
    Next j
   
    'Declare Directory Structure
   Dim DocPDF_Dir As String
  'Set Directory Structure
  'DocPDF_Dir = "C:\Documents and Settings\Desktop\"
  DocPDF_Dir = "C:\Documents and Settings\Desktop\"

  'Declare Filenames
  Dim Document_Name As String
  'Set Filenames
  Document_Name = "2006" & "_" & strNextValue
  'Distribute Files
  ActiveDocument.ExportAsPDF (DocPDF_Dir & Document_Name)
     
  Next i
  ' now, unless I can find a RemoveComplexFilter function, this line is used
  ' to invoke a filter that is always true.
 
  myrpt.AddComplexFilter myFilterVar, "=(1=1)"
  myrpt.ForceCompute
End Sub

[TomDuBouchon]

Bonjour,

Je n'aurais pas dit mieux. Cependant une petite précision : la présence d'une section n'est pas nécessaire.

En fait le fonctionnement de cette macro consiste à :

• Récupérer toutes les valeurs pour tous les clients
• Pour chaque client :
  • Filtrer le rapport sur le client correspondant
  • Exporter en pdf pour le client correspondant

[antakini]

merci pour la précision ...

si je comprend bien, c'est à ce niveau du code que le filtre se fait :

Code :

1
2
' Put your variable (or query object) here
  Set myFilterVar = mydoc.DocumentVariables("State")

[TomDuBouchon]

Non, ce n'est pas ici...

Pour expliquer le code :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
Option Explicit
Sub FilterAndExport()

'Déclaration des variables 
  Dim mydoc As Document
  Dim myrpt As Report
  Dim myFilterVar As DocumentVariable
 
  Dim i, j, noOfReports, intNumChoices As Integer
  Dim myFilterChoices As Variant
  Dim strNextValue As String
 
  'Enregistre dans une variable le document actif
  Set mydoc = ActiveDocument
 
  ' Enregistre dans une variable le rapport actif
  Set myrpt = ActiveReport

  ' Enregistre dans une variable l'objet "State"
  Set myFilterVar = mydoc.DocumentVariables("State")
 
  ' Enregistre dans une variable le nombre de valeurs de l'objet "State"
  intNumChoices = UBound(myFilterVar.Values(boUniqueValues))
  ' Enregistre dans une variable les valeurs de l'objet "State"
  myFilterChoices = myFilterVar.Values(boUniqueValues)
  'Parcoure toutes les valeurs de l'objet "State"
  For i = 1 To intNumChoices
   
    ' Récupère la valeur "en cours" de l'objet "State"
    strNextValue = myFilterChoices(i)
   
    'Récupère le nombre de rapports du document
    noOfReports = mydoc.Reports.Count
    'Parcoure l'ensemble des rapports du document
    For j = 1 To noOfReports
    'Enregistre dans une variable le rapport "en cours"
    Set myrpt = mydoc.Reports.Item(j)
   
    ' Application sur le rapport en cours du filtre sur l'objet "State" avec la valeur de l'objet "State" en cours 
    myrpt.AddComplexFilter myFilterVar, "=<State> = " & """" & strNextValue & """"
   
    ' Force le réaffichage du rapport en cours
    myrpt.ForceCompute
   
    Next j
   
  'Ensuite, il s'agit des lignes pour l'export PDF du document filtré, et des lignes pour la "suppression" du filtre
    'Declare Directory Structure
   Dim DocPDF_Dir As String
  'Set Directory Structure
  'DocPDF_Dir = "C:\Documents and Settings\Desktop\"
  DocPDF_Dir = "C:\Documents and Settings\Desktop\"

  'Declare Filenames
  Dim Document_Name As String
  'Set Filenames
  Document_Name = "2006" & "_" & strNextValue
  'Distribute Files
  ActiveDocument.ExportAsPDF (DocPDF_Dir & Document_Name)
     
  Next i
  ' now, unless I can find a RemoveComplexFilter function, this line is used
  ' to invoke a filter that is always true.
 
  myrpt.AddComplexFilter myFilterVar, "=(1=1)"
  myrpt.ForceCompute
End Sub

[antakini]

MERCI Beaucoup pour ces précisions; ça paraît vite plus simple ou du moins plus clair lorsque c'est bien expliqué .