Somme d'après dates

[Sylcoco]

Bonsoir,

J'ai colonne A une suite de date, colonne B des valeurs en face des dates (pas forcément en face de toutes d'ailleurs). J'aimerai pouvoir calculer la somme des valeurs sur 30 jours glissants.

D'avance merci pour l'aide qui pourrait m'être apportée.


Sylvain

[GerardCalc]

Bonsoir,

Queques précisions ne seraient pas superflues :
Tes dates sont-elles triées en ordre chronologique ?
Sont-elles uniques ou peut-il y avoir plusieurs fois la même date ?

La première formule est sur la 30 ème ligne si la réponse aux 2 premières questions est Oui.
Ou veux-tu juste une formule pour les 30 derniers jours ?

A suivre...

[Sylcoco]

Bonsoir,

Effectivement les dates sont triées par ordre chronologiques et il peut y avoir plusieurs fois la même date. Comme il pourrait n'y avoir que quelques dates. Le but étant de pouvoir calculer des sommes par rapport à des dates. En l'occurence sur 30 jours glissants.

Sylvain

[GerardCalc]

Supposons les dates en colonne A, les valeurs à sommer en B, le cumul glissant en C.
Pour la cellule C50, tu peux utiliser :

Code :

1
2
 
=SOMME(INDIRECT("A"&EQUIV(A50-30;A$1:A$500;0)&":A"&LIGNE()))

A adapter à ton fichier.

[Sylcoco]

Merci, mais je n'ai que N/A comme résultat

sylvain

[GerardCalc]

C'est vrai, je n'avais pas pensé qu'il puisse y avoir des dates manquantes.

Code :

1
2
 
=SOMME(INDIRECT("A"&SI(ESTNA(EQUIV(A50-30;A$1:A$500;0));EQUIV(A50-30;A$1:A$500)+1;EQUIV(A50-30;A$1:A$500;0))&":A"&LIGNE()))

[Pierre Fauconnier]

Bonjour

Tu pourrais utiliser SOMMEPROD avec, ici dans l'exemple, la date pivot en D1. Les plages sont à adapter (elles pourraient être nommées, ce serait plus simple)

=SOMMEPROD((A2:A55>=D1-29)*(A2:A55<=D1)*B2:B55)

Si tu veux des dates glissantes par rapport à la date du jour, tu peux utiliser

=SOMMEPROD((A2:A55>=AUJOURDHUI()-29)*(A2:A55<=AUJOURDHUI())*B2:B55)

Si tu souhaites les dates glissantes par rapport la "la plus grande" date, tu peux utiliser

=SOMMEPROD((A2:A55>=MAX(A2:A55)-29)*(A2:A55<=MAX(A2:A55))*B2:B55)

Pour ces trois premières formules, tu n'as pas besoin de trier tes dates.

Si tu veux des dates glissantes par rapport à la dernière date saisie en A (en considérant tes dates triées par ordre croissant), tu peux utiliser

=SOMMEPROD((A2:A55>=DECALER(A1;NBVAL(A:A)-1;0)-29)*(A2:A55<=DECALER(A1;NBVAL(A:A)-1;0))*B2:B55)